Как правильно использовать sql-запрос в функции coldfusion

Во-первых, правильный объем - arguments, а не cfargument. Итак, измените такие вещи:

cfargument.name,

к этому:

arguments.name,

Затем вы должны окружить имена переменных знаками решетки, чтобы получить значение переменной, то есть #arguments.name#.

Затем используйте параметры запроса, например <cfqueryparam value = "#arguments.name#">. Помимо прочего, они будут экранировать специальные символы, используемые в синтаксисе запроса SQL.

Подводя итог всем правильным ответам и комментариям выше. Это была бы ваша лучшая практика:

• Функция returnType должна быть «запросом», а не «структурой».
• Если вы укажете значение default, CF распознает аргумент как «необязательный».
• Использовать cfqueryparam для всех параметров запроса

По желанию

• Используйте атрибут null в cfqueryparam, чтобы вставить NULL, если значение не задано.
• Вам не нужна конечная точка с запятой в конце инструкции sql

<!---return type is query, not struct --->
<cffunction name = "insertSupplierPersonnel" output = "false" access = "public" returnType = "query">
    <cfargument name = "name" type = "string" required = "true" />
    <!--- NOTE: If you specify a default value, CF recognizes the argument as "not required" --->
    <cfargument name = "email" type = "string" default = "" />
    <cfargument name = "office_phone" type = "string" default = "" />
    <cfargument name = "mobile_phone" type = "string" default = "" />
    <cfargument name = "designation" type = "string" default = "" />

    <cfquery datasource = "#session.dsn_aset#" result = "local.data">
        INSERT INTO supplier_personnel_incharge (
            name, /*Unless your database column names are case-sensitive, you don't need quotation marks around the column names*/
            email,
            office_phone,
            mobile_phone,
            designation
        )
        VALUES
        (
            <cfqueryparam cfsqltype = "cf_sql_varchar" value = "#trim(arguments.name)#">,
            /*insert NULL if there is no value given*/
            <cfqueryparam cfsqltype = "cf_sql_varchar" null = "#Not Len(trim(arguments.email))#" value = "#trim(arguments.email)#">,
            <cfqueryparam cfsqltype = "cf_sql_varchar" null = "#Not Len(trim(arguments.office_phone))#" value = "#trim(arguments.office_phone)#">,
            <cfqueryparam cfsqltype = "cf_sql_varchar" null = "#Not Len(trim(arguments.mobile_phone))#" value = "#trim(arguments.mobile_phone)#">,
            <cfqueryparam cfsqltype = "cf_sql_varchar" null = "#Not Len(trim(arguments.designation))#" value = "#trim(arguments.designation)#">,
        ) /*you don't need a trailing semi-colon*/
    </cfquery>

    <cfreturn local.data />
</cffunction>

<cfset local.res = insertSupplierPersonnel(name='#form.personnel_name#',
    email='#form.personnel_email#', 
    office_phone='#form.personnel_office_phone#', 
    mobile_phone='#form.personnel_mobile_phone#', 
    designation='#form.personnel_designation#') />

<cfdump var = "#local.res#">