Мухобойка в обработке – почти работает

Вы очень близки, однако части вашего кода требуют более пристального внимания, так как есть несколько ошибок:

• mousePressed() функция, которую можно переопределить в любом скетче обработки:
• вызывать его с draw() нет необходимости (вот почему одна из причин, по которой вы видите дубликаты)
• if (mousePressed) { внутри mousePressed() является избыточным, так как функция должна вызываться только один раз за клик. (Попробуйте справочный пример в отдельном эскизе, чтобы освоиться)
• Еще один источник дубликатов мух — это состояние ограничивающей рамки внутри collisionDetect()

if (mouseX > fX[i] && mouseX < fX[i] + fly.width &&
        mouseY > fY[i] && mouseY < fY[i] + fly.height)...

только проверяет, находится ли внутри коробки муха (любая муха, даже уже прихлопнутая). Возможно, вы захотите еще больше ограничить это, фильтруя неотбитых мух только перед увеличением оценки и добавлением новой мухи.

например

void collisionDetect() {
  for (int i = 0; i < swat.length; i++) {
    if (mouseX > fX[i] && mouseX < fX[i] + fly.width &&
        mouseY > fY[i] && mouseY < fY[i] + fly.height &&
        // also check this fly has not been swatted (yet)
        swat[i] == 0) {
          swat[i] = 1;
          fX = append(fX, random(width));
          fY = append(fY, random(height));
          swat = append(swat, 0);
          score++;
          }
  } 
}

Это ваш код с добавленными выше упоминаниями:

PImage fly, flybye, swatter, swatted;
float[] fX, fY; // Declaring fX & fY location arrays
int[] swat;
int score = 0;

void setup() {
  size(800, 400);
  // Images
  fly = loadImage("fly.png");
  fly.resize(50,0);
  flybye = loadImage("flybye.png");
  flybye.resize(50,0);
  swatter = loadImage("swatter.png");  
  swatted = loadImage("swatted.png");
  
  fX = new float[0];
  fY = new float[0];
  swat = new int[0];
  
  fX = append(fX, random(width));
  fY = append(fY, random(height));
  swat = append(swat, 0);
}

void draw() {
  background(255);
  populate(); // Displays flys to the screen
  fill(0);
  textSize(30);
  text("Score: " + score, 20, 50); // Displays the score in the top left corner 
  noCursor(); // Removes the cursor from the screen
}

void populate() {
  for (int i = 0; i < fX.length; i++) {
    if (swat[i] == 1) { // if swatted
      image(flybye, fX[i], fY[i]);
    } else {
      image(fly, fX[i], fY[i]);
    }
  }
}

void collisionDetect() {
  for (int i = 0; i < swat.length; i++) {
    if (mouseX > fX[i] && mouseX < fX[i] + fly.width &&
        mouseY > fY[i] && mouseY < fY[i] + fly.height &&
        // also check this fly has not been swatted (yet)
        swat[i] == 0) {
          swat[i] = 1;
          fX = append(fX, random(width));
          fY = append(fY, random(height));
          swat = append(swat, 0);
          score++;
          }
  } 
}

void mousePressed() {
  collisionDetect();
}

Другие вещи, которые можно улучшить:

• форматирование: вы можете использовать Ctrl+T/CMD+T для приведения в порядок кода. Это облегчает чтение, и это хорошая привычка. В долгосрочной перспективе вы потратите больше времени на чтение/понимание кода, чем на его написание. Даже вернуться к собственному коду через две недели или больше будет проще, если вы отформатируете/комментируете/и т. д. и облегчите жизнь себе в будущем
• вы можете избежать копирования/вставки кода, инкапсулируя повторно используемые блоки кода. В этом случае добавление полета (один раз в настройке, при столкновении), а также условие проверки столкновения можно инкапсулировать в функцию, которую вы можете легко повторно использовать в любом другом эскизе.

например

PImage fly, flybye, swatter, swatted;
float[] fX, fY; // Declaring fX & fY location arrays
int[] swat;
int score = 0;

void setup() {
  size(800, 400);
  noCursor(); // Removes the cursor from the screen
  // Images
  fly = loadImage("fly.png");
  fly.resize(50, 0);
  flybye = loadImage("flybye.png");
  flybye.resize(50, 0);
  swatter = loadImage("swatter.png");
  swatted = loadImage("swatted.png");
  
  fX = new float[0];
  fY = new float[0];
  swat = new int[0];

  addFly();
}

void draw() {
  background(255);
  populate(); // Displays flys to the screen
  fill(0);
  textSize(30);
  text("Score: " + score, 20, 50); // Displays the score in the top left corner
}

void populate() {
  for (int i = 0; i < swat.length; i++) {
    if (swat[i] == 1) { // if swatted
      image(flybye, fX[i], fY[i]);
    } else {
      image(fly, fX[i], fY[i]);
    }
  }
}

void collisionDetect() {
  for (int i = 0; i < swat.length; i++) {
    if (isPointInRect(mouseX, mouseY, fX[i], fY[i], fly.width, fly.height) &&
      // also check this fly has not been swatted (yet)
      swat[i] == 0) {
      // mark this index as swatted
      swat[i] = 1;
      // increment score
      score++;
      // add new fly
      addFly();
    }
  }
}

void addFly() {
  fX = append(fX, random(width));
  fY = append(fY, random(height));
  swat = append(swat, 0);
}

boolean isPointInRect(int mx, int my, float rx, float ry, float rw, float rh) {
  return (mx >= rx && mx <= rx + rw) &&
         (my >= ry && my <= ry + rh);
}

void mousePressed() {
  collisionDetect();
}

Делайте это шаг за шагом. Иногда в коде замедление/перепроверка предположений поможет вам преодолеть черту быстрее, чем спешка. Веселиться !