Delphi Рассчитать возраст человека из компонента TDateEdit

Вы можете использовать функцию YearsBetween() из модуля System.DateUtils, чтобы вычислить количество лет между сегодняшним днем ​​(которое вы получаете из функции сейчас) и датой в вашем компоненте TDateEdit, которую вы получаете из свойства даты.

Label1.Text:= Trunc(YearsBetween(Now,DateEdit1.Date)).toString;

Вот функция для вычисления чьего-то возраста.

Она заметно отличается от функции RTL ГодыМежду, поскольку вычисляет количество лет между двумя датами; и принципиально не совпадает с чьим-то возрастом.

function GetAge(const BirthDate, CurrentDate: TDateTime): Integer;
var
    y1, m1, d1: Word; //born
    y2, m2, d2: Word; //today
begin
    Result := 0;

    if CurrentDate < BirthDate then
        Exit;

    DecodeDate(BirthDate, y1, m1, d1);
    DecodeDate(CurrentDate, y2, m2, d2);

    //Fudge someone born on the leap-day to Feb 28th of the same year
    //strictly for the purposes of this calculation
    if ( (m1=2) and (d1=29) )
            and
        ( not IsLeapYear(y2) ) then
    begin
        d1 := 28;
    end;

    Result := y2-y1; //rough count of years
    //Take away a year of the month/day is before their birth month/day
    if (m2 < m1) or
            ((m2=m1) and (d2<d1)) then
        Dec(Result);
end;

Я предпочитаю ответ Яна Бойда, но для тех, кто настаивает на том, что YearsBetween - это правильный путь, вот альтернатива.

Если Y является результатом YearsBetween, то правильным результатом будет либо Y, либо Y+1. Эта подпрограмма вызывает YearsBetween и возвращает Y+1. Затем он использует IncYear, чтобы проверить, не слишком ли велик ответ. Если это так, он возвращает Y.

Это может показаться проще, но за кулисами происходит гораздо больше работы. Ответ Яна Бойда - это тот, который вы должны использовать.

function AgeInCompleteYears ( const nBirthDate   : tDateTime;
                              const nCurrentDate : tDateTime  ) : integer;
begin
  Result := 1 + DateUtils.YearsBetween ( nCurrentDate, nBirthDate );
  if DateUtils.IncYear ( nBirthDate, Result ) > nCurrentDate then
    dec ( Result );
end;

function GetAge(BirthDate:TDateTime; RefDate:TDateTime=0):Integer;
begin
  if RefDate=0 then RefDate:= Today;
  Result := Trunc((RefDate- BirthDate) / 365.25)
end;