Gnuplot сохраняет вывод команды в переменную

Раньше мне также хотелось, чтобы некоторые параметры, которые можно отображать с помощью show ..., можно было поместить в переменную. Я не знаю, можно ли это легко сделать с помощью gnuplot сейчас, но, может быть, в будущем?

Насколько я понимаю, ваш вопрос вы хотите узнать в сценарии, установлено ли xdata на time или нет. Если вы отметите help xdata, настройка может быть time или numeric.

Один из возможных обходных путей, чтобы выяснить это:

• вы можете сохранить текущий скрипт в текстовый файл с помощью save (отметьте help save), очевидно, вы не можете сохранить его в блоке данных.
• проанализируйте этот текстовый файл, чтобы узнать, установлено ли для xdata значение timedata. Если установлено время, то строка для поиска — это set xdata time, а если она установлена ​​на числовую, строка — это только set xdata, что немного усложняет извлечение (возможно, есть более простой способ). Файл будет выглядеть так:

#    
#       G N U P L O T
#       Version 6.0 patchlevel 0    last modified 2023-12-09 
#    
#       Copyright (C) 1986-1993, 1998, 2004, 2007-2023
#       Thomas Williams, Colin Kelley and many others
#    
#       gnuplot home:     http://www.gnuplot.info
#       faq, bugs, etc:   type "help FAQ"
#       immediate help:   type "help"  (plot window: hit 'h')
# set terminal qt 0 font "Sans,10"
# set output
unset clip points
set clip one
unset clip two
unset clip radial
set errorbars front 1.000000 
set border 31 front lt black linewidth 1.000 dashtype solid
set cornerpoles
set zdata 
set ydata 
set xdata time
set y2data 
set x2data 
set boxwidth
set boxdepth 0
set style fill  empty border
...

К сожалению, gnuplot не предназначен для парсинга, но вы, тем не менее, можете это сделать.

Скрипт: (требуется gnuplot>=6.0 из-за функционального блока)

### return setting for xdata
reset session

function $xdata(none) <<EOF
    FILE = "Settings.txt"
    save FILE 
    set table $Dummy
        plot FILE u 0:(strcol(2) eq "xdata" ? \
             XDATA=(strlen(' '.strcol(3))>3 ? "time" : "numeric") : 0) w table
    unset table
    return XDATA
EOF

set xdata
print $xdata(0)

set xdata time
print $xdata(0)
### end of script

Результат:

numeric
time

Скрипт: (требуется gnuplot>=5.0.0 из-за блоков данных)

### return setting for xdata
reset session

set xdata
FILE = "SO78723633.txt"
save FILE 
set table $Dummy
    plot FILE u 0:(strcol(2) eq "xdata" ? \
         XDATA=(strlen(' '.strcol(3))>3 ? "time" : "numeric") : 0) w table
unset table
print XDATA

set xdata time
FILE = "SO78723633.txt"
save FILE 
set table $Dummy
    plot FILE u 0:(strcol(2) eq "xdata" ? \
         XDATA=(strlen(' '.strcol(3))>3 ? "time" : "numeric") : 0) w table
unset table
print XDATA
### end of script

Результат:

numeric
time

Добавление:

Как упоминалось в комментариях, вышеуказанные решения зависят от настройки разделителя файлов данных. Если это было установлено, например. set datafile separator comma эти решения не сработают.

Следовательно, вот решение, которое использует системно-зависимый вызов, однако оно работает под Windows без предварительной установки некоторых утилит, таких как grep, gawk, coreutils и т. д. Сохраненный файл сценария считывается 1:1 в блок данных., а затем проверил через strstrt() (отметьте help strstrt).

Скрипт: (требуется gnuplot>=5.2.0 из-за индексации блоков данных)

set xdata time     # e.g. set in the caller script

TEMP = "Temp.txt"
save TEMP
FileToDatablock(f,d) = GPVAL_SYSNAME[1:7] eq "Windows" ? \
                       sprintf('< echo   %s ^<^<EOD  & type "%s"',d,f) : \
                       sprintf('< echo "\%s   <<EOD" & cat  "%s"',d,f) # Linux/MacOS
load FileToDatablock(TEMP,'$Settings')

do for [i=1:|$Settings|] {
    if (strstrt($Settings[i],'set xdata')==1) { XDATA = $Settings[i] }
}
print XDATA

Результат:

set xdata time

Простой ответ, если вы не против создать временный файл с помощью стандартных команд оболочки *nix.

gnuplot> set xdata time
gnuplot> tempfile = system("mktemp")
gnuplot> save tempfile
gnuplot> query = "grep 'set xdata' " . tempfile
gnuplot> response = system(query)
gnuplot> print response
set xdata time