Как мой код может узнать, работает ли он как VBScript, .HTA или VBA?

У всех программ есть хост, который предоставляет как минимум глобальный объект Application. WScript предоставляет глобальный WScript, Word/Excel — объект Application, HTA — объект IE Window (который через родительское свойство дает доступ к объекту InternetExplorer.Application.

В COM мы вызываем QueryRef для интерфейса IUnknown, чтобы узнать, какие у него есть объекты. Это происходит под капотом. Принципиал заключается в том, что вы пытаетесь использовать его и ищете ошибку, которая говорит о свойстве E_Not_Implemented.

Это стандарт того, что должно быть в объекте приложения https://docs.microsoft.com/en-au/previous-versions/windows/desktop/automat/using-the-application-object-in-a-type-library.

Итак, wscript.name, InternetExplorer.Application.Name и Word.Application.Name.

В Wscript этот код печатает Windows Scripting Host. В Word печатает Normal 424 Object Required. В HTA Microsoft VBScript runtime error 424 Object required.

On Error Resume Next
x = wscript.name
If err.Number = 0 then
    Msgbox x
Else
    Msgbox err.source & " " & err.number & " " & err.description
End If

Аналогично в Word Microsoft Word, VBS Microsoft VBScript runtime error 424 Object required и HTA Microsoft VBScript runtime error 424 Object required.

On Error Resume Next
x = Application.Name
If Err.Number = 0 Then
    MsgBox x
Else
    MsgBox Err.Source & " " & Err.Number & " " & Err.Description
End If

Также обратите внимание, что тестирование приложения определено или не является надежным. В Excel также есть объект Application. Вы должны пройти тест на name.

Попробуйте проверить наличие объектов контекста, например

Function ScriptEngine()
    dim tst
    on error resume next
    Err.Clear
    tst = WScript is Nothing
    if Err=0 then ScriptEngine = "WScript" : exit function
    Err.Clear
' similar way check objects in other environments

End Function

Любая необъявленная переменная будет Variant/Empty, поэтому VarType(something) будет vbEmpty (или 0), если something не определена.

Если VarType не существует вне стандартной библиотеки VBA (я понятия не имею, TBH), то нет необходимости перехватывать/пропускать/обрабатывать какие-либо ошибки, чтобы это работало - проверено в VBA:

Function GetHostType()
    If VarType(wscript) <> vbEmpty Then
        GetHostType = "VBS"
        Exit Function
    End If        
    If VarType(Application) <> vbEmpty Then
        GetHostType = "VBA"
        Exit Function
    End If        
    GetHostType = "HTA"
End Function

Обратите внимание, что это приведет к неожиданным результатам, если, например. Application или WScriptявляется определен где-то, а хост не является VBA или VBScript соответственно.

В качестве альтернативы это будет работать независимо от того, определен ли VarType или нет:

Function GetHostType()
    On Error Resume Next

    If Not WScript Is Nothing Then
        If Err.Number = 0 Then
            GetHostType = "VBS"
            Exit Function
        End If
    End If
    Err.Clear ' clear error 424 if not VBS

    If Not Application Is Nothing Then
        If Err.Number = 0 Then
            GetHostType = "VBA"
            Exit Function
        End If
    End If
    Err.Clear ' clear error 424 if not VBA

    GetHostType = "HTA"
End Function

Снова предполагается, что ни один объект с этими именами не определен; механизм основан на том, что WScript/Application является Variant/Empty и, таким образом, выдает ошибку времени выполнения 424 «Требуется объект» при тестировании с Is Nothing.

Обратите внимание, что для этого нельзя указать Option Explicit. Причина в том, что если вы сделаете Dim WScript и Dim Application, чтобы удовлетворить компилятор, то во время выполнения эти переменные будут затенять глобальные идентификаторы, которые вы проверяете, и функция последовательно вернет тот хост, который вы проверили первым.

Я бы посоветовал вам подойти к проблеме в обратном направлении. Вместо того, чтобы спрашивать «кто здесь хозяин?», у вас должен быть общий интерфейс для задач. Например, у вас будет модуль - назовем его MyAPI:

Public Function MySleep(Milliseconds As Long)
End Function

Затем вы можете реализовать один для VBA, один для VBS, другой для HTA ​​(хотя я сомневаюсь, есть ли реальная разница. Тогда ваш код, не зависящий от хоста, потребует включения того модуля, который все должны разрешать. Например, см. здесь для включения файла в VBS. Это также выглядит как В HTA есть что-то подобное В VBA это просто еще один модуль.

Затем в коде независимого хоста вы должны вызывать MySleep вместо объявленных в API Sleep или WScript.Sleep и позволить включенному модулю предоставлять специфичную для хоста реализацию без какого-либо ветвления и, следовательно, без необходимости отключать Option Explicit или тестировать несуществующие объекты.

Ограничение на требование Option Explicit в реализации VBA делает это немного сложнее, чем было бы в противном случае (без него это однострочник) ... По иронии судьбы, это также оказывается ключом к решению. Если вы не ограничиваете себя одной функцией, вы можете обойтись без нее, выполнив что-то вроде этого:

Dim hta

Sub window_onload()
     hta = True
End Sub

Function HostType()
    On Error Resume Next
    If hta Then
        HostType = "HTA"
    Else
        Dim foo
        Set foo = foo
        If Err.Number = 13 Then
            HostType = "VBA"
        Else
            HostType = "VBS"
        End If
    End If
End Function

Это работает следующим образом: если он загружается через HTA-файл, запускается обработчик события window_onload, устанавливая для переменной hta значение True. Это первое испытание. Второй «тест» — на ошибку, которую выдает строка Set foo = foo. Это несоответствие типов в VBA, где оно интерпретируется как попытка Set преобразовать Variant в Empty, что не является совместимым типом. Та же строка кода выдает ошибку 424 (требуется объект) в VBScript, потому что это не строго типизированный язык. Это означает, что проверка типа VBA пропускается, и он пытается фактически выполнить назначение (что не удается). Остальное просто выяснить, как он бросил и вернуть результат.

Тестовый код

VBA

Option Explicit

Dim hta

Sub Test()
    Debug.Print HostType    'VBA
End Sub

Sub window_onload()
     hta = True
End Sub

Function HostType()
    On Error Resume Next
    If hta Then
        HostType = "HTA"
    Else
        Dim foo
        Set foo = foo
        If Err.Number = 13 Then
            HostType = "VBA"
        Else
            HostType = "VBS"
        End If
    End If
End Function

VBScript

WSCript.Echo HostType

Dim hta

Sub window_onload()
     hta = True
End Sub

Function HostType()
    On Error Resume Next
    If hta Then
        HostType = "HTA"
    Else
        Dim foo
        Set foo = foo
        If Err.Number = 13 Then
            HostType = "VBA"
        Else
            HostType = "VBS"
        End If
    End If
End Function

ОМТ

<HTML>
    <BODY>
        <script type = "text/vbscript">
            Dim hta

            Sub Test()
                MsgBox HostType 
            End Sub

            Sub window_onload()
                 hta = True
            End Sub

            Function HostType()
                On Error Resume Next
                If hta Then
                    HostType = "HTA"
                Else
                    Dim foo
                    Set foo = foo
                    If Err.Number = 13 Then
                        HostType = "VBA"
                    Else
                        HostType = "VBS"
                    End If
                End If
            End Function
        </script>
        <button onclick = "vbscript:Test()">Click me</button> 
    </BODY>
</HTML>

Обновлено:

FWIW, однострочник, упомянутый выше, если Option Explicit не нужен, просто так:

Function HostString()
    HostString = Application & document & WScript
End Function

Все три объекта имеют свойство по умолчанию, которое возвращает String. В VBScript это вернет «Хост сценариев Windows». В VBA он вернет имя хоста (например, «Microsoft Excel» в Excel). В HTA он вернет «[объект]».

Хотя я согласен с @это, вот мой Option Explicit-безопасный метод без On Error утверждений, который использует прослушиватель Window_OnLoad для HTA ​​(как это делал Коминтерн) и трюк с меткой строки, чтобы отличить VBScript от VBA.

Dim IsInHTA, IsInVBScript

Sub Window_Onload()
    IsInHTA = True
End Sub

Sub LineLabelTest()
'VBA and VB6 (maybe VB5 too, IDK) treats "DummyLabel:" as a line label
'VBScript treats "DummyLabel" as an expression to call and treats ":" as a statement separator.
DummyLabel:
End Sub

Sub DummyLabel()
    'this is called by the LineLabelTest subroutine only in VBScript
    IsInVBScript = True
End Sub

Function HostType()
    LineLabelTest

    If IsInVBScript Then
        If IsInHTA Then 
            HostType = "HTA"
        Else
            HostType = "VBS" 'Other hosts incuding WSH, ASP, Custom
        End If
    Else
        HostType = "VBA" 'VBA or VB6 (maybe VB5 too, don't know)
    End If
End Function

Для тех, кто столкнется с этим в будущем, это окончательный код, который я закончил, и он работает! Особая благодарность всем в этой теме, которые поделились идеями, которые объединились, чтобы сделать эту работу! :-)

'------------------------------------------------------------------
'--- Function ScriptEngine
'---
'--- Returns a string containing which script engine this is
'--- running in.
'--- Will return either "VBScript","VBA", or "HTA".

Function ScriptEngine

    On Error Resume Next

    ScriptEngine = "VBA"

    ReDim WScript(0)
    If Err.Number=501 Then ScriptEngine = "VBScript"

    Err.Clear

    ReDim Window(0)
    If Err.Number=501 Then ScriptEngine = "HTA"

    On Error Goto 0

    End Function

'-------------------------------------------------------------------