Как я могу преобразовать полные имена людей в имена пользователей в Perl?

Пытаться:

$name =~ s/(\w+),\s(\w)/$2$1/;
$name = lc $name;

\w здесь соответствует буквенно-цифровому символу. Если вы хотите быть более конкретным, вы также можете использовать вместо него [a-z] и передать флаг i (без учета регистра):

$name =~ s/([a-z]+)\s([a-z])/$2$1/i;

Я бы начал с фильтрации аномальных данных, чтобы у вас были только обычные имена. Тогда что-то вроде этого должно помочь

$t = "Parisi, Kenneth";
$t =~ s/(.+),\s*(.).*/\l$2\l$1/;

vinko@parrot:~$ cat genlogname.pl

use strict;
use warnings;

my @list;
push @list, "Zelleb, Charles F.,,IV";
push @list, "Eilt, John,, IV";
push @list, "Woods, Charles R.,,III";
push @list, "Welkt, Craig P.,,Jr.";

for my $name (@list) {
        print gen_logname($name)."\n";
}

sub gen_logname {
        my $n = shift;
        #Filter out unneeded characters
        $n =~ s/['-]//g;
        #This regex will grab the lastname a comma, optionally a space (the 
        #optional space is my addition) and the first char of the name, 
        #which seems to satisfy your condition
        $n =~ m/(\w+), ?(.)/;
        return lc($2.$1);
}

vinko@parrot:~$ perl genlogname.pl
czelleb
jeilt
cwoods
cwelkt

Вот однострочное решение, предполагающее, что вы храните все имена в файле с именем «names» (по одному в каждой строке), и позже вы каким-то образом определите повторяющиеся имена.

cat names | perl -e 'while(<>) {/^\s*(\S*)?,\s*(\S)/; print lc "$2$1\n";}' | sed s/\'//g

Похоже, ваши входные данные разделены запятыми. Для меня самый простой способ сделать это - разбить на компоненты, а затем сгенерировать из них имена для входа:

while (<>) {
    chomp;
    my ($last, $first) = split /,/, lc $_;
    $last =~ s/[^a-z]//g;  # strip out nonletters
    $first =~ s/[^a-z]//g; # strip out nonletters
    my $logname = substr($first, 0, 1) . $last;
    print $logname, "\n";
}

    $rowfetch =~ s/['-]//g; #All chars inside the [ ] will be filtered out.
    $rowfetch =~ m/(\w+), ?(.)/;
    $rowfetch = lc($2.$1);

вот как я закончил использовать решение Винко Врсаловича ... это внутри цикла while, который проходит через результат запроса sql ... еще раз спасибо винко

Это должно делать то, что вам нужно

use strict;
use warnings;
use 5.010;

while ( <DATA> ) {
    say abbreviate($_);
}


sub abbreviate {
    for ( @_ ) {
        s/[-']+//g;
        tr/A-Z/a-z/;
        tr/a-z/ /c;
        return "$2$1" if /([a-z]+)\s+([a-z])/;
    }
}


__DATA__
Zelleb, Charles F.,,IV
Eilt, John,, IV
Woods, Charles R.,,III
Welkt, Craig P.,,Jr.
O'Neil, Paul

выход

czelleb
jeilt
cwoods
cwelkt
poneil