Создайте документацию ascii doc api из документов Spring Rest с помощью Spock

Ваш код с @Rule выглядит как JUnit 4, но Spock 2.x основан на JUnit 5, т. е. этот подход, вероятно, не работает, если только вы не работаете со Spock 1.x.

Мне было любопытно, и я попытался создать проект Maven с нуля — извините, пожалуйста, преобразуйте его в Gradle самостоятельно:

https://github.com/kriegaex/SO_Spock_SpringRESTDocs_78424426

Образец заявления выглядит следующим образом:

package org.example;

import org.springframework.boot.SpringApplication;
import org.springframework.boot.autoconfigure.SpringBootApplication;
import org.springframework.web.bind.annotation.RequestMapping;
import org.springframework.web.bind.annotation.RestController;

@SpringBootApplication
public class Application {
  public static void main(String[] args) {
    new SpringApplication(Application.class).run(args);
  }

  @RestController
  private static class SampleController {
    @RequestMapping("/")
    public String index() {
      return "Hello, World";
    }
  }
}

Соответствующая спецификация Спока выглядит так:

package org.example

import org.springframework.beans.factory.annotation.Autowired
import org.springframework.boot.test.context.SpringBootTest
import org.springframework.restdocs.ManualRestDocumentation
import org.springframework.test.web.servlet.MockMvc
import org.springframework.test.web.servlet.setup.MockMvcBuilders
import org.springframework.web.context.WebApplicationContext
import spock.lang.Specification

import static org.springframework.restdocs.mockmvc.MockMvcRestDocumentation.document
import static org.springframework.restdocs.mockmvc.MockMvcRestDocumentation.documentationConfiguration
import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.get
import static org.springframework.test.web.servlet.result.MockMvcResultMatchers.status

@SpringBootTest(classes = [Application])
class MyControllerSpec extends Specification {
  def restDocumentation = new ManualRestDocumentation()
  @Autowired
  WebApplicationContext context
  MockMvc mockMvc

  def setup() {
    mockMvc = MockMvcBuilders
      .webAppContextSetup(context)
      .apply(documentationConfiguration(restDocumentation))
      .build()
    restDocumentation.beforeTest(getClass(), specificationContext.currentFeature.displayName)
  }

  def cleanup() {
    restDocumentation.afterTest()
  }

  def "should document the GET /hello endpoint"() {
    expect:
    mockMvc
      .perform(get("/"))
      .andExpect(status().isOk())
      .andDo(document("sample"))
  }
}

По сути, я скорректировал ручную настройку, описанную в руководстве для настроек, отличных от JUnit , для Спока. Из предоставленного примера проекта я скопировал код для TestNG.

Было немного сложно согласовать различные версии продукта для Spring и Spring REST Docs, а также хорошо работать со Споком, но в моем примере проекта теперь все работает нормально. Сгенерированная HTML-страница из asciidoc с включенными фрагментами выглядит следующим образом:

Отказ от ответственности: есть вероятность, что моя конфигурация несовершенна и ее можно улучшить. Но я никогда раньше не использовал Spring REST Docs и даже не знаю Spring.