Сравните две ячейки и покажите результат с символом

Вот альтернатива:

Sub alex()
    Dim i As Long, LastRow As Long
    Dim L, M, txt As String
    LastRow = Cells(Rows.Count, "L").End(xlUp).Row
    
    For i = 2 To LastRow
        L = Cells(i, "L").Value
        M = Cells(i, "M").Value
        
        If L = M Then
            txt = "they are equal"
        ElseIf L > M Then
            txt = "L is greater"
        Else
            txt = "M is greater"
        End If
        
        Cells(i, "N") = txt
    Next i
End Sub

Вы можете немного ускорить это, перенеся все данные столбцов L и M в массивы VBA и выполнив сравнения в VBA.

Чтобы получить стрелки, а не текст, используйте:

Sub alex()
    Dim i As Long, LastRow As Long
    Dim L, M, txt As String
    LastRow = Cells(Rows.Count, "L").End(xlUp).Row
    
    For i = 2 To LastRow
        L = Cells(i, "L").Value
        M = Cells(i, "M").Value
        
        If L = M Then
            txt = "n"
        ElseIf L > M Then
            txt = "h"
        Else
            txt = "i"
        End If
        
        Cells(i, "N") = txt
    Next i
End Sub

и отформатируйте ячейки результатов в столбце N, чтобы использовать шрифт Wingdings 3

Вот простое решение, которое вводит формулу во всем диапазоне без зацикливания.

Option Explicit

Sub Sample()
    Dim ws As Worksheet
    Dim lRow As Long
    
    '~~> Change this to the relevant sheet
    Set ws = Sheet1
    
    With ws
        '~~> Find last row in column L
        lRow = .Range("L" & .Rows.Count).End(xlUp).Row
        
        '~~> Insert the formula in Col N. Change as applicable
        With .Range("N1:N" & lRow)
            .Formula = "=IF(L1=M1,""L and M are equal"",IF(L1>M1,""L is greater than M " & _
                       ChrW(&H2191) & _
                       """, ""L is less than M " & _
                       ChrW(&H2193) & _
                       """))"
            '~~> Optional - Convert formula to values
            .Value = .Value
        End With
    End With
End Sub

Скриншот

Примечание:

1. Чтобы вставить стрелку вверх, вы можете использовать ChrW(&H2191), а для стрелки вниз вы можете использовать ChrW(&H2193)

2. Если вы хотите поставить формулу из 2-й строки, то она будет

    '~~> Insert the formula in Col N. Change as applicable
    With .Range("N2:N" & lRow)
        .Formula = "=IF(L2=M2,""L and M are equal"",IF(L2>M2,""L is greater than M " & _
                   ChrW(&H2191) & _
                   """, ""L is less than M " & _
                   ChrW(&H2193) & _
                   """))"
        '~~> Optional - Convert formula to values
        .Value = .Value
    End With
   

Точно так же для другой строки вам придется соответствующим образом настроить.

РЕДАКТИРОВАТЬ

Как вы думаете, можно ли использовать уже отформатированный текст стрелки? Например, красный (или любого другого цвета) определенного размера? А затем поместите это в свой код vba? – Алекс Д. 4 часа назад

Да, это возможно. В этом случае вы можете использовать событие Worksheet_Change для обработки изменений в столбце L и столбце M для заполнения столбца N

Я прокомментировал код ниже. Если у вас все еще есть проблемы с пониманием этого, не стесняйтесь спрашивать. Приведенный ниже код находится в области кода листа. Вы можете изменить атрибуты символа (стиль, цвет и размер) прямо в верхней части кода.

Код

Option Explicit

'~~> Change the symbol attributes here
Const Font_Style As String = "Bold"
Const Font_Size As Long = 15
Const Font_Color As Long = -16776961 '(Red)

Private Sub Worksheet_Change(ByVal Target As Range)
    On Error GoTo Whoa
    
    Application.EnableEvents = False
    
    Dim r  As Variant
    
    '~~> Check if the change happened in the relevant column
    If Not Intersect(Target, Me.Range("L:M")) Is Nothing Then
        For Each r In Target.Rows
            '~~> If even one cell is empty then clear out N cell
            If Len(Trim(Range("L" & r.Row).Value2)) = 0 Or _
               Len(Trim(Range("M" & r.Row).Value2)) = 0 Then
                Range("N" & r.Row).ClearContents
            '~~> Check if L = M
            ElseIf Range("L" & r.Row) = Range("M" & r.Row) Then
                Range("N" & r.Row).Value = "L and M are equal"
            '~~> Check if L > M
            ElseIf Range("L" & r.Row) > Range("M" & r.Row) Then
                With Range("N" & r.Row)
                    .Value = "L is greater than M " & ChrW(&H2191)
                    
                    '~~> Format the symbol which is at 21st position
                    With .Characters(Start:=21, Length:=1).Font
                        .FontStyle = Font_Style
                        .Size = Font_Size
                        .Color = Font_Color
                    End With
                End With
            '~~> L < M
            Else
                With Range("N" & r.Row)
                    .Value = "L is less than M " & ChrW(&H2193)
                    
                    '~~> Format the symbol which is at 18th position
                    With .Characters(Start:=18, Length:=1).Font
                        .FontStyle = Font_Style
                        .Size = Font_Size
                        .Color = Font_Color
                    End With
                End With
            End If
        Next r
    End If
    
Letscontinue:
    Application.EnableEvents = True
    Exit Sub
Whoa:
    MsgBox Err.Description
    Resume Letscontinue
End Sub

В бою