Очистка PATH в случае дубликатов

Похоже, атрибут -U (уникальный) можно установить отдельно для каждой переменной в паре связанных параметров, таких как path и PATH. Два имени по существу действуют как отдельные интерфейсы для общего бита данных, и поведение меняется, когда для установки и получения этих данных используются разные интерфейсы.

Установив -U для path и PATH, оболочка должна удалять дубликаты независимо от того, как добавляются записи:

typeset -U PATH path

Это все, что абсолютно необходимо, поскольку по умолчанию атрибуты -T (связанный) и -a (массив) для path/PATH уже установлены. Для новой переменной, которая ведет себя аналогичным образом, объявление может выглядеть так:

typeset -aUT LD_LIBRARY_PATH ld_library_path

Тестирование:

=> typeset -aUT PATH path
=> PATH=/usr/bin
=> path+=~/bin
=> typeset -p path
typeset -aUT PATH path=( /usr/bin /Users/me/bin )
=> path+=~/foo
=> path+=~/bin
=> typeset -p path
typeset -aUT PATH path=( /usr/bin /Users/me/bin /Users/me/foo )
=> PATH=~/bin:$PATH
=> typeset -p path
typeset -aUT PATH path=( /Users/me/bin /usr/bin /Users/me/foo )
=> path=(~/foo $path)
=> typeset -p path
typeset -aUT PATH path=( /Users/me/foo /Users/me/bin /usr/bin )

Если -U установлено по-разному для PATH и path:

=> path=()
=> typeset -U path; typeset +U PATH
=> typeset -p PATH path
typeset -T PATH path=(  )
typeset -aUT PATH path=(  )
=> PATH=/foo:/foo:/foo
=> typeset -p PATH path
typeset -T PATH path=( /foo /foo /foo )
typeset -aUT PATH path=( /foo /foo /foo )
=> path+=/bar; path+=/bar; path+=/bar
=> typeset -p PATH path
typeset -T PATH path=( /foo /bar )
typeset -aUT PATH path=( /foo /bar )
=> PATH=/foo:$PATH; PATH=/foo:$PATH;
=> typeset -p PATH path
typeset -T PATH path=( /foo /foo /foo /bar )
typeset -aUT PATH path=( /foo /foo /foo /bar )

=> path=()
=> typeset +U path; typeset -U PATH
=> typeset -p PATH path
typeset -UT PATH path=(  )
typeset -aT PATH path=(  )
=> path+=/alice; path+=/alice; path+=/alice
=> typeset -p PATH path
typeset -UT PATH path=( /alice /alice /alice )
typeset -aT PATH path=( /alice /alice /alice )
=> PATH=$PATH:/bob; PATH=$PATH:/bob; PATH=$PATH:/bob; 
=> typeset -p PATH path
typeset -UT PATH path=( /alice /bob )
typeset -aT PATH path=( /alice /bob )

Бонус — path=($^~path(/N)) можно использовать для удаления несуществующих каталогов и недействительных записей из path:

=> typeset -p path   
typeset -aUT PATH path=( /Users/me/foo /Users/me/bin /etc/hosts /usr/bin )
=> path=($^~path(/N))
=> typeset -p path   
typeset -aUT PATH path=( /Users/me/bin /usr/bin )

• ${^...} - эмулировать раскрытие скобок. Каждый элемент массива дополняется окружающим текстом, например: /Users/me/foo(/N) /Users/me/bin(/N) /etc/hosts(/N) /usr/bin(/N).
• ${~...} - расширение глобуса. Полученные строки используются в качестве шаблонов glob.
• (/) — включать в глобальные расширения только каталоги.
• (N) — разрешить пустые результаты. Итак:
  /Users/me/foo(/N) расширяется до нуля/ноля, поскольку его не существует.
  /Users/me/bin(/N) становится /Users/me/bin.
  /etc/hosts(/N) имеет значение null, потому что это файл.
  /usr/bin(/N) становится /usr/bin.
• path=(...) — сбрасывает path на все, что осталось от расширения. Если для -U установлено path, то добавляются только уникальные значения.

MacOS иногда добавляет бессмысленные записи через /etc/paths.d, это способ их очистить.