Отражение структуры отличается от класса - но только в коде

Что ж, вы не показали весь свой код - в частности, где вы устанавливаете target и как вы потом проверяете значение поля.

Вот пример, который показывает, что он отлично работает на C#:

using System;
using System.Reflection;

struct Foo
{
    public int x;
}

class Test
{
    static void Main()
    {
        FieldInfo field = typeof(Foo).GetField("x");

        object foo = new Foo();
        field.SetValue(foo, 10);
        Console.WriteLine(((Foo) foo).x);
    }
}

(Я почти уверен, что выбор языка здесь не актуален, но с большим количеством кода мы можем сказать наверняка.) Мое сильное подозрение, что вы делаете что-то вроде:

Foo foo = new Foo();
object target = foo;
// SetValue stuff

// What do you expect foo.x to be here?

Значение foo в приведенном выше фрагменте не изменится, потому что во второй строке значение скопировано, когда оно помещено в коробку. После этого вам нужно будет распаковать и снова скопировать:

foo = (Foo) target;

Если это не так, покажите короткую, но полный программу, которая демонстрирует проблему.

Работая с вашим исходным образцом, я согласен, что он работает на C#, но не на VB! Если вы используете Reflector или ILDasm, вы увидите, что вызов Field.SetValue (target, ...) фактически компилируется (в VB) как:

field.SetValue(RuntimeHelpers.GetObjectValue(target), ...)

GetObjectValue "Возвращает упакованную копию obj, если это класс значений; в противном случае возвращается сам объект obj." Т.е. значение устанавливается на копию вашей структуры!

Эта ссылка дает объяснение (такое, какое оно есть). Обходной путь - объявить цель как System.ValueType вместо Object. Я не уверен, действительно ли это помогает в вашем реальном коде: вам может потребоваться беспорядочный тест типов, чтобы иметь возможность обрабатывать типы значений отдельно от ссылочных типов.

Проблема в том, что VB делает копию объекта, и инструкция setvalue применяется к копии, но не к самому объекту. Обходной путь - восстановить изменения исходного объекта с помощью вспомогательной переменной и функции CType. В следующем примере мы хотим установить для поля страна переменной чемпион значение Испания (чемпион - это структура * St_WorldChampion *). Мы вносим изменения в переменную Икс, а затем копируем их в переменную чемпион. Оно работает.

Public Structure St_WorldChampion
    Dim sport As String
    Dim country As String
End Structure

Sub UpdateWorldChampion()
    Dim champion As New St_WorldChampion, x As ValueType
    Dim prop As System.Reflection.FieldInfo

    ' Initial values: Germany was the winner in 2006
    champion.country = "Germany"
    champion.sport = "Football"

    ' Update the World Champion: Spain since 2010
    x = champion
    prop = x.GetType().GetField("country")
    prop.SetValue(x, "Spain")
    champion = CType(x, St_WorldChampion)

End Sub

Привет, я сделал эту функцию на христианском примере, надеюсь, это поможет. Эта функция использует свойства, на которые также влияют

''' <summary>
''' Establece el -valor- en la -propiedad- en el -objeto-
''' Sets Value in Objeto.[propertyname]
''' </summary>
''' <param name = "objeto">Object where we will set this property</param>
''' <param name = "Propiedad">Name of the property</param>
''' <param name = "valor">New Value of the property</param>
''' <returns>Object with changed property</returns>
''' <remarks>It works on structures!</remarks>
Function Establecer_propiedad(objeto As Object, Propiedad As String, valor As Object) As Object
    'Check arguments
    If objeto Is Nothing Then Throw New ArgumentNullException("Objeto")
    If String.IsNullOrWhiteSpace(Propiedad) Then Throw New ArgumentNullException("Propiedad")
    'Get the object type
    Dim t As Type = objeto.GetType
    'Get the propertyInfo by its name
    Dim prop As PropertyInfo = t.GetProperty(Propiedad)
    'Check if the property exist
    If prop Is Nothing Then Throw New InvalidOperationException("Property does not exist")
    If Not prop.CanWrite Then Throw New InvalidOperationException("Property is read only")
    'Determine if it is a class or a structure
    If Not t.IsValueType Then ' (it is a reference value)
        'Set without troubles
        If prop.CanWrite Then prop.SetValue(objeto, valor)
        'Return object
        Return objeto
    Else '(It is a structure)
        'Create a box using a valuetype
        'It doesnot work in object
        Dim Box As ValueType
        'Set item in box
        Box = objeto
        'Set value in box
        prop.SetValue(Box, valor)
        'Return box
        Return Box
    End If
End Function