Как реализовать assert в Perl?

Использовать B:: Депарсировать?

#!/usr/bin/perl
use strict;
use warnings;

use B::Deparse;
my $deparser = B::Deparse->new();

sub assert(&) {
    my($condfunc) = @_;
    my @caller    = caller();
    unless ($condfunc->()) {
        my $src = $deparser->coderef2text($condfunc);
        $src =~ s/^\s*use\s.*$//mg;
        $src =~ s/^\s+(.+?)/$1/mg;
        $src =~ s/(.+?)\s+$/$1/mg;
        $src =~ s/[\r\n]+/ /mg;
        $src =~ s/^\{\s*(.+?)\s*\}$/$1/g;
        $src =~ s/;$//mg;
        die "Assertion failed: $src at $caller[1] line $caller[2].\n";
    }
}

my $var;
assert { 1 };
#assert { 0 };
assert { defined($var) };

exit 0;

Тестовый вывод:

$ perl dummy.pl
Assertion failed: defined $var at dummy.pl line 26.

В CPAN есть множество модулей утверждений. Они с открытым исходным кодом, так что довольно легко заглянуть в них и посмотреть, как они сделаны.

Карп::Утвердить — реализация с низким уровнем магии. В его документации есть ссылки на несколько более сложных модулей утверждений, одним из которых является мой модуль PerlX::Утвердить.

Использовать caller и извлечь строку исходного кода, которая сделала утверждение?

sub assert {
    my ($condition, $msg) = @_;
    return if $condition;
    if (!$msg) {
        my ($pkg, $file, $line) = caller(0);
        open my $fh, "<", $file;
        my @lines = <$fh>;
        close $fh;
        $msg = "$file:$line: " . $lines[$line - 1];
    }
    die "Assertion failed: $msg";
}

assert(2 + 2 == 5);

Вывод:

Assertion failed:  assert.pl:14: assert(2 + 2 == 5);

Если вы используете Carp::croak вместо die, Perl также сообщит информацию о трассировке стека и определит, где было вызвано ошибочное утверждение.

Одним из подходов к любым «утверждениям» является использование среды тестирования. Он не такой четкий, как assert в C, но несравненно более гибкий и управляемый, в то время как тесты по-прежнему можно свободно встраивать в код, как операторы assert.

Несколько очень простых примеров

use warnings;
use strict;
use feature 'say';

use Test::More 'no_plan';
Test::More->builder->output('/dev/null');

say "A few examples of tests, scattered around code\n";

like('may be', qr/(?:\w+\s+)?be/, 'regex');
cmp_ok('a', 'eq', 'a ', 'string equality');

my ($x, $y) = (1.7, 13);

cmp_ok($x, '==', $y, '$x == $y');

say "\n'eval' expression in a string so we can see the failing code\n";

my $expr = '$x**2 == $y';
ok(eval $expr, 'Quadratic') || diag explain $expr;  

# ok(eval $expr, $expr);

с выходом

A few examples of tests, scattered around code

#   Failed test 'string equality'
#   at assertion.pl line 19.
#          got: 'a'
#     expected: 'a '
#   Failed test '$x == $y'
#   at assertion.pl line 20.
#          got: 1.7
#     expected: 13

'eval' expression in a string so we can see the failing code

#   Failed test 'Quadratic'
#   at assertion.pl line 26.
# $x**2 == $y
# Looks like you failed 3 tests of 4.

Это просто разрозненные примеры, где последний прямо отвечает на вопрос.

Модуль Тест::Больше объединяет ряд инструментов; есть много вариантов того, как его использовать и как манипулировать выводом. См. Тест::Упряжь и Тест::Строитель (используемые выше), а также ряд руководств и сообщений SO.

Я не знаю, как приведенный выше eval считается «элегантным», но он действительно перемещает вас от единичных и индивидуально заботящихся об операторах assert в стиле C к более легко управляемой системе.

Хорошие утверждения задуманы и запланированы как системные тесты и документация по коду, но по своей природе им не хватает формальной структуры (и поэтому они все равно могут оказаться разрозненными и случайными). Когда это сделано таким образом, они поставляются с инфраструктурой, и ими можно управлять и настраивать с помощью многих инструментов и в виде пакета.