Радиособытие типа ввода в ASP.Net

Конечно, вы можете это сделать.

Вопрос в том, откуда берется список опций для RadioButtonList?

Кроме того, вам не нужна ни таблица, ни весь этот код для создания разметки.

Просто перетащите список радиокнопок на веб-форму из панели инструментов.

Теперь у вас есть это:

        <asp:RadioButtonList ID = "RadioButtonList1" runat = "server">

        </asp:RadioButtonList>

И в представлении формы используйте это:

Итак, теперь мы можем редактировать/добавлять элементы с помощью дизайнера.

Итак, прибавляем 1, а текст Division

и 2 в целом,

Итак, это:

Теперь, конечно, приведенное выше создает эту разметку:

        <asp:RadioButtonList ID = "RadioButtonList1" runat = "server"
            AutoPostBack = "true">
            <asp:ListItem Value = "1">Division</asp:ListItem>
            <asp:ListItem Value = "2">Overall</asp:ListItem>
        </asp:RadioButtonList>
        <br />

        <asp:Label ID = "Label1" runat = "server" Text = ""></asp:Label>

Итак, у нас есть autopostback=true и 2 варианта выше.

Итак, лист свойств, а затем вкладка событий и дважды щелкните событие SelectedIndexChanged отсюда:

Теперь мы можем написать код, чтобы установить значение метки, которая у нас есть ниже.

Protected Sub RadioButtonList1_SelectedIndexChanged(sender As Object, e As EventArgs) Handles RadioButtonList1.SelectedIndexChanged

    Dim strResult As String = ""

    If RadioButtonList1.SelectedIndex = -1 Then
        strResult = "No selection made"
    Else
        strResult = "Value selected = " & RadioButtonList1.SelectedItem.Value &
                    " Text selected value = " & RadioButtonList1.SelectedItem.Text
    End If

    Label1.Text = strResult


End Sub

Кроме того, мы можем настроить кнопки так, чтобы они двигались вертикально или горизонтально.

И мы даже можем добавить некоторые стили к кнопкам.

Итак, теперь у нас есть это:

И вы можете определенно использовать код, чтобы заполнить список вариантов.

Скажите так:

        <asp:RadioButtonList ID = "RadioButtonList1" runat = "server"
            AutoPostBack = "true"
            DataValueField = "ID"
            DataTextField = "HotelName">
        </asp:RadioButtonList>
        <br />

И на нашей странице загрузка, то этот код:

Protected Sub Page_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load

    If Not IsPostBack Then
        LoadButtonList
    End If
End Sub

Sub LoadButtonList()

    Dim strSQL As String =
        "SELECT  ID, HotelName FROM tblHotelsA ORDER BY HotelName"

    Using conn As New SqlConnection(My.Settings.TEST4)
        Using cmdSQL As New SqlCommand(strSQL, conn)
            conn.Open()
            RadioButtonList1.DataSource = cmdSQL.ExecuteReader
            RadioButtonList1.DataBind()
        End Using
    End Using
End Sub

Тот же код для выбранного индекса изменился, и мы получили это:

Итак, используйте список переключателей.

И вы можете не только использовать редактор для добавления списка вариантов, но и второй пример показывает, как мы можем даже использовать базу данных для управления вариантами.

Обратите внимание, что у каждого выбора есть отображаемое текстовое значение, а затем скрытое значение выбора, и я полагаю, что также можно использовать индекс выбора.

А в коде позади вы можете свободно использовать код для добавления вариантов, если вы не хотите жестко кодировать разметку, или, как во втором примере, извлекать варианты из базы данных.

Или, может быть, из кода вам нужен выбор от 1 до 5.

Итак, тогда это:

        <asp:RadioButtonList ID = "RadioButtonList1" runat = "server"
            AutoPostBack = "true">
        </asp:RadioButtonList>

И затем произнесите этот код при загрузке:

Protected Sub Page_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load

    If Not IsPostBack Then
        For i = 1 To 5
            Dim OneChoice As New ListItem("Choice " & i, i)
            RadioButtonList1.Items.Add(OneChoice)
        Next
    End If
End Sub

И теперь у нас есть это:

так что вы можете использовать встроенный редактор элементов, вы можете передать данные списка RB или даже просто зациклить и добавить варианты в код.