Как реализовать режим Unreal с NASM (DOS)?

Вы можете создать структуру GDT_STR в NASM следующим образом:

struc GDT_STR
    .s0_15:   resw 1
    .b0_15:   resw 1
    .b16_23:  resb 1
    .flags:   resb 1
    .access:  resb 1
    .b24_31:  resb 1
endstruc

а затем вы создаете экземпляры этих структур следующим образом:

dummy_descriptor:
    istruc GDT_STR
        at .s0_15,  dw 0
        at .b0_15,  dw 0
        at .b16_23, db 0
        at .flags,  db 0
        at .access, db 0
        at .b24_31, db 0
    iend

code32_descriptor:
    istruc GDT_STR
        at .s0_15,  dw 0xffff
        at .b0_15,  dw 0
        at .b16_23, db 0
        at .flags,  db 0x92
        at .access, db 0xcf
        at .b24_31, db 0
    iend

jmp $+2 переходит к следующей инструкции в 16-битном коде. В контексте кода нереального режима относительный переход к следующей инструкции очищает очередь предварительной выборки инструкций. Вы можете заменить его чем-то вроде:

    jmp next1                   ; Flush the instruction prefetch queue
next1:

Код использует NASM для создания файла obj, который можно связать в исполняемый файл. Инструкции по сборке и компоновке см. в комментариях вверху кода.

; Assemble with
;     nasm -f obj unreal.asm -o unreal.obj
;
; Link with Watcom Linker to unreal.exe
;     wlink format dos file unreal.obj
;
; Or link with MS 16-bit segmented linker
;     link16 unreal.obj;
;
; Or link with TLink (Turbo link)
;     tlink unreal.obj
    
; Define GDT_STR - a GDT descriptor entry
struc GDT_STR
    .s0_15:   resw 1
    .b0_15:   resw 1
    .b16_23:  resb 1
    .flags:   resb 1
    .access:  resb 1
    .b24_31:  resb 1
endstruc

bits 16

segment data
align 4

gdt:
FLAT_SEL  equ .flat  - .start

.start:
.null:
    istruc GDT_STR
        at .s0_15,  dw 0
        at .b0_15,  dw 0
        at .b16_23, db 0
        at .flags,  db 0
        at .access, db 0
        at .b24_31, db 0
    iend

.flat:
    istruc GDT_STR
        at .s0_15,  dw 0xffff
        at .b0_15,  dw 0
        at .b16_23, db 0
        at .flags,  db 0x92
        at .access, db 0xcf
        at .b24_31, db 0
    iend
.end:

.gdtr:
    dw .end - .start - 1
                                ; limit (Size of GDT - 1)
    dd .start                   ; base of GDT. Needs to be fixed up at runtime

in_pmode_str:  db "Processor already in protected mode - exiting", 0x0a, 0x0d, "$"


section code
    ; ..start is a special label for the DOS entry point

..start:
    ; Save initial EFLAGS state
    pushfd
    cli

    ; Initialize DS to our DOS DATA segment (needed for EXEs)
    ; SS:SP will be set by the DOS EXE loader to our stack segment
    mov ax, data
    mov ds, ax

check_pmode:
    smsw ax
    test ax, 0x1                ; Check if we are already in protected mode
                                ;    This may be the case if we are in a VM8086 task.
                                ;    EMM386 and other expanded memory manager often
                                ;    run DOS in a VM8086 task. DOS extenders will have
                                ;    the same effect

    jz not_prot_mode            ; If not in protected mode proceed to switch
    mov dx, in_pmode_str        ;    otherwise print an error and exit back to DOS
    mov ah, 0x9
    int 0x21                    ; Print Error
    jmp exit                    ; Exit program

not_prot_mode:
    ; Apply a fixup to  the GDTR base to convert to a linear address
    mov eax, ds
    shl eax, 4
    add [gdt.gdtr+2], eax
    lgdt [gdt.gdtr]             ; Load our GDT

    mov cx, ds                  ; Save DS so it can be restored
    mov eax, cr0
    or al, 1
    mov cr0, eax                ; Set protected mode flag
    jmp .next1                  ; Flush the instruction pefetch queue
.next1:

    ; In 16-bit protected mode
    ; Since we aren't changing CS
    ;     we don't need to enter 32-bit protected mode
    mov bx, FLAT_SEL
    mov ss, bx
    mov ds, bx
    mov es, bx
    mov fs, bx
    mov gs, bx

    and al, ~1
    mov cr0, eax                ; Unset protected mode flag
    jmp .next2                  ; Flush the instruction pefetch queue
.next2:

    ; Unreal mode here
    ; Restore SS=DS=ES
    mov ss, cx
    mov ds, cx
    mov es, cx

    ; Print UNR to the screen using a flat 4GiB selector
    ; This code won't work in regular real mode
    xor ax, ax
    mov fs, ax

    mov word fs:[dword 0xb8000+80*2*3+0], 0x57<<8 | 'U'
    mov word fs:[dword 0xb8000+80*2*3+2], 0x57<<8 | 'N'
    mov word fs:[dword 0xb8000+80*2*3+4], 0x57<<8 | 'R'

exit:
    ; Restore initial EFLAGS state
    popfd

    ; DOS exit
    mov ax, 0x4c00
    int 0x21

segment stack stack
    resb 1024

Примечание. Переход в нереальный режим не сработает, если процессор уже находится в защищенном режиме (т. е. выполняется как задача v8086). Это может быть в случае с EMM386, расширителями DOS и кодом, основанным на DPMI.