Как проверить, запущен ли процесс с помощью пакетного скрипта

Вы должны проверить имя родительского процесса, см. Статью Кодовый проект о Решение на основе .NET **.

Непрограммный способ проверить:

1. Запустить Cmd.exe
2. Запустить приложение (например, c:\windows\notepad.exe)
3. Проверьте свойства процесса Notepad.exe в Процесс
4. Проверьте родительский процесс (это показывает cmd.exe)

То же самое можно проверить, получив имя родительского процесса.

Я предполагаю, что окна здесь. Итак, вам нужно использовать WMI для получения этой информации. Посмотрите архивы от The Scripting Guy, где вы найдете множество примеров того, как использовать WMI из скрипта.

Вот как я это решил:

tasklist /FI "IMAGENAME eq notepad.exe" /FO CSV > search.log

FOR /F %%A IN (search.log) DO IF %%~zA EQU 0 GOTO end

start notepad.exe

:end

del search.log

Вышеупомянутый откроет Блокнот, если он еще не запущен.

Обновлено: обратите внимание, что при этом не будут обнаружены приложения, скрытые в списке задач. Это будет включать любые запланированные задачи, запущенные от имени другого пользователя, поскольку они автоматически скрываются.

Я не знаю, как это сделать со встроенным CMD, но если у вас есть grep, вы можете попробовать следующее:

tasklist /FI "IMAGENAME eq myApp.exe" | grep myApp.exe
if ERRORLEVEL 1 echo "myApp is not running"

Я использую PV.exe из http://www.teamcti.com/pview/prcview.htm, установленного в Program Files \ PV, с таким командным файлом:

@echo off
PATH=%PATH%;%PROGRAMFILES%\PV;%PROGRAMFILES%\YourProgram
PV.EXE YourProgram.exe >nul
if ERRORLEVEL 1 goto Process_NotFound
:Process_Found
echo YourProgram is running
goto END
:Process_NotFound
echo YourProgram is not running
YourProgram.exe
goto END
:END

Другая возможность, которую я придумал, вдохновленная использованием grep, такова:

tasklist /FI "IMAGENAME eq myapp.exe" 2>NUL | find /I /N "myapp.exe">NUL
if "%ERRORLEVEL%"= = "0" echo Program is running

Не нужно сохранять дополнительный файл, поэтому я предпочитаю этот метод.

Я использовал сценарий предоставлен Мэттом (2008-10-02). Единственное, с чем у меня была проблема, это то, что он не удалял файл search.log. Я ожидаю, потому что мне пришлось переместить cd в другое место, чтобы запустить мою программу. Я cd вернулся туда, где находятся BAT-файл и search.log, но он все равно не удалялся. Я решил это, удалив файл search.log первым, а не последним.

del search.log

tasklist /FI "IMAGENAME eq myprog.exe" /FO CSV > search.log

FOR /F %%A IN (search.log) DO IF %%-zA EQU 0 GOTO end

cd "C:\Program Files\MyLoc\bin"

myprog.exe myuser mypwd

:end

В Windows вы можете использовать инструментарий управления Windows (WMI), чтобы гарантировать, что никакие приложения с указанной командной строкой не запускаются, например:

wmic process where (name = "nmake.exe") get commandline | findstr /i /c:"/f load.mak" /c:"/f build.mak" > NUL && (echo THE BUILD HAS BEEN STARTED ALREADY! > %ALREADY_STARTED% & exit /b 1)

ответ предоставлен Мэттом Лейси работает в Windows XP. Однако в Windows Server 2003 строка

 tasklist /FI "IMAGENAME eq notepad.exe" /FO CSV > search.log

возвращается

INFO: No tasks are running which match the specified criteria.

который затем читается по мере выполнения процесса.

У меня нет опыта создания пакетных сценариев, поэтому я предпочитаю искать имя процесса в файле search.log, перекачивать результаты в другой файл и искать в нем любые выходные данные.

tasklist /FI "IMAGENAME eq notepad.exe" /FO CSV > search.log

FINDSTR notepad.exe search.log > found.log

FOR /F %%A IN (found.log) DO IF %%~zA EQU 0 GOTO end

start notepad.exe

:end

del search.log
del found.log

Надеюсь, это поможет кому-то другому.

Основываясь на ответ vtrz и Ответ Самуэля Ренкерта по другой теме, я придумал следующий сценарий, который запускает %EXEC_CMD%, только если он еще не запущен:

@echo off
set EXEC_CMD = "rsync.exe"
wmic process where (name=%EXEC_CMD%) get commandline | findstr /i %EXEC_CMD%> NUL
if errorlevel 1 (
    %EXEC_CMD% ...
) else (
    @echo not starting %EXEC_CMD%: already running.
)

Как было сказано ранее, для этого требуются административные привилегии.

