Вы можете добавить уникальные ключи в структуру данных:

locals {
  instances = csvdecode(file("myDnsRecords.csv"))
  instance_map = zipmap(range(0,length(local.instances)), local.instances)
}

 resource "..." "..." {
   for_each = local.instance_map
   ...
 }

Получает ли это то, что вы ищете?

Набор данных

RecordName,Type,Value
,A,1.2.3.4
,A,2.3.4.5
test,A,3.4.5.6
test,A,4.5.6.7
www,cname,example.com

main.tf

locals {
  records = [for pref in {for _, key in distinct([for i, v in csvdecode(file("myDnsRecords.csv")): v.RecordName]): key => [for r in csvdecode(file("myDnsRecords.csv")): r if key == r.RecordName]}: {for i, r in pref: ("${r.RecordName}_${i}") => r}]
}

output "test" {
  value = local.records
}

Выход

Changes to Outputs:
  + test = [
      + {
          + _0 = {
              + RecordName = ""
              + Type       = "A"
              + Value      = "1.2.3.4"
            }
          + _1 = {
              + RecordName = ""
              + Type       = "A"
              + Value      = "2.3.4.5"
            }
        },
      + {
          + test_0 = {
              + RecordName = "test"
              + Type       = "A"
              + Value      = "3.4.5.6"
            }
          + test_1 = {
              + RecordName = "test"
              + Type       = "A"
              + Value      = "4.5.6.7"
            }
        },
      + {
          + www_0 = {
              + RecordName = "www"
              + Type       = "cname"
              + Value      = "example.com"
            }
        },
    ]

You can apply this plan to save these new output values to the Terraform state, without changing any real infrastructure.

Выражения Terraform for при построении сопоставления имеют «режим группировки», в котором он позволяет дублировать ключи в обмен на значения карты, все из которых представляют собой списки потенциально множественных значений, которые все имеют один и тот же ключ.

Поэтому я бы начал с использования этого для проецирования данных CSV в значение map(list(map(string))), где ключи строятся из имени и типа записи, например:

locals {
  records_raw = csvdecode(file("${path.module}/myDnsRecords.csv"))

  records_grouped = tomap({
    for row in local.records_raw :
    "${row.RecordName} ${row.RecordType}" => row...
  })
}

Результирующая структура данных будет иметь следующую форму:

records_grouped = tomap({
  " A" = tolist([
    { RecordName = "", Type = "A", Value = "1.2.3.4" },
    { RecordName = "", Type = "A", Value = "2.3.4.5" },
  ])
  "test A" = tolist([
    { RecordName = "test", Type = "A", Value = "3.4.5.6" },
    { RecordName = "test", Type = "A", Value = "4.5.6.7" },
  ])
  "www CNAME" = tolist([
    { RecordName = "www", Type = "CNAME", Value = "example.com" },
  ])
})

Сбор записей с общими ключами в списки означает, что теперь у нас есть индекс списка для каждой из них, уникальный только в пределах записей с общим ключом.

Итак, теперь мы можем спроецировать это еще раз на плоскую карту карт (map(map(string))), включив эти индексы списка в ключи карты:

locals {
  records = tomap(merge([
    for group_key, group in local.records_grouped : {
      for idx, record in group :
      "${group_key} ${idx}" => group
    } 
  ]...))
}

Это должно создать структуру данных, подобную следующей:

records = tomap({
  " A 0"        = { RecordName = "", Type = "A", Value = "1.2.3.4" }
  " A 1"        = { RecordName = "", Type = "A", Value = "2.3.4.5" }
  "test A 0"    = { RecordName = "test", Type = "A", Value = "3.4.5.6" }
  "test A 1"    = { RecordName = "test", Type = "A", Value = "4.5.6.7" }
  "www CNAME 0" = { RecordName = "www", Type = "CNAME", Value = "example.com" }
})

Эта структура данных имеет подходящую форму для выражения for_each, поэтому, наконец:

resource "aws_route53_record" "example" {
  for_each = local.records

  name    = "${each.value.RecordName}${each.value.RecordName == "" ? "" : "."}${var.domainname}"
  type    = each.value.Type
  zone_id = aws_route53_zone.zone.zone_id
  ttl     = 3600
  records = [each.value.Value]
}

Это создаст уникальные ключи экземпляра для каждой записи в исходном CSV-файле, сохраняя при этом все отдельные пары (имя, тип) разделенными, чтобы вы могли добавлять новые, не нарушая существующие записи:

• aws_route53_record.example[" A 0"]
• aws_route53_record.example[" A 1"]
• aws_route53_record.example["test A 0"]
• ...и т. д

Вы упомянули о необходимости отдельного экземпляра для каждой строки в вашем CSV-файле, но я также хотел отметить, что тип ресурса aws_route53_record уже предназначен для управления несколькими записями с одинаковым именем и типом вместе, и поэтому я думаю, что на самом деле было бы неплохо оставить записи сгруппированы вместе. (Название `aws_route53_record немного неправильное, поскольку каждый экземпляр этого типа ресурса управляет набором записей, а не одной записью.)

Вот вариант, который работает таким образом:

locals {
  records_raw = csvdecode(file("${path.module}/myDnsRecords.csv"))

  record_groups = tomap({
    for row in local.records_raw :
    "${row.RecordName} ${row.RecordType}" => row...
  })
  recordsets = tomap({
    for group_key, group in local.record_groups : group_key => {
      name   = group[0].Name
      type   = group[0].Type
      values = group[*].Value
    } 
  })
}

resource "aws_route53_record" "example" {
  for_each = local.recordsets

  name    = "${each.value.name}${each.value.name == "" ? "" : "."}${var.domainname}"
  type    = each.value.type
  zone_id = aws_route53_zone.zone.zone_id
  ttl     = 3600
  records = each.value.values
}

На этот раз окончательная карта имеет один элемент на набор записей вместо одного элемента на запись после группировки всех отдельных записей вместе с использованием их имен и типов. Теперь вам вообще не нужны синтетические индексы, потому что пара имени и типа является естественным уникальным идентификатором для набора записей Route53.