Сохранение большого целого числа в OCaml

Вам понадобится установить библиотеку Zarith для работы с числами произвольной точности, поскольку собственные целочисленные типы не могут обрабатывать числа размера, которые вы им запрашиваете.

Тогда вашу функцию split_digits довольно просто реализовать, используя такие функции, как Z.div и Z.rem вместо операций int/ и mod.

# #require "zarith";;

# let n = Z.of_string "11515195063862318899931685488813747395775516287289682636499965282714637259206269";;
val n : Z.t = <abstr>

# let rec split_digits n =
    if n = Z.zero then []
    else
      let z256 = Z.of_int 256 in
      Z.to_int (Z.rem n z256) :: split_digits (Z.div n z256);;
val split_digits : Z.t -> int list = <fun>

# split_digits n;;
- : int list =
[125; 110; 119; 48; 100; 95; 121; 52; 119; 95; 51; 104; 55; 95;
 108; 108; 52; 95; 54; 110; 49; 100; 48; 99; 110; 51; 123; 111;
 116; 112; 121; 114; 99]

Конечно, вы можете захотеть сделать функцию split_digits хвостовой рекурсивной, чтобы избежать вероятности переполнения стека при работе с особенно огромными числами. Это легко сделать с помощью Tail_mod_cons.

let[@tail_mod_cons] rec split_digits n =
  if n = Z.zero then []
  else
    let z256 = Z.of_int 256 in
    Z.to_int (Z.rem n z256) :: split_digits (Z.div n z256)

Конечно, того же можно добиться, адаптировав split_digits для создания последовательности . Я также сделаю 256 параметром для большей гибкости.

# let rec split_digits sz n () =
    let open Z in
    if n = zero then Seq.Nil
    else
      let z_sz = of_int sz in
      Seq.Cons (
        to_int @@ rem n z_sz, 
        split_digits sz @@ div n z_sz
      );;
val split_digits : Z.t -> int -> int Seq.t = <fun>

# n
  |> split_digits 256 
  |> List.of_seq;;
- : int list =
[125; 110; 119; 48; 100; 95; 121; 52; 119; 95; 51; 104; 55; 95;
 108; 108; 52; 95; 54; 110; 49; 100; 48; 99; 110; 51; 123; 111;
 116; 112; 121; 114; 99]