У меня возникают проблемы с включением/отключением кнопки (управление формой) в зависимости от того, заполнены все 4 ячейки или нет (A2, A4, B2 и B4). Вот мой код, все они находятся в одном модуле листа.
Sub Disable_Button()
Dim myshape As Shape
Set myshape = ThisWorkbook.Worksheets("FORM").Shapes("Button")
With myshape
.ControlFormat.Enabled = False '---> Disable the button
.TextFrame.Characters.Font.ColorIndex = 15 '---> Grey out button label
.OnAction = ""
End With
End Sub
Sub Enable_Button()
Dim myshape As Shape
Set myshape = ThisWorkbook.Worksheets("FORM").Shapes("Button")
With myshape
.ControlFormat.Enabled = True '---> Enable the button
.TextFrame.Characters.Font.ColorIndex = 1 '---> Highlight button label
.OnAction = "Module1.TEST"
End With
End Sub
Private Sub Test_Button(ByVal Target As Range)
If Target.Address= 'I'm not sure what to put here since it won't accept multiple ranges
Application.EnableEvents = False
If Target.Value = "" Then
Disable_Button
Else
Enable_Button
End If
Application.EnableEvents = True
End If
End Sub
Module1.TEST
просто выводит «УСПЕХ» в ячейке C1. Я протестировал Disable_Button и Enable_Button по отдельности и подтвердил, что они работают. Однако у меня возникли проблемы с написанием кода, так что кнопка активируется только тогда, когда все 4 ячейки (A2, A4, B2 и B4) заполнены. Я не уверен, подходит ли ByVal Target As Range. Спасибо за любую помощь.
Если вы хотите реагировать на изменения значений ячеек, вам нужно использовать событие Worksheet_Change
. Тонны предыдущих сообщений здесь на эту тему.
Это войдет в модуль кода рабочего листа:
Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
Dim rng As Range
Set rng = Me.Range("A2:B2,A4:B4") 'the cells to monitor
'check if any of the cells in `rng` are in `Target`
If Not Application.Intersect(Target, rng) Is Nothing Then
ToggleButton (Application.CountA(rng) = 4) 'toggle button
End If
End Sub
'switch button between enabled/disabled according to `bEnable`
Sub ToggleButton(bEnable As Boolean)
With Me.Shapes("Button")
.ControlFormat.Enabled = bEnable
.TextFrame.Characters.Font.ColorIndex = IIf(bEnable, 1, 15)
.OnAction = IIf(bEnable, "Module1.TEST", "")
End With
End Sub
Используйте and() для проверки ячеек, укажите условие для каждой: and(A1="yes",B1="Blue") и т. д.