Мне нравятся инструменты WMIC и TASKLIST, но они недоступны в домашних / базовых версиях Windows. Другой способ - использовать команду QPROCESS, доступную почти на каждом компьютере с Windows (для тех, у которых есть терминальные службы - я думаю, что выиграть XP без SP2 так что практически каждая машина Windows):

@echo off
:check_process
setlocal
if "%~1" equ "" echo pass the process name as forst argument && exit /b 1
:: first argument is the process you want to check if running
set process_to_check=%~1
:: QPROCESS can display only the first 12 symbols of the running process
:: If other tool is used the line bellow could be deleted
set process_to_check=%process_to_check:~0,12%

QPROCESS * | find /i "%process_to_check%" >nul 2>&1 && (
    echo process %process_to_check%  is running
) || (
    echo process %process_to_check%  is not running
)
endlocal

Команда QPROCESS не так мощна, как TASKLIST, и ограничена отображением только 12 символов имени процесса, но должна приниматься во внимание, если TASKLIST недоступен.

Более простое использование, когда он использует имя процесса в качестве аргумента (суффикс .exe является обязательным в этом случае, когда вы передаете имя исполняемого файла):

@echo off
:check_process
setlocal
if "%~1" equ "" echo pass the process name as forst argument && exit /b 1
:: first argument is the process you want to check if running
:: .exe suffix is mandatory
set "process_to_check=%~1"


QPROCESS "%process_to_check%" >nul 2>&1 && (
    echo process %process_to_check%  is running
) || (
    echo process %process_to_check%  is not running
)
endlocal

Разница между двумя способами использования QPROCESS заключается в том, что QPROCESS * перечислит все процессы, а QPROCESS some.exe будет фильтровать только процессы для текущего пользователя.

Использование объектов WMI через Windows script host exe вместо WMIC также является вариантом. Он должен запускаться также на каждой машине с Windows (за исключением тех, где WSH отключен, но это редкий случай). Здесь bat-файл, в котором перечислены все процессы через классы WMI и может использоваться вместо QPROCESS в приведенном выше сценарии (это гибрид jscript / bat и должен быть сохранен как .bat):

@if (@X)==(@Y) @end /* JSCRIPT COMMENT **


@echo off
cscript //E:JScript //nologo "%~f0"
exit /b

************** end of JSCRIPT COMMENT **/


var winmgmts = GetObject("winmgmts:\\.\root\cimv2");
var colProcess = winmgmts.ExecQuery("Select * from Win32_Process");
var processes =  new Enumerator(colProcess);
for (;!processes.atEnd();processes.moveNext()) {
    var process=processes.item();
    WScript.Echo( process.processID + "   " + process.Name );
}

И модификация, которая проверяет, запущен ли процесс:

@if (@X)==(@Y) @end /* JSCRIPT COMMENT **


@echo off
if "%~1" equ "" echo pass the process name as forst argument && exit /b 1
:: first argument is the process you want to check if running
set process_to_check=%~1

cscript //E:JScript //nologo "%~f0" | find /i "%process_to_check%" >nul 2>&1 && (
    echo process %process_to_check%  is running
) || (
    echo process %process_to_check%  is not running
)

exit /b

************** end of JSCRIPT COMMENT **/


var winmgmts = GetObject("winmgmts:\\.\root\cimv2");
var colProcess = winmgmts.ExecQuery("Select * from Win32_Process");
var processes =  new Enumerator(colProcess);
for (;!processes.atEnd();processes.moveNext()) {
    var process=processes.item();
    WScript.Echo( process.processID + "   " + process.Name );
}

Эти два варианта можно использовать на машинах без TASKLIST.

Конечная техника - использование MSHTA. Это будет работать на каждой машине Windows, начиная с XP и выше, и не зависит от настроек хоста скриптов Windows. вызов MSHTA может немного снизить производительность (снова следует сохранить как bat):

@if (@X)==(@Y) @end /* JSCRIPT COMMENT **
@echo off

setlocal
if "%~1" equ "" echo pass the process name as forst argument && exit /b 1
:: first argument is the process you want to check if running

set process_to_check=%~1


mshta "about:<script language='javascript' src='file://%~dpnxf0'></script>" | find /i "%process_to_check%" >nul 2>&1 && (
    echo process %process_to_check%  is running
) || (
    echo process %process_to_check%  is not running
)
endlocal
exit /b
************** end of JSCRIPT COMMENT **/


   var fso= new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1);


   var winmgmts = GetObject("winmgmts:\\.\root\cimv2");
   var colProcess = winmgmts.ExecQuery("Select * from Win32_Process");
   var processes =  new Enumerator(colProcess);
   for (;!processes.atEnd();processes.moveNext()) {
    var process=processes.item();
    fso.Write( process.processID + "   " + process.Name + "\n");
   }
   close();

