Получить вложение файла из MMS через контроллер ASP.NET MVC

Используемый вами класс SmsRequest взят из вспомогательной библиотеки Twilio для ASP.NET, цель которой — упростить интеграцию Twilio в ASP.NET. Однако SmsRequest и другие классы не охватывают все возможные параметры веб-перехватчика. Если в классе отсутствуют параметры, вы все равно можете получить параметры вручную, а не полагаться на привязку модели MVC.

На основе этого примера C# я создал пример VB.NET, чтобы показать, как получать и сохранять входящие файлы MMS:

Imports System.IO
Imports System.Net.Http
Imports System.Threading.Tasks
Imports MimeTypes
Imports Twilio.AspNet.Mvc
Imports Twilio.TwiML
Imports Twilio.TwiML.Messaging

Public Class HomeController
    Inherits TwilioController

    Shared httpClient As HttpClient = New HttpClient

    Async Function Index() As Task(Of TwiMLResult)
        Dim response As New MessagingResponse
        Dim message As New Message

        Dim numMedia = Short.Parse(If(Request.Form.Get("NumMedia"), 0))
        If numMedia = 0 Then
            response.Message("No file received.")
            Return TwiML(response)
        End If

        For mediaIndex As Integer = 0 To numMedia - 1
            Dim mediaUrl = Request.Form.Get($"MediaUrl{mediaIndex}")
            Dim contentType = Request.Form.Get($"MediaContentType{mediaIndex}")
            Dim saveFilePath = Server.MapPath(String.Format(
                "~/App_Data/{0}{1}",
                Path.GetFileName(mediaUrl),
                MimeTypeMap.GetExtension(ContentType)
            ))
            Await DownloadUrlToFileAsync(mediaUrl, saveFilePath)
        Next

        response.Message("File received.")
        Return TwiML(response)
    End Function

    Private Async Function DownloadUrlToFileAsync(mediaUrl As String, saveFilePath As String) As Task
        Dim Response = Await httpClient.GetAsync(mediaUrl)
        Dim httpStream = Await Response.Content.ReadAsStreamAsync()
        Using fileStream As Stream = IO.File.Create(saveFilePath)
            Await httpStream.CopyToAsync(fileStream)
            Await fileStream.FlushAsync()
        End Using
    End Function


End Class

Вероятно, вы можете немного упростить код, предполагая, что по MMS будет отправлен только один файл, но это хорошая идея, чтобы обрабатывать и другие случаи.

Чтобы получить правильное расширение файла, я использую это Библиотека MimeTypeMap, но можно накатить собственное решение.

По умолчанию файлы из входящих MMS общедоступны по MediaUrl{mediaIndex} URL-адресу, но рекомендуется включить базовую аутентификацию для этих медиафайлов.

Если вы включаете обычную аутентификацию для медиафайлов, вам необходимо добавить заголовок аутентификации в HTTP-запросы, например:

Imports System.IO
Imports System.Net.Http
Imports System.Net.Http.Headers
Imports System.Threading.Tasks
Imports MimeTypes
Imports Twilio.AspNet.Mvc
Imports Twilio.TwiML
Imports Twilio.TwiML.Messaging

Public Class HomeController
    Inherits TwilioController

    Shared httpClient As HttpClient = CreateHttpClient()
    Private Shared Function CreateHttpClient() As HttpClient
        Dim client As New HttpClient
        Dim appSettings As NameValueCollection = ConfigurationManager.AppSettings
        If Boolean.Parse(If(appSettings.Get("TwilioUseBasicAuthForMedia"), False)) Then
            Dim authString = $"{appSettings.Get("TwilioAccountSid")}:{appSettings.Get("TwilioAuthToken")}"
            authString = Convert.ToBase64String(Encoding.ASCII.GetBytes(authString))
            client.DefaultRequestHeaders.Authorization = New AuthenticationHeaderValue("Basic", authString)
        End If

        Return client
    End Function

    ...

End Class

Я получаю TwilioUseBasicAuthForMedia, TwilioAccountSid и TwilioAuthToken из настроек приложения Web.config.

(Убедитесь, что вы не проверяете эти секреты в системе управления версиями, а используйте вместо этого UserSecretsConfigBuilder, чтобы безопасно установить секреты).

Вот исходный код на GitHub.

Вы можете отправить сообщение о проблеме GitHub и/или PR, чтобы добавить поддержку этих отсутствующих параметров в SmsRequest. Хотя это будет не так просто, как обычная привязка модели, потому что количество параметров увеличивается по мере того, как больше файлов отправляется по MMS.