Объединить строки / объединить строки

Я думаю, что Nz - это то, что вам нужно, синтаксис - Nz(variant, [if null value]). Вот ссылка на документацию: Функция Nz

---Person--- 
John
Steve
Richard

DECLARE @PersonList nvarchar(1024)
SELECT @PersonList = Nz(@PersonList + ',','') + Person
FROM PersonTable

PRINT @PersonList

Хотя Nz делает то же самое, что и COALESCE, вы не можете использовать его в Access для выполнения операции, которую вы выполняете. Список значений строк строится не COALESCE, а объединением в переменную.

К сожалению, это невозможно внутри запроса Access, который должен быть единственным оператором SQL и где нет возможности объявить переменную.

Я думаю, вам нужно будет создать функцию, которая открывала бы набор результатов, перебирала его и объединяла значения строки в строку.

Чтобы объединить строки в Access, вам, вероятно, понадобится код, который выглядит примерно так:

Public Function Coalesce(pstrTableName As String, pstrFieldName As String)

Dim rst As DAO.Recordset
Dim str As String

    Set rst = CurrentDb.OpenRecordset(pstrTableName)
    Do While rst.EOF = False
        If Len(str) = 0 Then
            str = rst(pstrFieldName)
        Else
            str = str & "," & rst(pstrFieldName)
        End If
        rst.MoveNext
    Loop

    Coalesce = str

End Function

Вы захотите добавить код обработки ошибок и очистить свой набор записей, и это немного изменится, если вы будете использовать ADO вместо DAO, но общая идея остается той же.

Я так понимаю, у вас есть таблица "человек" с 3 записями. Нет ничего похожего на то, что вы описываете в Access.

В "стандартном" доступе (набор записей DAO) вам нужно будет открыть набор записей и использовать метод getrows для получения ваших данных

Dim rs as DAO.recordset, _
    personList as String, _
    personArray() as variant

set rs = currentDb.open("Person")
set personArray = rs.getRows(rs.recordcount)

rs.close

как только у вас есть этот массив (он будет двумерным), вы можете манипулировать им, чтобы извлечь «столбец», который вам понадобится. Может быть разумный способ извлечь из этого одномерный массив, поэтому вы можете затем использовать инструкцию «Присоединиться» для объединения каждого значения массива в одну строку.

Вот пример определяемой пользователем функции (UDF) и возможные варианты использования.

Функция:

Function Coalsce(strSQL As String, strDelim, ParamArray NameList() As Variant)
Dim db As Database
Dim rs As DAO.Recordset
Dim strList As String

    Set db = CurrentDb

    If strSQL <> "" Then
        Set rs = db.OpenRecordset(strSQL)

        Do While Not rs.EOF
            strList = strList & strDelim & rs.Fields(0)
            rs.MoveNext
        Loop

        strList = Mid(strList, Len(strDelim))
    Else

        strList = Join(NameList, strDelim)
    End If

    Coalsce = strList

End Function

Использование:

SELECT documents.MembersOnly, 
    Coalsce("SELECT FName From Persons WHERE Member=True",":") AS Who, 
    Coalsce("",":","Mary","Joe","Pat?") AS Others
FROM documents;

Версия ADO, вдохновленная комментарием onedaywhen

Function ConcatADO(strSQL As String, strColDelim, strRowDelim, ParamArray NameList() As Variant)
   Dim rs As New ADODB.Recordset
   Dim strList As String

   On Error GoTo Proc_Err

       If strSQL <> "" Then
           rs.Open strSQL, CurrentProject.Connection
           strList = rs.GetString(, , strColDelim, strRowDelim)
           strList = Mid(strList, 1, Len(strList) - Len(strRowDelim))
       Else
           strList = Join(NameList, strColDelim)
       End If

       ConcatADO = strList

   Exit Function

   Proc_Err:
       ConcatADO = "***" & UCase(Err.Description)
   End Function

От: http://wiki.lessthandot.com/index.php/Concatenate_a_List_into_a_Single_Field_%28Column%29