Перечисление всех строк в resx

Мы хотели бы перечислить все строки в файле ресурсов в .NET (файл resx). Мы хотим, чтобы это сгенерировало объект javascript, содержащий все эти пары ключ-значение. Мы делаем это сейчас для вспомогательных сборок с таким кодом (это VB.NET, но подойдет любой пример кода):

Dim rm As ResourceManager
rm = New ResourceManager([resource name], [your assembly])
Dim Rs As ResourceSet
Rs = rm.GetResourceSet(Thread.CurrentThread.CurrentCulture, True, True)
For Each Kvp As DictionaryEntry In Rs
    [Write out Kvp.Key and Kvp.Value]
Next

Однако, к сожалению, мы еще не нашли способ сделать это для файлов .resx. Как мы можем перечислить все строки локализации в файле resx?

ОБНОВИТЬ:

Следуя комментарию Денниса Майрена и идеям здесь, я создал ResXResourceManager. Теперь я могу делать с файлами .resx то же самое, что и со встроенными ресурсами. Вот код. Обратите внимание, что Microsoft сделала необходимый конструктор закрытым, поэтому я использую отражение для доступа к нему. Вам нужно полное доверие при использовании этого.

Imports System.Globalization
Imports System.Reflection
Imports System.Resources
Imports System.Windows.Forms

Public Class ResXResourceManager
    Inherits ResourceManager

    Public Sub New(ByVal BaseName As String, ByVal ResourceDir As String)
        Me.New(BaseName, ResourceDir, GetType(ResXResourceSet))
    End Sub

    Protected Sub New(ByVal BaseName As String, ByVal ResourceDir As String, ByVal UsingResourceSet As Type)
        Dim BaseType As Type = Me.GetType().BaseType
        Dim Flags As BindingFlags = BindingFlags.NonPublic Or BindingFlags.Instance
        Dim Constructor As ConstructorInfo = BaseType.GetConstructor(Flags, Nothing, New Type() { GetType(String), GetType(String), GetType(Type) }, Nothing)
        Constructor.Invoke(Me, Flags, Nothing, New Object() { BaseName, ResourceDir, UsingResourceSet }, Nothing)
    End Sub

    Protected Overrides Function GetResourceFileName(ByVal culture As CultureInfo) As String
        Dim FileName As String
        FileName = MyBase.GetResourceFileName(culture)
        If FileName IsNot Nothing AndAlso FileName.Length > 10 Then
            Return FileName.Substring(0, FileName.Length - 10) & ".resx"
        End If
        Return Nothing
    End Function
End Class