Как использовать CStruct

Интерфейс NativeCall требует, чтобы транзакции C-структур выполнялись с указателями:

Объекты CStruct передаются собственным функциям по ссылке, и собственные функции также должны возвращать объекты CStruct по ссылке.

Однако ваша функция C возвращает новую структуру по значению. Затем, я думаю, это пытаются интерпретировать как адрес памяти, так как он ожидает указатель и пытается читать/записывать из диких областей памяти, отсюда и segfault.

Вы можете указать свою функцию как:

struct MyStruct* newstruct(int32_t val) {
    /* dynamically allocating now */
    struct MyStruct *stru = malloc(sizeof *stru);
    stru->member = val;
    return stru;
}

с #include <stdlib.h> в самом верху для malloc. Программа Raku, по сути, такая же по модулю некоторой эстетики:

# prog.raku
use NativeCall;

my constant LIB = "./libstruct.so";

class MyStruct is repr("CStruct") {
    has int32 $.member;
}

# C bridge
sub newint(int32) returns int32 is native(LIB) { * }
sub newstruct(int32) returns MyStruct is native(LIB) { * }

say newint(42);

my $s := newstruct(84);
say $s;
say $s.member;

Мы собираем библиотеку и запускаем программу Raku, чтобы получить

$ gcc -Wall -Wextra -pedantic -shared -o libstruct.so -fPIC mod_struct.c
$ raku prog.raku
42
MyStruct.new(member => 84)
84

(взял на себя смелость переименовать файл C в «mod_struct.c»)

Выглядит неплохо. Но есть проблема: теперь, когда динамическое распределение было сделано, возникает ответственность за его возврат. И нам нужно сделать это самостоятельно с C-мостовым фризером:

Когда тип на основе CStruct используется в качестве возвращаемого типа собственной функции, сборщик мусора не управляет памятью.

Так

/* addendum to mod_struct.c */
void free_struct(struct MyStruct* s) {
    free(s);
}

Отметив, что, поскольку сама структура не имеет динамических распределений для своих членов (поскольку она имеет только целое число), мы не делали дальнейшего освобождения.

Теперь программа Raku должна знать об этом и использовать это:

# prog.raku
use NativeCall;

my constant LIB = "./libstruct.so";

class MyStruct is repr("CStruct") {
    has int32 $.member;
}

# C bridge
sub newint(int32) returns int32 is native(LIB) { * }
sub newstruct(int32) returns MyStruct is native(LIB) { * }
sub free_struct(MyStruct) is native(LIB) { * };   # <-- new!

say newint(42);

my $s := newstruct(84);
say $s;
say $s.member;

# ... after some time
free_struct($s);
say "successfully freed struct";

и вывод следует как

42
MyStruct.new(member => 84)
84
successfully freed struct

Вручную отслеживать объекты MyStruct, чтобы помнить об их освобождении через некоторое время, может быть обременительно; это будет писать C! На уровне Раку у нас уже есть класс, представляющий структуру; то мы можем добавить к нему подметод DESTROY, который освобождает себя всякий раз, когда сборщик мусора сочтет это необходимым:

class MyStruct is repr("CStruct") {
    has int32 $.member;

    submethod DESTROY {
        free_struct(self);
    }
}

С этим дополнением не требуются ручные вызовы free_struct (на самом деле, лучше этого не делать, потому что это может привести к двойному освобождению, что является неопределенным поведением на уровне C).

P.S. ваш основной файл C может быть пересмотрен, например, файл заголовка кажется в порядке, но это выходит за рамки или это был только демонстративный пример, кто знает. В любом случае, спасибо за предоставление MRE и добро пожаловать на сайт.

В дополнение к отличному ответу @Mustafa.

Я нашел другой способ решить свою проблему: мы можем выделить структуру в raku и передать ее функции C. Вот пример, файл mod_struct.c:

#include <stdint.h>

struct MyStruct {
    int32_t member;
};
void writestruct(struct MyStruct *outputStruct, int32_t arg) {
    outputStruct->member = arg;
}

Файл usestruct.raku:

#!/bin/env raku
use NativeCall;

class MyStruct is repr('CStruct') {
    has int32 $.member;
}
sub writestruct(MyStruct is rw, int32) is native('./libstruct.so') { * }

my $myStruct = MyStruct.new;
writestruct($myStruct, 42);
say $myStruct.member;

Скомпилируйте и запустите его:

$ gcc -Wall -Wextra -pedantic -shared -o libstruct.so -fPIC mod_struct.c
$ ./usestruct.raku
42