WinSock: сервер не получает данные в той же последовательности, что и клиент

Мне нужно отправить данные из Клиент в Сервер в определенной последовательности, где сервер может получать эти данные также в той же последовательности, отправленной клиентом. В приведенном ниже коде существует проблема, заключающаяся в том, что данные (это байт управления, 1) принимаются как данные следующих данных.

Бывший:

На Клиент у меня есть следующий кусок, который отправляет 1 (Connection._Input)

if SendInt(Sock, Ord(Connection._Input)) <= 0 then
      Exit;

Этот байт, отправленный выше, в Сервер принимается правильно в переменной Check, но вместо этого принимается в dwC.

Видеть:

WinSock: сервер не получает данные в той же последовательности, что и клиент

Как это решить?

Вот полный код:

Клиент:

program _Client;

{$APPTYPE CONSOLE}
{$R *.res}

uses
  Windows,
  WinSock,
  SysUtils;

type
  Connection = (Desktop, _Input);

const
  SendBuf: array [0 .. 9] of AnsiChar = ('A', 'B', 'C', 'D', 'E', 'F', 'G',
    'H', 'I', #0);

function SendInt(S: TSocket; I: Integer): Integer;
begin
  Result := send(S, I, SizeOf(I), 0);
end;

function ConnectServer: TSocket;
var
  Wsa: WSAData;
  Client: sockaddr_in;
  S: TSocket;
  Rslt: Integer;
begin
  S := INVALID_SOCKET;
  try
    Rslt := WSAStartup(MakeWord(2, 2), Wsa);
    if Rslt = NO_ERROR then
    begin
      S := socket(AF_INET, SOCK_STREAM, IPPROTO_IP);
      if S <> INVALID_SOCKET then
      begin
        Client.sin_family := AF_INET;
        Client.sin_addr.s_addr := inet_addr('192.168.15.6');
        Client.sin_port := htons(5099);
        if connect(S, Client, SizeOf(Client)) <> SOCKET_ERROR then
          Writeln('Connected successfully!');
      end;
    end;
  except
    Writeln(SysErrorMessage(WSAGetLastError));
  end;
  Result := S;
end;

function DesktopThread(P: Pointer): DWORD; stdcall;
var
  Sock: TSocket;
  dwC, dwD, dwE, dwF, dwG: DWORD;
  A, B: Integer;
begin
  Result := 0;
  Sock := ConnectServer;

  if send(Sock, SendBuf, SizeOf(SendBuf), 0) <= 0 then
    Exit;

  if SendInt(Sock, Ord(Connection.Desktop)) <= 0 then
    Exit;

  dwC := 111;
  dwD := 222;
  dwE := 333;
  dwF := 444;
  dwG := 555;

  repeat
    if recv(Sock, A, SizeOf(A), 0) <= 0 then
      Exit;

    if recv(Sock, B, SizeOf(B), 0) <= 0 then
      Exit;

    if SendInt(Sock, Ord(Connection._Input)) <= 0 then
      Exit;

    if SendInt(Sock, dwC) <= 0 then
      Exit;

    if SendInt(Sock, dwD) <= 0 then
      Exit;

    if SendInt(Sock, dwE) <= 0 then
      Exit;

    if SendInt(Sock, dwF) <= 0 then
      Exit;

    if SendInt(Sock, dwG) <= 0 then
      Exit;

    // Writeln(Format('%s', [SysErrorMessage(WSAGetLastError)]));

    Writeln(Format('dwC: %d, dwD: %d, dwE: %d, dwF: %d, dwG: %d',
      [dwC, dwD, dwE, dwF, dwG]));

  until True;
end;

var
  ThrId: Cardinal;

begin
  try
    CreateThread(nil, 0, @DesktopThread, nil, 0, ThrId);
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;

  Readln;

end.

Сервер:

program _Server;

{$APPTYPE CONSOLE}
{$R *.res}

uses
  Windows,
  WinSock,
  SysUtils;

type
  Connection = (Desktop, Input, _End);

const
  Buffer: array [0 .. 9] of AnsiChar = ('A', 'B', 'C', 'D', 'E', 'F', 'G',
    'H', 'I', #0);

function SendInt(S: TSocket; I: Integer): Integer;
begin
  Result := send(S, I, SizeOf(I), 0);
end;

function ClientThread(P: Pointer): DWORD; stdcall;
var
  Buf: array [0 .. SizeOf(Buffer) - 1] of AnsiChar;
  Sock: TSocket;
  Check: BOOL;
  A, B: Integer;
  _connection: Connection;
  dwC, dwD, dwE, dwF, dwG: DWORD;
begin
  Result := 0;
  Sock := TSocket(P);

  if recv(Sock, Buf, SizeOf(Buffer), 0) <= 0 then
  begin
    closesocket(Sock);
    Result := 0;
    Exit;
  end;

  if not CompareMem(@Buf, @Buffer, SizeOf(Buffer)) then
  begin
    closesocket(Sock);
    Result := 0;
    Exit;
  end;

  if recv(Sock, _connection, SizeOf(_connection), 0) <= 0 then
  begin
    closesocket(Sock);
    Result := 0;
    Exit;
  end;

  if _connection = Connection.Desktop then
  begin
    A := 666;
    B := 777;
    repeat

      if SendInt(Sock, A) <= 0 then
        Exit;

      if SendInt(Sock, B) <= 0 then
        Exit;

      if recv(Sock, Check, SizeOf(Check), 0) <= 0 then
        Exit;

      Writeln(BoolToStr(Check));

      { if not Check then
        continue; }

      if recv(Sock, dwC, SizeOf(dwC), 0) <= 0 then
        Exit;

      if recv(Sock, dwD, SizeOf(dwD), 0) <= 0 then
        Exit;

      if recv(Sock, dwE, SizeOf(dwE), 0) <= 0 then
        Exit;

      if recv(Sock, dwF, SizeOf(dwF), 0) <= 0 then
        Exit;

      if recv(Sock, dwG, SizeOf(dwG), 0) <= 0 then
        Exit;

      // Writeln(Format('%s', [SysErrorMessage(WSAGetLastError)]));

      Writeln(Format('dwC: %d, dwD: %d, dwE: %d, dwF: %d, dwG: %d',
        [dwC, dwD, dwE, dwF, dwG]));

    until True;
  end;
end;

function StartServer(Port: Integer): Boolean;
var
  _wsdata: WSAData;
  serverSocket, S: TSocket;
  _addrIn, _addr: sockaddr_in;
  addrSize: Integer;
  tid: Cardinal;
begin
  Result := False;

  if WSAStartup(MakeWord(2, 2), _wsdata) <> 0 then
    Exit;

  serverSocket := socket(AF_INET, SOCK_STREAM, 0);

  if serverSocket = INVALID_SOCKET then
    Exit;

  _addrIn.sin_family := AF_INET;
  _addrIn.sin_addr.S_addr := INADDR_ANY;
  _addrIn.sin_port := htons(Port);

  if bind(serverSocket, _addrIn, SizeOf(_addrIn)) = SOCKET_ERROR then
    Exit;

  if listen(serverSocket, SOMAXCONN) = SOCKET_ERROR then
    Exit;

  addrSize := SizeOf(_addrIn);
  getsockname(serverSocket, _addrIn, addrSize);

  Writeln(Format('Listening on port %d.' + #13, [ntohs(_addrIn.sin_port)]));

  while True do
  begin
    S := accept(serverSocket, @_addr, @addrSize);
    CreateThread(nil, 0, @ClientThread, Pointer(S), 0, tid);
  end;

  Result := True;
end;

begin
  try
    if not StartServer(5099) then
      Writeln(SysErrorMessage(WSAGetLastError));
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  Readln;

end.
Стоит ли изучать PHP в 2023-2024 годах?
Стоит ли изучать PHP в 2023-2024 годах?
Привет всем, сегодня я хочу высказать свои соображения по поводу вопроса, который я уже много раз получал в своем сообществе: "Стоит ли изучать PHP в...
Поведение ключевого слова "this" в стрелочной функции в сравнении с нормальной функцией
Поведение ключевого слова "this" в стрелочной функции в сравнении с нормальной функцией
В JavaScript одним из самых запутанных понятий является поведение ключевого слова "this" в стрелочной и обычной функциях.
Приемы CSS-макетирования - floats и Flexbox
Приемы CSS-макетирования - floats и Flexbox
Здравствуйте, друзья-студенты! Готовы совершенствовать свои навыки веб-дизайна? Сегодня в нашем путешествии мы рассмотрим приемы CSS-верстки - в...
Тестирование функциональных ngrx-эффектов в Angular 16 с помощью Jest
В системе управления состояниями ngrx, совместимой с Angular 16, появились функциональные эффекты. Это здорово и делает код определенно легче для...
Концепция локализации и ее применение в приложениях React ⚡️
Концепция локализации и ее применение в приложениях React ⚡️
Локализация - это процесс адаптации приложения к различным языкам и культурным требованиям. Это позволяет пользователям получить опыт, соответствующий...
Пользовательский скаляр GraphQL
Пользовательский скаляр GraphQL
Листовые узлы системы типов GraphQL называются скалярами. Достигнув скалярного типа, невозможно спуститься дальше по иерархии типов. Скалярный тип...
1
0
166
1
Перейти к ответу Данный вопрос помечен как решенный

Ответы 1

Ответ принят как подходящий

У вас несоответствие размера данных в клиенте и сервере.

type
  Connection = (Desktop, _Input);

Размер перечисления по умолчанию в Delphi равен byte. Это само по себе нормально, но вы обрабатываете их по-разному в клиенте и на сервере.

Вы отправляете с клиента, используя функцию SendInt(), которая преобразуется в целое число.

На стороне сервера вы получаете его как SizeOf(_connection), который представляет собой всего лишь байт. Из-за порядка байтов 1 остается в буфере и позже считывается в dwC.

Вы можете исправить ошибку, установив Minimum enum size в параметрах проекта на doubleword или отправив в виде байта.


Редактировать после комментария

Ведь у вас тоже другая ошибка, а может недоразумение.

От клиента, которого вы отправляете

SendInt(Sock, Ord(Connection._Input))

который принимается сервером как

var
  Check: BOOL;
....
  recv(Sock, Check, SizeOf(Check), 0) , 

Потом пишешь как

Writeln(BoolToStr(Check)); 

и консоль показывает «-1». Но это не ошибка, это задокументировано:

System.SysUtils.BoolToStr

Value of B  Value of UseBoolStrs  Value of returned string  
  true        false                 '-1' 

Возможно, вы хотите вместо этого показать его как значение перечисления.

спасибо за ответ, но эти предложения не сработали на 100%. Я получаю -1 вместо 1.

BrowJr 29.04.2019 14:39
"by setting Minimum enum size in project options to doubleword" сработал. Тогда кажется, что проблема, связанная с этим вопросом, связана с IDE, потому что у меня есть аналогичный код на С++, скомпилированный с VS2013, и этого не происходит.
BrowJr 29.04.2019 17:08

Я не уверен, что понимаю, что вы имеете в виду, ссылаясь на код C++ и VS2013? Но, если на этот вопрос теперь есть ответ, вы знаете, что делать ;-)

Tom Brunberg 29.04.2019 17:18

Другие вопросы по теме