Решить проблему с несколькими условиями в autoit

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $sLanguage

    ; Create a GUI
    Local $hGUI = GUICreate("my program", 300, 200)

    ; Create a combobox control.
    Local $idComboBox = GUICtrlCreateCombo("", 10, 10, 185, 20)
    Local $idButton = GUICtrlCreateButton("Activate", 210, 140, 85, 25)
    Local $idButton_Close = GUICtrlCreateButton("Close", 210, 170, 85, 25)

    ; Add additional items to the combobox.
    GUICtrlSetData($idComboBox, "Arabic|French|English", "Arabic")

    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)

    Local $sComboRead = ""

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $idButton_Close
                ExitLoop

            Case $idButton
                $sComboRead = GUICtrlRead($idComboBox)

                local $slktlng = '"' & @ComSpec & '" /C "' & @ScriptDir & '\bin\prog.exe" enable_language'

                ; Define language code.
                Switch $sComboRead
                    Case "Arabic"
                        $sLanguage = "ar-MA"
                    Case "French"
                        $sLanguage = "fr-FR"
                    Case "English"
                        $sLanguage = "en-US"
                EndSwitch

                Run($slktlng & " " & $sLanguage, @ScriptDir & "\bin\", @SW_HIDE)
        EndSwitch
    WEnd

    GUIDelete($hGUI)
EndFunc

Вы можете использовать другой оператор switch для определения кода языка. Не уверен, почему вы должны использовать отдельные имена переменных для код языка, хотя я использовал общее имя $sLanguage для присвоить выбранный языковой код. Это помогает избежать дублирования кода, т.е. только одного Требуется вызов функции Run() вместо трех.

Также исправлено цитирование команды, хранящейся в $slktlng. Я изменил аргумент /K на /C, поэтому ComSpec автоматически закрывается по завершении.