Как убрать доли секунды из переменной даты?

Задний план:

Я прочитал атрибут pwdLastSet из Active Directory и хочу сохранить его в столбце DATETIME2(0) в таблице SQL Server. Я не хочу хранить доли секунды.

Это 8-байтовое целое число, выраженное с шагом 100 наносекунд с 12:00 AM, 1 января 1601. Я использую эта функция, чтобы преобразовать его в переменную Date.

Это продолжало терпеть неудачу с ODBC-call failed, и мне потребовалось некоторое время, чтобы понять, что дополнительная точность, возвращаемая этой функцией, вызвала ошибку.

Вопрос:

Как лучше всего убрать доли секунды из переменной Date?

Как воспроизвести:

Я использую SQL Server 2008 R2 и Access 2010.
В SQL Server:

CREATE TABLE TestDT (
    ID      INT             NOT NULL,
    colDT2  DATETIME2(0)    NULL,

    CONSTRAINT PK_TestDT PRIMARY KEY (ID)
)
GO
INSERT TestDT (ID) VALUES (1)
GO

Свяжите эту таблицу с Access, используя драйвер ODBC для собственного клиента или текущий Драйвер Microsoft ODBC 17 для SQL Server. Драйвер SQL Server по умолчанию на самом деле не знает, как работать с DATETIME2.

В Access VBA:

Public Sub TestDT()

    Dim DB As DAO.Database
    Dim RS As DAO.Recordset
    Dim dte As Date
    Dim i As Long
    
    Set DB = CurrentDb
    
    ' Random date+time
    dte = CDate("2018-12-24 15:16:17")
    
    ' 1st iteration: write original date+time -> works
    ' 2nd iteration: try to write date+time with fractional seconds -> error for DATETIME2(0) column
    
    For i = 1 To 2
        If i = 2 Then
            ' Introduce milliseconds nastiness
            dte = dte + 0.00001
        End If
        Debug.Print "Iteration " & i, Format(dte, "yyyy-mm-dd hh:nn:ss")
            
        Set RS = DB.OpenRecordset("SELECT * FROM TestDT WHERE ID = 1", dbOpenDynaset)
    
        With RS
            .Edit
            !colDT2 = dte
            On Error Resume Next
            .Update
            
            If Err.Number <> 0 Then
                Debug.Print "Error " & Err.Number, Err.Description
                ' The DAO Errors collection shows the actual error
                Debug.Print Errors(0).Description
            Else
                Debug.Print "Update OK"
            End If
            On Error GoTo 0
            
            .Close
        End With
    Next i

End Sub

Вывод:

Iteration 1   2018-12-24 15:16:17
Update OK
Iteration 2   2018-12-24 15:16:18
Error 3146    ODBC-Aufruf fehlgeschlagen.
[Microsoft][ODBC Driver 17 for SQL Server]Datetime field overflow. 
    Fractional second precision exceeds the scale specified in the parameter binding.