Вывод графика амортизации в Messagebox - Цикл не отображается

В вашем коде есть несколько ошибок... как указывали и другие.

Во-первых, вы хотите запустить цикл For...next, используя

For i = 1 To n * frequency

    'some code

next

Цикл запускается до того, как этим переменным «n» и «частота» будет присвоено значение. Хотя вы намеревались установить «частоту» с помощью поля ввода, «n» нигде не установлено и, следовательно, всегда будет равно 0. Таким образом, в результате цикл выглядит следующим образом:

For i = 1 To 0 * 12 'which results in the loop not running at all

    'some code

next

Итак, правильно установите «n» на то, что ему нужно, или предоставьте диалог ввода для него.

Более того, фактическое назначение этого цикла — расширить отображаемый текст в окне сообщения.

Если вы хотите это сделать, вам нужно будет сначала начать строить строку. В соответствии с вашим кодом ваш текст должен начинаться с:

"Loan Amount " & FormatCurrency(PV) & _
    vbNewLine & "Number of Payments " & years * frequency & _
    vbNewLine & "Interest Rate " & FormatPercent(rate) & _
    vbNewLine & _
    vbNewLine & "PMT # " & vbTab & "Balance " & vbTab & "Payment " & vbTab & "Interest " & vbTab & "Capital "

Итак, если вы присвоите этот текст переменной, вы можете расширить текст с помощью цикла, например:

Dim msgText As String
msgText = "Loan Amount " & FormatCurrency(PV) & _
    vbNewLine & "Number of Payments " & years * frequency & _
    vbNewLine & "Interest Rate " & FormatPercent(rate) & _
    vbNewLine & _
    vbNewLine & "PMT # " & vbTab & "Balance " & vbTab & "Payment " & vbTab & "Interest " & vbTab & "Capital "
    
    'now the loop extends 'msgText'
    For i = 1 To n * frequency
        Pmt = PV * rate / frequency
        msgText = msgText & vbNewLine & Str(i) & _
                       vbTab & FormatCurrency(PV, 2) & _
                       vbTab & FormatCurrency(Pmt, 2) & _
                       vbTab & FormatCurrency(Ipmt, 2) & _
                       vbTab & FormatCurrency(-Ipmt, 2)
        PV = PV - Pmt + Ipmt
    Next i

msgText = msgText & vbNewLine & RepeatCalc

Как только это будет завершено, вся строка будет содержаться в переменной msgText Затем вы можете инициировать MsgBox с этим текстом.

MsgBox msgText, vbOKOnly, "Payment Calculator"

Еще одна вещь: у вас есть InputBox для rate, и вы, кажется, пытаетесь удалить знак «%» в конце строки на случай, если кто-то вставит процент со знаком. (хорошая мысль сама по себе..:-))

Хотя это работает, в итоге получается переменная типа String, и, поскольку rate объявляется как Variant, с этим проблем нет... Но это испортит ваш расчет в вашем цикле For..next, так как Pmt = PV * rate / frequency может работать только с использованием значений (например, Double\Integer и т. д.)

Что вам нужно сделать, так это объявить rate как Double и убедиться, что результат вашего удаления «%» будет преобразован в значение Double с помощью, например, использования CDbl(Val(Left(rate, Len(rate) - 1) / 100))

Итак, ваш код с некоторыми поправками должен выглядеть примерно так, как показано ниже. Имейте в виду, что вам, возможно, придется убедиться, что все переменные (включая «n») установлены правильно, чтобы обеспечить правильность расчета. Как, например, Ipmt нигде не вычисляется...

Измененный код:

Sub PaymentScheduleCalculator()

Dim PV As Single '10000
Dim years As Single '2
Dim frequency As Double '12
Dim rate As Double '4% APR
Dim strRate As String

Dim Ppmt As Double
Dim Ipmt As Double
Dim Pmt As Single 'for pmt after each year

Dim i As Integer 'designation for loop
  
Dim Temp As Integer

n = 1 'has to be properly set to relevant value?
  
PV = InputBox("How much money do you want to borrow?", "Payment Calculator", 10000)
years = InputBox("If you borrow " & FormatCurrency(PV) & " - how many years do want to borrow the money for?", "Payment Calculator", 2)

strRate = InputBox("If you borrow " & FormatCurrency(PV) & " for " & years & " years, " & "what interest rate are you paying?", "Payment Calculator", 0.04)
        If Right(strRate, 1) = "%" Then
            rate = CDbl(Val(Left(strRate, Len(strRate) - 1) / 100))
        Else
            rate = CDbl(strRate)
        End If

frequency = InputBox("If you borrow " & FormatCurrency(PV) & " at " & FormatPercent(rate) & "," & " for " & years & " years, " & _
"how many payment intervals are there per year?", "Payment Calculator", 12)

Dim msgText As String
msgText = "Loan Amount " & FormatCurrency(PV) & _
    vbNewLine & "Number of Payments " & years * frequency & _
    vbNewLine & "Interest Rate " & FormatPercent(rate) & _
    vbNewLine & _
    vbNewLine & "PMT # " & vbTab & "Balance " & vbTab & "Payment " & vbTab & "Interest " & vbTab & "Capital "
    
    'now extends the 'msgText' variable
    For i = 1 To n * frequency
        Pmt = PV * rate / frequency
        msgText = msgText & vbNewLine & Str(i) & _
                       vbTab & FormatCurrency(PV, 2) & _
                       vbTab & FormatCurrency(Pmt, 2) & _
                       vbTab & FormatCurrency(Ipmt, 2) & _
                       vbTab & FormatCurrency(-Ipmt, 2)
        PV = PV - Pmt + Ipmt
    Next i

msgText = msgText & vbNewLine & RepeatCalc

MsgBox msgText, vbOKOnly, "Payment Calculator"

End Sub