Рассчитать значение текущего и предыдущего месяца на основе выбора слайсера в power bi

CALCULATE не влияет на переменные, которые вы уже определили, поэтому FILTER ничего не делает с первым SUMX. См. этот пост по теме для более подробной информации.

Я бы предложил написать меру намного проще. Что-то вроде этого:

Previous Month Revenue =
VAR PrevMonth =
    SELECTEDVALUE (
        'Date'[Month],
         MONTH ( TODAY () )
    ) - 1
RETURN
    CALCULATE (
        SUM ( 'Main Table'[Revenue] ),
        'Main Table'[Mon] = PrevMonth
    )

Из кода я вижу, что таблица «Дата» имеет числовой столбец «Месяц», который, как я предполагаю, имеет тот же тип, что и столбец «Пн» в вашей «Основной таблице».

Кроме того, поскольку в «Основной таблице» нет года, я предполагаю, что год не следует учитывать.

Из слайсера над таблицей дат мы можем напрямую получить выбранную дату [месяц] с помощью SELECTEDVALUE(). В качестве параметра по умолчанию мы используем текущий месяц, полученный функцией TODAY().

Затем мы получаем предыдущий месяц, вычитая один из выбранного месяца, и мы можем использовать его для среза таблицы, сгруппированной по CustomerName, Mon и Revenue. Группировка необходима для удаления повторяющихся доходов для одного и того же клиента в том же месяце и реализуется с помощью SUMMARIZE().

В качестве последнего шага мы можем агрегировать «Основную таблицу» [Доход] отфильтрованной и сгруппированной таблицы, используя SUMX.

'Measure Previous Month Revenue' = 
VAR CurrentMonth =
    MONTH(
        TODAY()
    )
VAR SelectedMonth =
    SELECTEDVALUE(
        'Date'[Month],
        CurrentMonth
    )
VAR PrevMonth = SelectedMonth - 1   
VAR MyTable =
    CALCULATETABLE(
        SUMMARIZE(
            'Main Table',
            'Main Table'[ClientName],
            'Main Table'[Mon],
            'Main Table'[Revenue]
        ),
        'Main Table'[Mon] = PrevMonth,
        REMOVEFILTERS( 'Date' )
    )
VAR Result =
    SUMX(
        MyTable,
        'Main Table'[Revenue]
    )
RETURN
    Result

Тот же код, но для расчета предыдущего месяца, можно записать для текущего месяца.

'Measure Current Month Revenue' = 
VAR CurrentMonth =
    MONTH(
        TODAY()
    )
VAR SelectedMonth =
    SELECTEDVALUE(
        'Date'[Month],
        CurrentMonth
    )
VAR MyTable =
    CALCULATETABLE(
        SUMMARIZE(
            'Main Table',
            'Main Table'[ClientName],
            'Main Table'[Mon],
            'Main Table'[Revenue]
        ),
        'Main Table'[Mon] = SelectedMonth,
        REMOVEFILTERS( 'Date' )
    )
VAR Result =
    SUMX(
        MyTable,
        'Main Table'[Revenue]
    )
RETURN
    Result

Лучшее решение может быть реализовано путем установки связи между таблицей «Дата» и «Основной таблицей». В зависимости от бизнес-требований можно использовать таблицу дат с детализацией на уровне месяца со столбцом YearMonth вместо столбца Mon или на уровне дня со столбцом Date вместо столбца Mon.