VBA: результаты сопоставления независимо от сортировки индексов?

РЕДАКТИРОВАТЬ, чтобы подтвердить соответствие предположений:

Лист Пользователь1: | Идентификатор | Комментарий | Последний мод | | --- | ------- | --------| | 3 | S1 Связь3| 2 | | 2 | S1 Связь2| 8 | | 1 | S1 Связь1| 6 |

Лист Пользователь2: | Идентификатор | Комментарий | Последний мод | | --- | ------- | --------| | 1 | S2 Связь1| 3 | | 2 | S2 Связь2| 4 | | 3 | S2 Связь3| 8 |

Ожидаемый результат:

Один из вариантов — собрать набор результатов в отдельную коллекцию, а затем заполнить набор результатов по завершении. Поскольку это операция, включающая несколько поисков (проверка того, был ли уже посещен системный идентификатор), мне нравится использовать объекты словаря. Они предлагают высокопроизводительные операции поиска.

Я собираюсь опубликовать ниже очень упрощенный пример, который вы, надеюсь, сможете использовать для своих целей. В приведенном ниже коде предполагается, что столбец SystemId является уникальным ключом, который сопоставляет запись на листе 1 с записью на листе 2. Также предполагается, что каждый системный идентификатор появляется один раз на листе. Если нет, его можно настроить для поддержки этого.

Код в основном перебирает диапазон и проверяет, имеют ли строки на обоих листах совпадающий системный идентификатор. Если это так, он добавляет эту строку в словарь, используя идентификатор в качестве ключа и массив из двух элементов, содержащий комментарий и время последнего изменения.

Если они не совпадают, он сверяет каждую запись со словарем, чтобы увидеть, был ли этот идентификатор системы уже посещен (ранее на другом листе). Если это так, он сравнивает записи и сохраняет самое последнее время модификации, в противном случае оставляет его как есть.

Попробуйте разобраться с этим и дайте нам знать, если вам нужна дополнительная помощь.

Sub Tester()
    Dim oDict As Object
    Dim a(0 To 1)
    Dim sUser1 As Worksheet
    Dim sUser2 As Worksheet
    
    Set oDict = CreateObject("Scripting.Dictionary")
    Set sUser1 = Sheets("User1")
    Set sUser2 = Sheets("User2")
    
    'Here I will assume that both ranges will always
    'be the same length. I'm also hardcoding in the
    'needed rows. You can use whichever logic
    'works best for you to determine how to capture
    'all rows in both sheets
    For i = 2 To 8
        'Two possibilities here:
        '   1. The SystemId in both sheets match and
        '      can be directly compared
        '   2. They differ and will each be checked
        '      to see if they already exist in the dict.
        'You can bypass this and just treat each of the
        'ranges individually, but I think it would be
        'slightly more performant the way I'm doing it.
        '
        'Also, this assumes that each SystemId will only
        'appear once in each sheet, and is a true Primary Key
        If sUser1.Cells(i, 1).Value = sUser2.Cells(i, 1) Then
            If sUser1.Cells(i, 3).Value > sUser2.Cells(i, 3).Value Then
                MergeEntryToDictionary oDict, sUser1.Cells(i, 1).Value, _
                    sUser1.Cells(i, 2).Value, sUser1.Cells(i, 3).Value
            Else
                MergeEntryToDictionary oDict, sUser2.Cells(i, 1).Value, _
                    sUser2.Cells(i, 2).Value, sUser2.Cells(i, 3).Value
            End If
        Else
            'In case they don't match, check each entry against the
            'dictionary to see if the systemId has already been added.
            'If not, then add it. Otherwise, compare the last mod date
            'of the entry to the current, and update if needed.
            MergeEntryToDictionary oDict, sUser1.Cells(i, 1).Value, _
                    sUser1.Cells(i, 2).Value, sUser1.Cells(i, 3).Value
            
            MergeEntryToDictionary oDict, sUser2.Cells(i, 1).Value, _
                    sUser2.Cells(i, 2).Value, sUser2.Cells(i, 3).Value
        End If
    Next i
    
    'Below prints back to sheet
    Dim k As Variant
    Dim n As Long
    n = 2
    For Each k In oDict.keys
        Sheets("result").Cells(n, 1).Value = k
        Sheets("result").Cells(n, 2).Value = oDict(k)(0)
        Sheets("result").Cells(n, 3).Value = oDict(k)(1)
        
        n = n + 1
    Next k
End Sub

Function MergeEntryToDictionary(ByRef oDict As Object, _
                                SystemId As String, _
                                sComment As String, _
                                LastModTime As Double) As Boolean
    Dim a(0 To 2)
    
    If oDict.exists(SystemId) Then
        If LastModTime > oDict(SystemId)(1) Then
            a(0) = sComment
            a(1) = LastModTime
            oDict(SystemId) = a
        End If
    Else
        a(0) = sComment
        a(1) = LastModTime
        
        oDict.Add SystemId, a
    End If
    
    MergeEntryToDictionary = True
End Function