Можно ли изменить шрифт установки NSIS (без установки шрифта)?

Я попробовал использовать шрифт из NSIS, как показано ниже.

CreateFont $0 "Fonts installed on the system" 9 "500"

Я хочу сделать следующее:

Файлы шрифтов (.ttf) включены в установку.
Однако я хотел бы изменить шрифты на странице настройки, не устанавливая их в системе пользователя (Windows Fonts.)

Причина в том, что существует отдельная программа удаления,

Я хочу удалить только каталог шрифтов, установленный при предыдущей настройке, и не хочу удалять шрифты в системе пользователя.

(08.07.2024) меня нашли плагин font-info Однако пользователи API и примеры не объясняют подробно, как они его используют.

Какую минимальную версию Windows вам необходимо поддерживать?

— 05.07.2024 16:12

больше, чем Windows 7 :)

— 08.07.2024 06:43

fonts nsis modern-ui

05.07.2024 13:24

Стоит ли изучать PHP в 2023-2024 годах?

Привет всем, сегодня я хочу высказать свои соображения по поводу вопроса, который я уже много раз получал в своем сообществе: "Стоит ли изучать PHP в...

Поведение ключевого слова "this" в стрелочной функции в сравнении с нормальной функцией

В JavaScript одним из самых запутанных понятий является поведение ключевого слова "this" в стрелочной и обычной функциях.

Приемы CSS-макетирования - floats и Flexbox

Здравствуйте, друзья-студенты! Готовы совершенствовать свои навыки веб-дизайна? Сегодня в нашем путешествии мы рассмотрим приемы CSS-верстки - в...

Тестирование функциональных ngrx-эффектов в Angular 16 с помощью Jest

В системе управления состояниями ngrx, совместимой с Angular 16, появились функциональные эффекты. Это здорово и делает код определенно легче для...

Концепция локализации и ее применение в приложениях React ⚡️

Локализация - это процесс адаптации приложения к различным языкам и культурным требованиям. Это позволяет пользователям получить опыт, соответствующий...

Пользовательский скаляр GraphQL

Листовые узлы системы типов GraphQL называются скалярами. Достигнув скалярного типа, невозможно спуститься дальше по иерархии типов. Скалярный тип...

Перейти к ответу Данный вопрос помечен как решенный

Ответы 1

Ответ принят как подходящий

RequestExecutionLevel User
!include LogicLib.nsh
!include WinMessages.nsh
#!define EXAMPLE_SETALL ; Uncomment to set the font for all controls


!define /IfNDef FR_PRIVATE  0x10
!define /IfNDef FR_NOT_ENUM 0x20
!macro LoadCustomFont path
System::Call 'GDI32::AddFontResourceEx(t "${path}", i ${FR_PRIVATE}|${FR_NOT_ENUM}, p0)i'
!macroend
!macro FreeCustomFont path
System::Call 'GDI32::RemoveFontResourceEx(t "${path}", i ${FR_PRIVATE}|${FR_NOT_ENUM}, p0)i'
!macroend

var FontPath

!ifdef EXAMPLE_SETALL
SetFont "Cascadia Code PL" 8
!else
var CustomFontHandle
Page InstFiles "" OnInstFilesShow
Function OnInstFilesShow
    System::Call GDI32::DeleteObject(p$CustomFontHandle)
    !insertmacro FreeCustomFont $FontPath
    !insertmacro LoadCustomFont $FontPath
    GetDlgItem $0 $hWndParent 1 ; The Next/Close button
    CreateFont $CustomFontHandle "Cascadia Code PL" 8 400 /UNDERLINE
    SendMessage $0 ${WM_SETFONT} $CustomFontHandle 1
FunctionEnd
!endif

Function .onInit
${IfNot} ${Silent}
    InitPluginsDir
    StrCpy $FontPath "$PluginsDir\CascadiaCodePL.ttf"
    File "/oname=$FontPath" "CascadiaCodePL.ttf" #github.com/microsoft/cascadia-code/releases
    !ifdef EXAMPLE_SETALL
        !insertmacro LoadCustomFont $FontPath
    !endif
${EndIf}
FunctionEnd

Function .onGUIEnd
!ifndef EXAMPLE_SETALL
    System::Call GDI32::DeleteObject(p$CustomFontHandle)
!endif
!insertmacro FreeCustomFont $FontPath
FunctionEnd

Section
SectionEnd

Спасибо. Благодаря вашему ответу я сделал именно то, что хотел. @Андерс

— 09.07.2024 09:23

К сожалению, моя минимальная репутация — 11, поэтому я не смог дать рекомендацию «полезный голос» (более 15) в этом ответе.

— 09.07.2024 09:24

@tuxNeoh Вы можете принять ответ...

— 10.07.2024 15:12

@tuxNeoh смотри Что мне делать, когда кто-то отвечает на мой вопрос?

— 10.07.2024 16:25

08.07.2024 12:16