Имя хоста виртуальной машины Azure не меняется в terraform

Имя хоста виртуальной машины Azure не меняется в terraform.

Я создал Rocky Linux VM, используя собственное изображение, и оно берет указанный computer_name из кода Terraform.

В вашем случае он принимает еще один computer name, что может указывать на то, что он не использует текущую конфигурацию Terraform. Проверьте план перед его применением, а также удалите все ранее созданные файлы состояния перед повторным запуском кода.

provider "azurerm" {
  features {}
}

data "azurerm_resource_group" "example" {
  name     = "RG-Name"
}

resource "azurerm_virtual_network" "example" {
  name                = "rockyvnet"
  address_space       = ["10.0.0.0/16"]
  location            = data.azurerm_resource_group.example.location
  resource_group_name = data.azurerm_resource_group.example.name
lifecycle  {
    prevent_destroy = true
    }
}

resource "azurerm_subnet" "example" {
  name                 = "rocky-subnet"
  resource_group_name  = data.azurerm_resource_group.example.name
  virtual_network_name = azurerm_virtual_network.example.name
  address_prefixes     = ["10.0.1.0/24"]
lifecycle  {
    prevent_destroy = true
    }
}

resource "azurerm_network_interface" "example" {
  name                = "rockyvm-nic"
  location            = data.azurerm_resource_group.example.location
  resource_group_name = data.azurerm_resource_group.example.name

  ip_configuration {
    name                          = "internal"
    subnet_id                     = azurerm_subnet.example.id
    private_ip_address_allocation = "Dynamic"
  }
lifecycle  {
    prevent_destroy = true
    }
}

resource "azurerm_linux_virtual_machine" "example" {
  name                = "Linuxvm-Rocky"
  source_image_id     = "/subscriptions/11111b-b5ba-21111111/resourceGroups/RG-name/providers/Microsoft.Compute/galleries/Venkatgallery/images/Venkat-Image"
  resource_group_name = data.azurerm_resource_group.example.name
  location            = data.azurerm_resource_group.example.location
  size                = "Standard_D2s_v5"
  network_interface_ids = [
    azurerm_network_interface.example.id,
  ]
  identity {
    type = "SystemAssigned"
  }

  computer_name      = "Rockylinuxvm"
  admin_username      = "adminuser"
  admin_password      = "Welcome@123$"
  disable_password_authentication = false

  os_disk {
    name                 = "rockyosdisk"
    caching              = "ReadWrite"
    storage_account_type = "Standard_LRS"
    disk_size_gb         = "128"
  }



  plan {
    name      = "8-base"
    publisher = "resf"
    product   = "rockylinux-x86_64"
  }
  lifecycle  {
    prevent_destroy = true
    }
}

Терраформирование Применить

Имя хоста виртуальной машины

Если он по-прежнему использует имя по умолчанию, вы можете изменить имя хоста с помощью команды sudo hostnamectl set-hostname Linux-RockyVM с расширением виртуальной машины.

resource "azurerm_virtual_machine_extension" "example" {
  name                 = "hostname"
  virtual_machine_id   = azurerm_linux_virtual_machine.example.id
  publisher            = "Microsoft.Azure.Extensions"
  type                 = "CustomScript"
  type_handler_version = "2.0"

  settings = <<SETTINGS
 {
  "commandToExecute": "sudo hostnamectl set-hostname Linux-RockyVM && sudo systemctl restart"
 }
SETTINGS
}

После выполнения VM Extension имя хоста было успешно изменено.

Ссылка: azurerm_virtual_machine_extension

Спасибо всем, кто помог. Я хотел бы объединить свои мнения и использовать код, измененный следующим образом. Я не знаю, лучший это способ или нет, но я уверен, что он в любом случае соответствует требованиям. Ниже приведен модифицированный код. Если у вас есть лучшее мнение, я был бы очень признателен, если бы вы сообщили мне об этом.

resource "azurerm_virtual_machine_extension" "run_command" {
  for_each             = var.vm_template
  name                 = "${each.value.vm_name}-run_command"
  virtual_machine_id   = azurerm_linux_virtual_machine.vm[each.key].id
  publisher            = "Microsoft.Azure.Extensions"
  type                 = "CustomScript"
  type_handler_version = "2.0"
  timeouts {
    create = "1h"
  }
  settings = <<SETTINGS
 {
  "commandToExecute": "bash -c 'hostnamectl set-hostname --static ${each.value.hostname}'"
 }
SETTINGS
}