Нашел ответ здесь.

Добавление следующего в мой файл .vimrc помогло.

autocmd BufWritePre *.py :%s/\s\+$//e

Еще у меня обычно есть:

match Todo /\s\+$/

в моем файле .vimrc, так что пробелы в конце строки подсвечиваются.

Todo - это синтаксическая подсветка имя группы, которая используется для выделения ключевых слов, таких как TODO, FIXME или XXX. У него раздражающе уродливый желтоватый цвет фона, и я считаю, что лучше всего выделять то, что вам нужно не в вашем коде :-)

Вот как я это делаю. Не могу вспомнить, где я его украл.

autocmd BufWritePre * :call <SID>StripWhite()
fun! <SID>StripWhite()
    %s/[ \t]\+$//ge
    %s!^\( \+\)\t!\=StrRepeat("\t", 1 + strlen(submatch(1)) / 8)!ge
endfun

Компиляция выше плюс сохранение позиции курсора:

function! <SID>StripTrailingWhitespaces()
  if !&binary && &filetype != 'diff'
    let l:save = winsaveview()
    keeppatterns %s/\s\+$//e
    call winrestview(l:save)
  endif
endfun

autocmd FileType c,cpp,java,php,ruby,python autocmd BufWritePre <buffer> :call <SID>StripTrailingWhitespaces()

Если вы хотите применить это при сохранении к любому файлу, оставьте второй autocmd и используйте подстановочный знак *:

autocmd BufWritePre,FileWritePre,FileAppendPre,FilterWritePre *
  \ :call <SID>StripTrailingWhitespaces()

Скопировано и вставлено из http://blog.kamil.dworakowski.name/2009/09/unobtrusive-highlighting-of-trailing.html (ссылка больше не работает, но нужный вам бит находится ниже)

«Это имеет то преимущество, что не выделяется каждый вводимый вами пробел в конце строки, только когда вы открываете файл или выходите из режима вставки. Очень удобно».

highlight ExtraWhitespace ctermbg=red guibg=red
au ColorScheme * highlight ExtraWhitespace guibg=red
au BufEnter * match ExtraWhitespace /\s\+$/
au InsertEnter * match ExtraWhitespace /\s\+\%#\@<!$/
au InsertLeave * match ExtraWhiteSpace /\s\+$/

Вот способ фильтрации по более чем одному типу файла.

autocmd FileType c,cpp,python,ruby,java autocmd BufWritePre <buffer> :%s/\s\+$//e

Я как выделяю существующие конечные пробелы, так и удаляю конечные пробелы.

Я настраиваю свой редактор (vim) так, чтобы в конце было пустое пространство, например

с этим внизу моего .vimrc:

highlight ExtraWhitespace ctermbg=red guibg=red
match ExtraWhitespace /\s\+$/
autocmd BufWinEnter * match ExtraWhitespace /\s\+$/
autocmd InsertEnter * match ExtraWhitespace /\s\+\%#\@<!$/
autocmd InsertLeave * match ExtraWhitespace /\s\+$/
autocmd BufWinLeave * call clearmatches()

и я автоматически удаляю его из файлов при их сохранении, в моем случае * .rb для файлов ruby, снова в моем ~ / .vimrc

function! TrimWhiteSpace()
    %s/\s\+$//e
endfunction
autocmd BufWritePre     *.rb :call TrimWhiteSpace()

Решение, которое просто удаляет конечные пробелы из файла, неприемлемо при любых обстоятельствах. Он будет работать в проекте, в котором эта политика действовала с самого начала, и поэтому нет таких пробелов, которые вы не добавляли бы просто в свой предстоящий коммит.

Предположим, вы хотите просто не добавлять новые экземпляры завершающих пробелов, не затрагивая существующие пробелы в строках, которые вы не редактировали, чтобы ваша фиксация не содержала изменений, не имеющих отношения к вашей работе.

В этом случае с git вы можете использовать такой скрипт:

#!/bin/sh

set -e # bail on errors

git stash save commit-cleanup
git stash show -p | sed '/^\+/s/ *$//' | git apply
git stash drop

То есть мы сохраняем изменения, а затем фильтруем все строки + в diff, чтобы удалить их конечные пробелы, когда мы повторно применяем изменение к рабочему каталогу. Если этот командный конвейер успешен, мы отбрасываем тайник.

Другие подходы здесь почему-то не работали для меня в MacVim при использовании в файле .vimrc. Итак, вот тот, который выделяет конечные пробелы:

set encoding=utf-8
set listchars=trail:·
set list

autocmd BufWritePre * :%s/\s\+$//<CR>:let @/=''<CR>

Для людей, которые хотят запускать его для определенных типов файлов (FileTypes не всегда надежны):

autocmd BufWritePre *.c,*.cpp,*.cc,*.h,*.hpp,*.py,*.m,*.mm :%s/\s\+$//e

Или с vim7:

autocmd BufWritePre *.{c,cpp,cc,h,hpp,py,m,mm} :%s/\s\+$//e

Если вы обрезаете пробелы, вы должны сделать это с помощью Только для уже чистых файлов. "Когда в Риме...". Это хороший этикет при работе с кодовыми базами, где ложные изменения нежелательны.

Эта функция обнаруживает завершающие пробелы и включает обрезку только в том случае, если они уже были чистыми.

Заслуга в этой идее - жемчужина комментария здесь: https://github.com/atom/whitespace/issues/10 (самый длинный поток комментариев к тикету об ошибке за всю историю)

autocmd BufNewFile,BufRead *.test call KarlDetectWhitespace()

fun! KarlDetectWhitespace()
python << endpython
import vim
nr_unclean = 0
for line in vim.current.buffer:
    if line.rstrip() != line:
        nr_unclean += 1

print "Unclean Lines: %d" % nr_unclean
print "Name: %s" % vim.current.buffer.name
cmd = "autocmd BufWritePre <buffer> call KarlStripTrailingWhitespace()"
if nr_unclean == 0:
    print "Enabling Whitespace Trimming on Save"
    vim.command(cmd)
else:
    print "Whitespace Trimming Disabled"
endpython
endfun

fun! KarlStripTrailingWhitespace()
    let l = line(".")
    let c = col(".")
    %s/\s\+$//e
    call cursor(l, c)
endfun

Я видел это решение в комментарии на VIM Wikia - Удалите ненужные пробелы

Мне действительно это понравилось. Добавляет . на ненужные белые места.

Поместите это в свой .vimrc

" Removes trailing spaces
function TrimWhiteSpace()
  %s/\s*$//
  ''
endfunction

set list listchars=trail:.,extends:>
autocmd FileWritePre * call TrimWhiteSpace()
autocmd FileAppendPre * call TrimWhiteSpace()
autocmd FilterWritePre * call TrimWhiteSpace()
autocmd BufWritePre * call TrimWhiteSpace()