Сопоставление и составление списка значений на основе значений, перечисленных в другом столбце

Сопоставление нескольких вхождений данных

• Я не думаю, что формулу можно легко исправить. В любом случае, вот альтернатива.
• Функция GetRunningCount ЛАМБДА возвращает текущий счетчик заданного (несортированного) столбца (array).

=LET(headers,A1:I1,data,A3:I22,lookup,K9:K22,
        lookup_header,M3,return_header,M5,
    GetRunningCount,LAMBDA(array,LET(
        so,SORT(HSTACK(SEQUENCE(ROWS(array)),array),2),
        d,DROP(so,,1),        
        SORTBY(SCAN(0,d=VSTACK("",DROP(d,-1)),LAMBDA(sr,r,
            IF(r,sr+1,1))),TAKE(so,,1)))),
    d,IF(data = "","",data),
    rci,XLOOKUP(return_header,headers,d),
    f,rci<>"",
    rc,FILTER(rci,f),
    lc,FILTER(XLOOKUP(lookup_header,headers,d),f),
    src,GetRunningCount(lc),
    drc,GetRunningCount(lookup),
    r,BYROW(SEQUENCE(ROWS(drc)),LAMBDA(r,
        XLOOKUP(1,(lc=INDEX(lookup,r))
            *(src=INDEX(drc,r)),rc,""))),
    r)

• Замените последнюю r любой другой переменной, чтобы увидеть, что она содержит.
• Обратите внимание, что r в BYROW — это другая переменная.

В варианте 2 не могли бы вы попробовать изменить

MAP(a, LAMBDA(e, @DROP(TOCOL(FILTER(IFS(d = e, c), M6 = b), 3),
COUNTIF(K9:e, e) - 1)))

к

MAP(a, LAMBDA(e, @DROP(TOCOL(FILTER(IFS(d = e, 
IF(LEN(TRIM(c)) = 0, NA(), c)), 
M6 = b), 3), COUNTIF(K9:e, e) - 1)))

поскольку TOCOL с вариантом 3 пропускает ячейки с ошибками.

приняв предыдущий ответ:

=LAMBDA(selected_data, data_range, col_headers, header_for_lookup, header_for_return,
    LET(
        lookup_col_0, INDEX(data_range, , XMATCH(header_for_lookup, col_headers)),
        return_col_0, INDEX(data_range, , XMATCH(header_for_return, col_headers)),
        comment_0, "remove cells with corressponding empty cells in return col",
        lookup_col, FILTER(lookup_col_0, LEN(TRIM(return_col_0)) > 0),
        return_col, FILTER(return_col_0, LEN(TRIM(return_col_0)) > 0),
        freq, LAMBDA(arr,
            LET(
                indices, SEQUENCE(ROWS(arr)),
                MAP(indices, LAMBDA(i, SUM(IF(TAKE(arr, i) = INDEX(arr, i, ), 1, 0))))
            )
        ),
        comment_1, "400 1, 400 2",
        lookup_col_with_freq, lookup_col & " " & freq(lookup_col),
        selected_col_with_freq, selected_data & " " & freq(selected_data),
        xlook, XLOOKUP(selected_col_with_freq, lookup_col_with_freq, return_col),
        formatted, IF(RIGHT(header_for_return, 2) = "-M", TEXT(xlook, "0%"), xlook),
        formatted
    )
)(K9:K17, A3:I22, A1:I1, M3, M6)

Быстрое исправление существующей формулы (я считаю, что в конечном итоге вам понадобится гибкий return_array):

=LET(
     _A, K6:K14,
     _B, A1:I1,
     _C, A3:I22,
     _D, XLOOKUP(M3,_B,_C,""),
     MAP(_A,LAMBDA(α, @DROP(TOCOL(FILTER(IFS(_D=α,IF(_C=0,x,_C)),M5=_B),3),
     COUNTIF(K6:α,α)-1))))

В основном измените @DROP(FILTER(), Count-1) на index(FILTER(), COUNT, 1) в этом ответе: XLOOKUP с гибким столбцом для return_array, а не уникальными значениями в search_array

=LET(
    included, A3:A22 <> "",
    lookup_array, FILTER(XLOOKUP(M3, A1:I1, A3:I22, ""), included, ""),
    return_array, FILTER(XLOOKUP(M5, A1:I1, A3:I22, ""), included, ""),
    selected, K9:K17,
    BYROW(
        selected,
        LAMBDA(row,
            LET(
                filtered, FILTER(return_array, lookup_array = row, ""),
                current_count, COUNTIF(K9:row, row),
                INDEX(filtered, current_count, 1)
            )
        )
    )
)