Заполнение ListBox. «Ошибка выполнения '380': не удалось установить свойство List. Недопустимое значение свойства»

• Существует ограничение на использование несвязанного источника данных в ListBox. Максимальное количество столбцов — 10 (индекс 0–9). Ошибка возникает в i=11 (индекс столбца 10).

• Рассмотрите возможность заполнения списка массивом, особенно если вы имеете дело с более чем 10 столбцами.

Option Explicit
Private Sub FilterPopulateListBox()
    Dim PSelectedAssessor As String
    PSelectedAssessor = CmbAssessors.Value  ' Get the currently selected assessor's name
    Dim PWs As Worksheet
    Set PWs = ThisWorkbook.Sheets(1) ' modify as needed
    Dim PLastRow As Long
    PLastRow = PWs.Cells(PWs.Rows.Count, "B").End(xlUp).Row
    Dim PData As Range
    Set PData = PWs.Range("B3:P" & PLastRow)
    Dim arrRes(), iR As Long, i As Integer
    ReDim arrRes(1 To 15, 1 To PData.Rows.Count)
    ' Clear previous entries in the ListBox
    With lstEvaluations
        .Clear
        .ColumnCount = 15  ' Assuming there are 15 columns from B to P
        .ColumnWidths = "50;50;50;50;50;50;50;50;50;50;50;50;50;50;50"
        Debug.Print lstEvaluations.ColumnCount  ' Should print 15
        ' Loop through each row in the range and add to ListBox if the fourth column matches
        Dim PRow As Range
        For Each PRow In PData.Rows
            If PRow.Cells(1, 4).Value = PSelectedAssessor Then  ' Check if fourth column matches the ComboBox
                Dim PRowArray() As Variant
                PRowArray = Application.Transpose(Application.Transpose(PRow.Value))
                iR = iR + 1
                For i = 1 To UBound(PRowArray)  ' Add other columns
                    arrRes(i, iR) = CStr(PRowArray(i))
                Next i
            End If
        Next PRow
        If iR > 0 Then
            ReDim Preserve arrRes(1 To 15, 1 To iR)
            .Column = arrRes
        End If
    End With
End Sub

Пользовательская форма имеет не только встроенное ограничение в 10 столбцов при использовании метода .AddItem. Он даже игнорирует это, когда для свойства .ColumnWidth явно установлено большее количество столбцов — он принимает начальное значение в 10 столбцов, что приводит только к ошибке 380 (невозможно установить свойство List — неверное значение свойства).

Обычно это ограничение можно обойти двумя способами:

• 1. Во-первых, путем присвоения 2D-массива свойству .List (или .Column) — это называется методом массива, ср. мой предыдущий пост Заполните список несколькими столбцами для получения более подробной информации.
• 2. Если вы придерживаетесь .AddItem, вы можете получить выгоду от минимального присвоения массива свойству .List на основе фактического количества столбцов с помощью следующей процедуры в качестве начального шага кода после определения нужного количества столбцов:

Sub fixColumnCount(lbx As MSForms.ListBox, ByVal colCnt As Long)
'Auth.: T.M. (c) 2023-08
'Purp.: fix ColumnCount to an exact number (even greater than default of 10 cols) !!!!!!!!!!!!!
'Note:  example call (here: to number of column captions (Row 1:1) in given range)
'       fixColumnCount Me.ListBox1, rng.Columns.Count + 1

    With lbx
        .ColumnCount = colCnt
         '.Column = Split(String(.ColumnCount, " "), " ")
        .Column = Split(Space(.ColumnCount))       ' assign initial Array of empty strings to .Column prop
        .Clear
    End With
End Sub