Мне нравится решение Chaosmaster! Но я искал решение, которое не запускает другую внешнюю программу (например, find.exe или findstr.exe). Поэтому я добавил идею из решения Мэтта Лейси, которое создает временный файл, которого также можно избежать. В итоге я смог найти довольно простое решение, поэтому делюсь им ...

SETLOCAL EnableExtensions
set EXE=myprog.exe
FOR /F %%x IN ('tasklist /NH /FI "IMAGENAME eq %EXE%"') DO IF %%x == %EXE% goto FOUND
echo Not running
goto FIN
:FOUND
echo Running
:FIN

У меня это прекрасно работает ...

Ответ TrueY казался самым элегантным решением, однако мне пришлось немного повозиться, потому что я не понимал, что именно происходит. Позвольте мне прояснить ситуацию, чтобы сэкономить время для следующего человека.

Измененный ответ TrueY:

::Change the name of notepad.exe to the process .exe that you're trying to track
::Process names are CASE SENSITIVE, so notepad.exe works but Notepad.exe does NOT
::Do not change IMAGENAME
::You can Copy and Paste this into an empty batch file and change the name of
::notepad.exe to the process you'd like to track
::Also, some large programs take a while to no longer show as not running, so
::give this batch a few seconds timer to avoid a false result!!

@echo off
SETLOCAL EnableExtensions

set EXE=notepad.exe

FOR /F %%x IN ('tasklist /NH /FI "IMAGENAME eq %EXE%"') DO IF %%x == %EXE% goto ProcessFound

goto ProcessNotFound

:ProcessFound

echo %EXE% is running
goto END
:ProcessNotFound
echo %EXE% is not running
goto END
:END
echo Finished!

В любом случае, я надеюсь, что это поможет. Я знаю, что иногда чтение пакета / командной строки может сбивать с толку, если вы такой новичок, как я.

TASKLIST | FINDSTR ProgramName || START "" "Path\ProgramName.exe"

Обычно я выполняю следующую команду в командной строке, чтобы проверить, запущен ли мой program.exe или нет:

tasklist | grep program

Предложение npocmaka использовать QPROCESS вместо TASKLIST великолепно, но его ответ настолько велик и сложен, что я чувствую себя обязанным опубликовать его довольно упрощенную версию, которая, я думаю, решит проблему большинства неопытных пользователей:

QPROCESS "myprocess.exe">NUL
IF %ERRORLEVEL% EQU 0 ECHO "Process running"

Приведенный выше код был протестирован в Windows 7 с правами администратора.

Просто отметим, что если имя вашей задачи действительно длинное, то оно не будет полностью отображаться в результате tasklist, поэтому может быть безопаснее (кроме локализации) проверить обратное.

Вариант этот ответ:

:: in case your task name is really long, check for the 'opposite' and find  the message when it's not there
tasklist /fi "imagename eq yourreallylongtasknamethatwontfitinthelist.exe" 2>NUL | find /I /N "no tasks are running">NUL
if "%errorlevel%"= = "0" (
    echo Task Found
) else (
    echo Not Found Task
)

Мне нужно было решение с повторной попыткой. Этот код будет работать до тех пор, пока процесс не будет найден, а затем уничтожит его. Вы можете установить тайм-аут или что угодно, если хотите.

Заметки:

• ".Exe" является обязательным.
• Вы можете сделать файл запускаемым с параметрами, версия ниже

    :: Set programm you want to kill
    :: Fileextension is mandatory
    SET KillProg=explorer.exe

    :: Set waiting time between 2 requests in seconds
    SET /A "_wait=3"

    :ProcessNotFound
        tasklist /NH /FI "IMAGENAME eq %KillProg%" | FIND /I "%KillProg%"
        IF "%ERRORLEVEL%"= = "0" (
            TASKKILL.EXE /F /T /IM %KillProg%
        ) ELSE (
            timeout /t %_wait%
            GOTO :ProcessNotFound
        )

taskkill.bat:

    :: Get program name from argumentlist
    IF NOT "%~1"= = "" (
        SET "KillProg=%~1"
    ) ELSE (
        ECHO Usage: "%~nx0" ProgramToKill.exe & EXIT /B
    )

    :: Set waiting time between 2 requests in seconds
    SET /A "_wait=3"

    :ProcessNotFound
        tasklist /NH /FI "IMAGENAME eq %KillProg%" | FIND /I "%KillProg%"
        IF "%ERRORLEVEL%"= = "0" (
            TASKKILL.EXE /F /T /IM %KillProg%
        ) ELSE (
            timeout /t %_wait%
            GOTO :ProcessNotFound
        )

Запуск с .\taskkill.bat ProgramToKill.exe