Парсинг веб-страниц по элементам

Я думаю, вы хотите что-то вроде следующего.

Начальная ошибка:

Я думаю, что ваша первоначальная ошибка отчасти связана с тем, что URL-адрес не возвращает html, который вы видите при использовании того же URL-адреса в браузере. Содержимое, которое я видел, не содержало этих списков в ответе, поэтому количество строк было равно 0; следовательно, ваша ошибка subscript out of range ошибка в этой строке: ReDim results(1 To rowCount, 1 To numColumns)

Итак, URL-адрес изменился на:

https://www.stormore.net/self-storage-seattle-wa-101616

Следующий:

Изучая html, чтобы узнать, как генерировать строки списков, мы замечаем, что списки четко представлены .main li.pure-g. В li необходимо добавить дополнительный класс для фильтрации нежелательной информации. Мы хотим зацикливать только строки, содержащие интересующую информацию.

Set listings = html.querySelectorAll(".main li.pure-g")

Ну наконец то:

При проверке html мы замечаем, что не все строки содержат все интересующие элементы, например. offer1 и offer2, поэтому мы заключаем попытки доступа к некоторым элементам в On Error Resume Next, On Error GoTo 0, чтобы замаскировать ошибку и вывести «» в этом столбце вывода.

VBA:

Option Explicit

Public Sub GetInfo()
    Dim ws As Worksheet, html As HTMLDocument, s As String
    Const URL As String = "https://www.stormore.net/self-storage-seattle-wa-101616"

    Set ws = ThisWorkbook.Worksheets("Sheet1")
    Set html = New HTMLDocument
    With CreateObject("MSXML2.XMLHTTP")
        .Open "GET", URL, False
        .setRequestHeader "User-Agent", "Mozilla/5.0"
        .send
        s = .responseText

        html.body.innerHTML = s

        Dim headers(), results(), listings As Object, amenities As String

        headers = Array("Size", "Description", "Amenities", "Offer1", "Offer2", "RateType", "Price")
        Set listings = html.querySelectorAll(".main li.pure-g")

        Dim rowCount As Long, numColumns As Long, r As Long, c As Long
        Dim icons As Object, icon As Long, amenitiesInfo(), i As Long, item As Long

        rowCount = listings.Length
        numColumns = UBound(headers) + 1

        ReDim results(1 To rowCount, 1 To numColumns)
        Dim html2 As HTMLDocument
        Set html2 = New HTMLDocument
        For item = 0 To listings.Length - 1
            r = r + 1
            html2.body.innerHTML = listings.item(item).innerHTML
            'size,description, amenities,specials offer1 offer2, rate type, price

            results(r, 1) = Trim$(html2.querySelector(".size").innerText)
            results(r, 2) = Trim$(html2.querySelector(".description").innerText)
            On Error Resume Next
            Set icons = html2.querySelectorAll("i[title]")
            ReDim amenitiesInfo(0 To icons.Length - 1)

            For icon = 0 To icons.Length - 1
                amenitiesInfo(icon) = icons.item(icon).getAttribute("title")
            Next

            amenities = Join$(amenitiesInfo, ", ")

            results(r, 3) = amenities

            results(r, 4) = html2.querySelector(".offer1").innerText
            results(r, 5) = html2.querySelector(".offer2").innerText
            On Error GoTo 0
            results(r, 6) = html2.querySelector(".rate-label").innerText
            results(r, 7) = html2.querySelector(".price").innerText
        Next

        ws.Cells(1, 1).Resize(1, UBound(headers) + 1) = headers
        ws.Cells(2, 1).Resize(UBound(results, 1), UBound(results, 2)) = results
    End With
End Sub