Проблемы с развертыванием RAD-сервера в IIS

Оказывается, в моей программе создания PDF-файлов из динамически создаваемых FastReports не было ничего плохого, и не было никаких редких сломанных зависимостей. Fastreports работал нормально, проблема заключалась в возврате этих данных в EndpointResponse (но вслепую, без журналов, мне потребовалось много времени, чтобы понять это).

Если кто-то хочет генерировать отчеты со стороны сервера полностью динамически, это моя процедура. Для удобства я использую SmartPointers, поэтому компоненты освобождаются сами (но их можно легко удалить).

unit MyReportUtilsUnit;

interface

uses
  System.Classes,
  System.SysUtils,
  System.Types,
  frxClass,
  frxExportPDF,
  Data.DB,
  FireDAC.Comp.DataSet,
  SmartPointerClass;

type
  TKeyValue = record
    Key: string;
    Value: variant;
  end;
  TKeyValueArray = array of TKeyValue;

  TDatasetArray = array of TFDDataset;

  TMyReportUtils = record
    class function BuildReport(ReportOwner: TComponent; Template: TBytes; DataQuerys: TDatasetArray; Variables: TKeyValueArray): TfrxReport; static;
    class function ExportToPDF(ReportOwner: TComponent; Template: TBytes; DataQuerys: TDatasetArray; Variables: TKeyValueArray): TStream; static;
  end;

var
  MyReportUtils: TMyReportUtils;

implementation

uses
  System.Variants,
  System.Diagnostics,
  System.Math,
  System.IOUtils,
  frxDBSet,
  frxBarcode,
  frxTableObject;

class function TMyReportUtils.BuildReport(ReportOwner: TComponent; Template: TBytes; DataQuerys: TDatasetArray; Variables: TKeyValueArray): TfrxReport;
var
  Report: TfrxReport;
  StreamTemplate: TSmartPointer<TBytesStream>;
  fdbDataset: TfrxDBDataset;
begin
  Report := TfrxReport.Create(ReportOwner);
  Report.Clear;

  Report.EngineOptions.UseFileCache := False;
  Report.ShowProgress := False;
  Report.EngineOptions.SilentMode := True;

  StreamTemplate := TBytesStream.Create(Template);
  StreamTemplate.Value.Position := 0;
  if StreamTemplate.Value.Size > 0 then
    Report.LoadFromStream(StreamTemplate.Value);

  for var InputItem in Variables do
    Report.Variables.AddVariable('Variables', InputItem.Key, VarToStr(InputItem.Value));

  Report.DataSets.Clear;
  for var DataQuery in DataQuerys do
  begin
    fdbDataset := TfrxDBDataset.Create(ReportOwner);
    fdbDataset.UserName := DataQuery.Name;
    fdbDataset.Name := 'fdb' + DataQuery.Name;
    fdbDataset.CloseDatasource := False;
    fdbDataset.DataSet := DataQuery;
    Report.DataSets.Add(fdbDataset);
  end;

  Report.PrepareReport(True);  // ToDo: Check why it needs to be prepared twice in order to load its datasets
  Report.PrepareReport(True);

  Result := Report;
end;

class function TMyReportUtils.ExportToPDF(ReportOwner: TComponent; Template: TBytes; DataQuerys: TDatasetArray; Variables: TKeyValueArray): TStream;
var
  frReport: TfrxReport;
  frPDF: TSmartPointer<TfrxPDFExport>;
begin
  Result := TBytesStream.Create;

  frPDF := TfrxPDFExport.Create(ReportOwner);
  frPDF.Value.Stream := Result;
  frPDF.Value.Compressed := True;
  frPDF.Value.EmbeddedFonts := False;
  frPDF.Value.Outline := False;
  frPDF.Value.OpenAfterExport := False;
  frPDF.Value.ShowProgress := False;
  frPDF.Value.ShowDialog := False;
  frPDF.Value.PrintOptimized := False;
  frPDF.Value.PictureDPI :=  600;
  frPDF.Value.Quality := 95;
  frPDF.Value.UseFileCache := False;
  frPDF.Value.Background := False;
  frPDF.Value.CenterWindow := False;
  frPDF.Value.DataOnly := False;
  frPDF.value.EmbedFontsIfProtected := False;
  frPDF.Value.FitWindow := False;
  frPDF.value.HideMenubar := False;
  frPDF.Value.HideToolbar := False;
  frPDF.Value.HideWindowUI := False;
  frPDF.Value.OverwritePrompt := False;
  frPDF.Value.PdfA := False;
  frPDF.Value.PrintScaling := False;
  frPDF.Value.HTMLTags := False;
  frPDF.Value.Transparency := False;

  frReport := BuildReport(ReportOwner, Template, DataQuerys, Params);
  frReport.Export(frPDF);

  Result.Position := 0;
end;

end.

Моя проблема заключалась в том, что BuildReport возвращал TSmartPointer, который отлично работал на EMSDevServer, но под IIS выглядел так, как будто он был освобожден до того, как IIS смог прочитать его значение.

Изменение этой функции для возврата TStream вместо TSmartPointer решило проблему.

Конечная точка изначально была

procedure TdmTestResource.GetReport(const AContext: TEndpointContext; const ARequest: TEndpointRequest; const AResponse: TEndpointResponse);
begin
  var Template: TBytes;
  var ReportDatasets: TDatasetArray;
  var ReportVariables: TKeyValueArray;

  GetData(Self, Template, ReportDatasets, ReportVariables);

  var StreamSmartPtr := MyReportUtils.ExportToPDF(Self, Template, ReportDatasets, ReportVariables);
  AResponse.Body.SetStream(StreamSmartPtr.Value, 'application/pdf', False);
end;

А чтобы вернуть данные из потока вместо TSmartPointer, нужно было всего лишь изменить его на:

procedure TdmTestResource.GetReport(const AContext: TEndpointContext; const ARequest: TEndpointRequest; const AResponse: TEndpointResponse);
begin
  var Template: TBytes;
  var ReportDatasets: TDatasetArray;
  var ReportVariables: TKeyValueArray;

  GetData(Self, Template, ReportDatasets, ReportVariables);

  var Stream := MyReportUtils.ExportToPDF(Self, Template, ReportDatasets, ReportVariables);
  AResponse.Body.SetStream(Stream, 'application/pdf', True);
end;

Используемые SmartPointers рекомендованы Марко Канту.

https://github.com/marcocantu/DelphiSessions/blob/master/DelphiLanguageCodeRage2018/02_SmartPointers/SmartPointerClass.pas