Зиг `Ошибка сегментации по адресу` в цикле при выделении и копировании структуры

Ваша ошибка в том, что вы сохраняете в результате строки из JSON, но эти строки освобождаются вместе с JSON.

Например:

options.source_type = _new_json.source_type;

Это должно быть:

options.source_type = try allocator.dupe(u8, _new_json.source_type);

Вам нужно будет освободить от опций не только опции, но и отдельные строки. Для этого вы можете добавить функцию в свой BabelOptions.

И я бы рекомендовал:

• Просто верните структуру из функции from_test_path вместо возврата указателя на структуру. Возврат указателя ограничивает возможности действий со структурой.
• Добавляйте errdefer после каждого распределения, которое иначе не имеет defer.
• Используйте только один ArrayList для плагинов вместо выделения нескольких в if.
• В readJsonFiledefer для source должен появляться сразу после выделения, а не после чтения. В противном случае, если чтение не удастся, source не будет освобожден.
• Проверьте наличие утечек памяти с помощью defer std.debug.assert(gpa.deinit() == .ok);

Это будет выглядеть примерно так:

const std = @import("std");
const fs = std.fs;
const Allocator = std.mem.Allocator;

const string = []const u8;
const BabelOptions = struct {
    source_type: ?string = null,
    throws: ?string = null,
    plugins: ?[]string = null,

    pub fn free(self: BabelOptions, allocator: Allocator) void {
        if (self.source_type) |source_type| {
            allocator.free(source_type);
        }
        if (self.throws) |throws| {
            allocator.free(throws);
        }
        if (self.plugins) |plugins| {
            for (plugins) |plugin| {
                allocator.free(plugin);
            }
            allocator.free(plugins);
        }
    }

    pub fn from_test_path(path: string, allocator: Allocator) !BabelOptions {
        var options: BabelOptions = .{};
        errdefer options.free(allocator);
        var plugin_list = std.ArrayList([]const u8).init(allocator);
        errdefer {
            for (plugin_list.items) |plugin| {
                allocator.free(plugin);
            }
            plugin_list.deinit();
        }

        var dir = try std.fs.cwd().openDir(path, .{});
        defer dir.close();

        for (0..3) |_| {
            const realpath = try dir.realpathAlloc(allocator, ".");
            defer allocator.free(realpath);
            const file: ?std.fs.File = dir.openFile("options.json", .{}) catch null;
            if (file == null) {
                std.debug.print("No options.json found in {s}\n", .{realpath});
                continue;
            }

            const new_json = try readJsonFile(BabelOptions, file.?, allocator);
            defer new_json.deinit();
            const _new_json = new_json.value;

            if (options.source_type == null and _new_json.source_type != null) {
                options.source_type = try allocator.dupe(u8, _new_json.source_type.?);
            }
            if (options.throws == null and _new_json.throws != null) {
                options.throws = try allocator.dupe(u8, _new_json.throws.?);
            }
            if (_new_json.plugins) |plugins| {
                for (plugins) |plugin| {
                    try plugin_list.append(try allocator.dupe(u8, plugin));
                }
            }
            dir = try dir.openDir("..", .{});
        }
        options.plugins = try plugin_list.toOwnedSlice();
        return options;
    }
};

fn readJsonFile(T: type, file: std.fs.File, allocator: Allocator) !std.json.Parsed(T) {
    const file_size = try file.getEndPos();
    const source = try allocator.alloc(u8, file_size);
    defer allocator.free(source);
    _ = try file.readAll(source);

    return try std.json.parseFromSlice(T, allocator, source, .{ .ignore_unknown_fields = true, .allocate = .alloc_always });
}

pub fn main() !void {
    var gpa = std.heap.GeneralPurposeAllocator(.{}){};
    defer std.debug.assert(gpa.deinit() == .ok);
    const allocator = gpa.allocator();

    const path = "src/test/fixtures/babel/t0/t1/t2";
    const options = try BabelOptions.from_test_path(path, allocator);
    defer options.free(allocator);

    std.log.debug("source_type: {any}", .{options.source_type});
}