Как правильно закрыть Winform при выполнении асинхронной задачи?

(Проверьте конец вопроса в разделе Edit2, где опубликован окончательный рабочий код из принятого ответа)

Я создаю приложение Winforms (.Net 7), которое отображает статистику на графиках. Источником статистических данных является запрос MySQL, который выполняется в Async Task. После завершения запроса результат datatable привязывается к диаграмме.

Когда приложение запускается, появляется основная Winform, где есть кнопки, которые запускают разные Winform или несколько экземпляров одной и той же Winform.

Моя проблема в том, что если, например, в одном из дочерних Winforms выполняется асинхронный запрос MySQL, и я закрываю этот Winform с помощью «x», и теперь на экране находится только основная Winform, то при завершении запроса возникает исключение System.NullReferenceException: 'Object reference not set to an instance of an object.' когда таблица данных привязана к диаграмме. Очевидно, закрытия Winform недостаточно для освобождения всех связанных с ним ресурсов (я не имею в виду уничтожение запроса, который, естественно, продолжает выполняться на сервере MySQL). Я ожидал, что если я закрою форму, то с ней все будет покончено.

Каков правильный подход в таких ситуациях? Как я могу избавиться от исключений из Winform, который был закрыт, пока его задача не была завершена? Наличие таких исключений влияет на взаимодействие с пользователем, когда пользователи работают в других формах того же приложения.

Упрощенный пример моего кода приведен ниже:

Public Class Form4
    Private Async Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click

        Dim TabCell As New DataTable
        'This is the statistical table

        Dim getStats As New Queries
        '"Queries " is a class containing query execution functions

        TabCell = Await Task().Run(Function() getStats.ExecQuery(parameters))
        'This is the asynchronous run of the task for query execution.
        'If the Winform is closed while this task is running...
        '...there is the mentioned exception in the line below:
        Chart1.DataSource = TabCell

        Chart1.Series.Clear()
        Chart1.Titles.Clear()
        'Further code for chart definition

    End Sub
End Class

Код класса Queries приведен ниже.

Public Class Queries

    Public Property connStr As String

    Public Function ExecQuery(date1 As Date, date2 As Date, queryString As String) As DataTable
        Dim dTab As New DataTable
        Dim SQL As New MySqlCommand
        Dim Adap As New MySqlDataAdapter

        Try
            MysqlConn.ConnectionString = connStr
            MysqlConn.Open()

            SQL.Parameters.AddWithValue("@date1", date1)
            SQL.Parameters.AddWithValue("@date2", date2)

            SQL.Connection = MysqlConn
            SQL.CommandText = queryString
            SQL.CommandTimeout = 1200

            Adap.SelectCommand = SQL
            Adap.Fill(dTab)

        Catch Err As MySqlException
            MsgBox("Error: " & Err.Number & " - " & Err.Message)
        Finally
            MysqlConn.Close()
            MysqlConn.Dispose()
        End Try

        Return dTab

    End Function

End Class

Обновлено: я публикую здесь код из ответа, полученного от пользователя «Zch», но не знаю, почему он бесследно исчез. Этот ответ был очень хорошо структурирован и по большей части полезен. Там объяснялось, как бороться с CancellationToken.

Я реализовал это, и это сработало как шарм. Теперь, когда Winform закрывается до завершения Async Task, исключений больше нет.

Часть, которую я не могу понять, как заставить это работать, — это реализация CancellationToken в функции выполнения запроса в классе Queries. Должен сказать, что код в Winform работает вполне нормально без записей, касающихся токена в классе Queries. Пожалуйста, проверьте ниже точные строки, для которых я не понимаю, для чего они предназначены.

If token.IsCancellationRequested Then
    token.ThrowIfCancellationRequested()
End If

Предполагается ли, что эта запись уничтожит запрос на стороне сервера MySQL? Автор ответа написал следующее:

Убедитесь, что ваш query func выдержит отмену, предоставив a CancelationToken и периодически проверяем его.

Я не знаю, как это периодически проверять.

Полный код из исчезнувшего ответа показан ниже. Это модификация моего кода с добавлением записей для CancelationToken.

Public Class Form4
    Private cts As CancellationTokenSource

    Private Async Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        cts = New CancellationTokenSource()
        Dim token As CancellationToken = cts.Token

        Try
            Dim TabCell As New DataTable
            'store the data from the query

            Dim getStats As New Queries
            'runs the queries

            TabCell = Await Task.Run(Function() getStats.ExecQuery(parameters, token), token)
            'Run the async query with the cancellation token

            If Not Me.IsDisposed Then
                Chart1.DataSource = TabCell
                Chart1.Series.Clear()
                Chart1.Titles.Clear()
                'Set up your data chart
            End If
        Catch ex As OperationCanceledException
            'The task was canceled, yay
        Catch ex As Exception
            'Handle other exceptions
        Finally
            cts.Dispose()
        End Try
    End Sub
    
    Private Sub Form4_FormClosing(sender As Object, e As FormClosingEventArgs) Handles MyBase.FormClosing
        If cts IsNot Nothing Then
            cts.Cancel()
        End If
    End Sub
End Class

Public Class Queries
    Public Function ExecQuery(parameters As Object, token As CancellationToken) As DataTable
        Dim dt As New DataTable

        'Simulate a long-running query
        For i As Integer = 1 To 10
            If token.IsCancellationRequested Then
                token.ThrowIfCancellationRequested()
            End If
            Threading.Thread.Sleep(420)
        Next

        'Your query logic goes here
        'Populate the DataTable

        Return dt
    End Function
End Class

Edit2: Ниже вы можете найти окончательный рабочий код из принятого ответа. Есть некоторые отличия от кода в разделе «Редактирование» относительно использования функциональности Adapter.FillAsync соединителя MySQL, а также добавления cts = Nothing после End Try и удаления cts.Dispose() в разделе Finally.

Public Class Form4
    Private cts As CancellationTokenSource

    Private Async Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    
        cts = New CancellationTokenSource()
        Dim token As CancellationToken = cts.Token

        Try
            Dim TabCell As New DataTable
            'store the data from the query

            Dim getStats As New Queries
            'runs the queries

            TabCell = Await Task.Run(Function() getStats.ExecQuery(queryString, token), token)
            'Run the async query with the cancellation token

            If Not Me.IsDisposed Then
                Chart1.DataSource = TabCell
                Chart1.Series.Clear()
                Chart1.Titles.Clear()
                'Set up your data chart
            End If
            
        Catch ex As OperationCanceledException
            'The task was canceled, yay
        Catch ex As Exception
            'Handle other exceptions
        End Try
        
        cts = Nothing
        
    End Sub
    
    Private Sub Form4_FormClosing(sender As Object, e As FormClosingEventArgs) Handles MyBase.FormClosing
        If cts IsNot Nothing Then
            cts.Cancel()
        End If
    End Sub
End Class

Public Class Queries
    Public Async Function ExecQuery(queryString As String, token As CancellationToken) As Task(Of DataTable)
        Dim dt As New DataTable
        Dim SQL As New MySqlCommand
        Dim Adap As New MySqlDataAdapter

        Try

            SQL.Connection = MysqlConn
            SQL.CommandText = queryString

            Adap.SelectCommand = SQL
            Await Adap.FillAsync(dTab, token)

            token.ThrowIfCancellationRequested()

        Catch Err As MySqlException
            MsgBox("Error: " & Err.Number & " - " & Err.Message)
        End Try

        Return dt
    End Function
End Class