Как получить класс исключений на стороне Delphi из общего исключения EDelphi в скрипте

Вы не можете напрямую получить тип класса исключения, поскольку обработчик исключений DWScript нигде не хранит эту информацию, а тип на стороне Delphi в любом случае не будет иметь смысла внутри сценария. Однако вы можете легко получить имя класса из объекта исключения на стороне сценария EDelphi через свойство EDelphi.ExceptionClass. Так:

Скрипт

try

  var x := 1/0;

except
  on E: EDelphi do
    WriteLn('Error: ' + E.Message + ' (' + E.ExceptionClass + ')');

  on E: Exception do
    WriteLn('Error: ' + E.Message);
else
  WriteLn('Unknown exception type');
end;

Выход

Error: Floating point division by zero (EZeroDivide)

Вы можете увидеть исходный код DWScript, который преобразует исключение на стороне Delphi в исключение на стороне сценария EDelphi здесь: https://github.com/EricGrange/DWScript/blob/2d61c8a95fb4a2aab328f3cc84bb9f243c927286/Source/dwsExprs.pas#L2244

Как я нашел ответ

Я просто поискал в исходнике на Github (поиск в основном репозитории Bitbucket отстой) по запросу «EDelphi»: https://github.com/search?q=repo%3AEricGrange%2FDWScript%20EDelphi&type=code

Это дало мне этот фрагмент кода:

// A Delphi exception. Transform it to a EDelphi-dws exception
exceptObj:=CreateEDelphiObj(mainException.ClassName, mainException.Message);

Затем я посмотрел на метод CreateEDelphiObj:

function TdwsProgramExecution.CreateEDelphiObj(const ClassName : String;
                                   const Message : String) : IScriptObj;
begin
   Result := IScriptObj(IUnknown(
      ProgramInfo.Vars[SYS_EDELPHI].Method[SYS_TOBJECT_CREATE].Call([ClassName, Message]).Value));
   (Result.ExternalObject as TdwsExceptionContext).ReplaceTop(LastScriptError); // temporary constructor expression
end;

Это похоже на вызов конструктора на стороне скрипта с передачей строк ClassName и Message в качестве параметров. Это нормально, но что происходит со значением ClassName?

Опять же, глядя на результат поиска, я заметил реализацию конструктора EDelphi на стороне Delphi:

procedure TDelphiExceptionCreateMethod.Execute(info : TProgramInfo; var ExternalObject: TObject);
begin
   inherited;
   Info.ValueAsVariant[SYS_EDELPHI_EXCEPTIONCLASS_FIELD]:=Info.ValueAsVariant['Cls']
end;

Таким образом, конструктор вызывает унаследованный конструктор, а затем сохраняет значение ClassName в поле FExceptionClass (значение константы SYS_EDELPHI_EXCEPTIONCLASS_FIELD).

На этом этапе я мог догадаться, что свойство будет называться ExceptionClass, поэтому я использовал свою DWScriptStudio IDE/отладчик, чтобы написать пример и проверить результат.