XSL: преобразование неизвестного количества дочерних узлов в CSV
Я пытаюсь преобразовать тело SOAP XML в файл CSV. Я не могу быть уверен, какие элементы появятся в полезной нагрузке обратно ко мне. Некоторые элементы, такие как ReportResults и все его предки, будут статическими для каждой полезной нагрузки, но появится N число Result, а также N дочерних элементов, описывающих Result. Мне нужно сгенерировать заголовки столбцов, используя имена дочерних элементов в разделе «Результат», даже если я не знаю, сколько элементов появится, а затем мне нужно, чтобы каждый результат был одной строкой данных в файле CSV. Проблема с моим XSL заключается в том, что он извлекает только первый предикат, и я понимаю, почему он это делает, но не понимаю, как это исправить. Я думал, что смогу быть умным и отсортировать количество дочерних элементов, а затем вытащить первый предикат; однако при попытке применить XSL: sort и даже применить шаблоны я не получаю желаемых результатов.
В этом примере XML мой первый результат состоит из 3 элементов. У моего второго 4. Используя мой существующий код, появятся единственные заголовки столбцов: ID, Name, Status. Я бы хотел, чтобы я включил все возможные дочерние элементы, а затем оставил поле пустым, если элемент отсутствует.
Есть какая-то часть этого, которую я не понимаю, чтобы заставить эту работу работать. Любая помощь, которую вы можете оказать, приветствуется.
Желаемый результат
Id, Name, Status, DateAdded, ContactState,LastStatusChangeDate
1,Bob,New,,,
2,Judy,Dead,2020-04-16T17:21:38,,
3,Ann,New,2020-04-16T17:21:38,NC,2020-04-16T18:28:53
Текущий выход
Id, Name, Status
1,Bob,New
2,Judy,Dead,2020-04-16T17:21:38
3,Ann,New,2020-04-16T17:21:38,NC,2020-04-16T18:28:53
Пример полезной нагрузки XML
<?xml version = "1.0" encoding = "utf-8"?>
<soap:Envelope xmlns:soap = "http://schemas.xmlsoap.org/soap/envelope/" xmlns:xsi = "http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd = "http://www.w3.org/2001/XMLSchema">
<soap:Header>
<wsa:MessageID>urn</wsa:MessageID>
</soap:Header>
<soap:Body>
<GetReportResultsResponse xmlns = "https://fakenamespace.com">
<GetReportResultsResult>
<ReportResults reportId = "1" xmlns = "">
<Result>
<Id>1</Id>
<Name>Bob</Name>
<Status>New</Status>
</Result>
<Result>
<Id>2</Id>
<Name>Judy</Name>
<Status>Dead</Status>
<DateAdded>2020-04-16T17:21:38</DateAdded>
</Result>
<Result>
<Id>3</Id>
<Name>Ann</Name>
<Status>New</Status>
<DateAdded>2020-04-16T17:21:38</DateAdded>
<ContactState>NC</ContactState>
<LastStatusChangeDate>2020-04-16T18:28:53</LastStatusChangeDate>
</Result>
</ReportResults >
</GetReportResultsResult>
</GetReportResultsResponse>
</soap:Body>
</soap:Envelope>
XSL-файл
<xsl:stylesheet version = "3.0"
xmlns:xsl = "http://www.w3.org/1999/XSL/Transform"
xmlns:xsd = "http://www.w3.org/2001/XMLSchema"
xmlns:soap = "http://schemas.xmlsoap.org/soap/envelope/">
<xsl:output method = "text" indent = "no"/>
<xsl:variable name = "separator" select = "','" />
<xsl:variable name = "newline" select = "' '" />
<xsl:template match = "/">
<xsl:for-each select = "//Result[1]/*">
<xsl:value-of select = "name()"/><xsl:if test = "position() < last()">,</xsl:if>
</xsl:for-each>
<xsl:value-of select = "$newline" />
<xsl:for-each select = "//Result">
<xsl:for-each select = "*">
<xsl:value-of select = "text()"/><xsl:if test = "position() < last()">,</xsl:if>
</xsl:for-each>
<xsl:value-of select = "$newline" />
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
Ответы 2
Я бы сделал это так:
<xsl:variable name = "columns" select = "distinct-values(//Result/*/local-name())"/>
<xsl:template match = "Result">
<xsl:value-of select = "for $col in $columns return string(*[local-name() = $col])" separator = ","/>
<xsl:text> </xsl:text>
</xsl:template>
См. более полный пример на xsltfiddle.liberty-development.net/bEJbVrp, мне пришлось исправить ввод XML, чтобы объявить пространство имен и избежать вывода из других элементов, я использовал strip-space и установил режим по умолчанию для пропуска но затем опубликованный код выводит три строки CSV.
Спасибо! Я смог манипулировать им, чтобы создать заголовки столбцов, основываясь на том, что вы мне дали. Так что это работает, но теперь мне нужно многое изучить, чтобы понять, что, черт возьми, здесь происходит на самом деле. Спасибо, что указали мне правильное направление.
Решено
<?xml version = "1.0" encoding = "UTF-8"?>
<xsl:stylesheet xmlns:xsl = "http://www.w3.org/1999/XSL/Transform"
xmlns:xs = "http://www.w3.org/2001/XMLSchema"
exclude-result-prefixes = "#all"
version = "3.0">
<xsl:output method = "text"/>
<xsl:strip-space elements = "*"/>
<xsl:mode on-no-match = "shallow-skip"/>
<xsl:variable name = "columns" select = "distinct-values(//Result/*/local-name())"/>
<xsl:template match = "/">
<xsl:value-of select = "$columns" separator = ","/>
<xsl:text> </xsl:text>
<xsl:apply-templates select = "//ReportResults/Result" />
</xsl:template>
<xsl:template match = "Result">
<xsl:value-of select = "for $col in $columns return string(*[local-name() = $col])" separator = ","/>
<xsl:text> </xsl:text>
</xsl:template>
</xsl:stylesheet>
Может быть, я не следую здесь должным образом, но когда я удаляю весь свой другой шум, чтобы попытаться создать только первую строку заголовков, что, как я полагаю, вы сделали здесь, у меня ничего не генерируется. ``` <xsl:stylesheet version = "3.0" > <xsl:output method = "text" indent = "no"/> <xsl:variable name = "columns" select = "distinct-values(//Result/* /local-name())"/> <xsl:template match = "Result"> <xsl:value-of select = "for $col in $columns return string(*[local-name() = $col]) " separator = ","/> <xsl:text> </xsl:text> </xsl:template> </xsl:stylesheet> ```