LINQ или XSLT для преобразования одного элемента в другой в Visual Basic 9

Вы ищете что-то вроде этого:

 <xsl:template match = "Tag">
    <xsl:element name = "Genre">
      <xsl:value-of select = "@Name"/>           
    </xsl:element>    
  </xsl:template>

Вы можете сопоставить любой узел с node(), например:

<?xml version = "1.0" encoding = "utf-8"?>
<xsl:stylesheet version = "2.0"
    xmlns:xsl = "http://www.w3.org/1999/XSL/Transform">

<!-- Uncomment to remove Tags elements -->
<!-- <xsl:template match = "Tags" /> -->

<xsl:template match = "Genres">
    <xsl:copy>
        <xsl:apply-templates select = "@*|node()" />
        <xsl:for-each select = "../Tags/Tag">
            <xsl:element name = "Genre">
                <xsl:value-of select = "@Name" />
            </xsl:element>
        </xsl:for-each>
    </xsl:copy>
</xsl:template>

<!-- Default rule: Copy node and descend -->
<xsl:template match = "@*|node()">
        <xsl:copy>
                <xsl:apply-templates select = "@*|node()"/>
        </xsl:copy>
</xsl:template>

</xsl:stylesheet>

Используя один из самых фундаментальных и мощных шаблонов проектирования XSLT: переопределив шаблон удостоверения личности, можно написать это очень простое преобразование, чтобы заменить каждый элемент «Жанры» на элемент «Темы»:

<xsl:stylesheet version = "1.0"
 xmlns:xsl = "http://www.w3.org/1999/XSL/Transform">

 <xsl:output omit-xml-declaration = "yes"/>

    <xsl:template match = "node()|@*">
      <xsl:copy>
         <xsl:apply-templates select = "node()|@*"/>
      </xsl:copy>
    </xsl:template>

    <xsl:template match = "Genres">
      <Topics>
         <xsl:apply-templates select = "node()|@*"/>
      </Topics>
    </xsl:template>
</xsl:stylesheet>

При применении к предоставленному исходному XML-документу:

<Collection>
    <DVD>
        <ID>0000502461</ID>
        <Title>Cirque du Soleil: Alegría</Title>
        <Released>2002-05-31</Released>
        <RunningTime>90</RunningTime>
        <Genres>
            <Genre>Family</Genre>
            <Genre>Music</Genre>
        </Genres>
        <Overview>What if anything were possible? What if ...    </Overview>
        <Notes/>
        <Tags>
            <Tag Name = "Kids" FullName = "Kids"/>
        </Tags>
    </DVD>
</Collection>

Получен желаемый результат:

<Collection>
    <DVD>
        <ID>0000502461</ID>
        <Title>Cirque du Soleil: Alegría</Title>
        <Released>2002-05-31</Released>
        <RunningTime>90</RunningTime>
        <Topics>
            <Genre>Family</Genre>
            <Genre>Music</Genre>
        </Topics>
        <Overview>What if anything were possible? What if ...    </Overview>
        <Notes/>
        <Tags>
            <Tag Name = "Kids" FullName = "Kids"/>
        </Tags>
    </DVD>
</Collection>

Первый шаблон в таблице стилей - это правило идентификации. Он копирует любой согласованный узел без изменений и рекурсивно применяет шаблоны к его атрибутам или дочерним элементам. Если другого шаблона нет, этот шаблон создает идентичную копию исходного xml-документа, отсюда и его название.

Когда существует более конкретный шаблон (с указанием более конкретных деталей для согласованного узла, таких как имя и / или другие условия), говорят, что он «переопределяет» более общие шаблоны. Это означает, что для обработки узла выбран более конкретный шаблон.

Используя этот чрезвычайно мощный шаблон проектирования, легко реализовать в несколько строк такую ​​обработку, как:

1. Удалите все узлы, удовлетворяющие некоторому условию.
2. Переименуйте все узлы, удовлетворяющие некоторому условию.
3. Измените содержимое всех узлов, удовлетворяющих некоторому условию

при копировании всех остальных узлов нетронутыми.

В нашем случае второй шаблон более конкретен и выбирается для обработки каждого элемента с именем «Жанры». Все, что он делает, - это создает элемент с именем «Темы» и внутри него применяет шаблоны ко всем текущим атрибутам и дочерним элементам узла.

Ну наконец то, следующее преобразование добавит новый элемент «Жанр» к дочерним элементам «Жанры» для каждого элемента «Тег».:

<xsl:stylesheet version = "1.0"
 xmlns:xsl = "http://www.w3.org/1999/XSL/Transform">

 <xsl:output omit-xml-declaration = "yes"/>

    <xsl:template match = "node()|@*">
      <xsl:copy>
         <xsl:apply-templates select = "node()|@*"/>
      </xsl:copy>
    </xsl:template>

    <xsl:template match = "Genres">
      <xsl:copy>
         <xsl:apply-templates select = "node()|@*"/>
         <xsl:apply-templates select = "../Tags/Tag" mode = "Gen"/>
      </xsl:copy>
    </xsl:template>

    <xsl:template match = "Tag" mode = "Gen">
      <Genre>
        <xsl:value-of select = "@Name"/>
      </Genre>
    </xsl:template>
</xsl:stylesheet>

Результат снова такой, как требуется:

<Collection>
    <DVD>
        <ID>0000502461</ID>
        <Title>Cirque du Soleil: Alegría</Title>
        <Released>2002-05-31</Released>
        <RunningTime>90</RunningTime>
        <Genres>
            <Genre>Family</Genre>
            <Genre>Music</Genre>

        <Genre>Kids</Genre>

        </Genres>
        <Overview>What if anything were possible? What if ...    </Overview>
        <Notes/>
        <Tags>
            <Tag Name = "Kids" FullName = "Kids"/>
        </Tags>
    </DVD>
</Collection>

Дополнительные фрагменты кода, использующие шаблон «правила идентификации», можно найти здесь.

У меня была такая же потребность в VB9, и я хотел использовать Linq вместо XSL. Я нашел это: http://msdn.microsoft.com/en-us/library/bb669154.aspx, и он работал очень хорошо.