Рассчитать дни каждого месяца в диапазоне дат в формуле Excel

Используйте функцию DATEDIF().

=DATEDIF(A1,B1,"D")+1

Я не уверен, что именно это вы просите, чтобы получить общую выплаченную сумму:

• Формула, используемая в ячейке B2

=LET(
     _StartDate, TEXTBEFORE(A2," - "),
     _EndDate, TEXTAFTER(A2," - "),
     _FirstDay, EOMONTH(_StartDate,-1)+1,
     _Dates, TEXT(HSTACK(SEQUENCE(_EndDate-_StartDate+1,,_StartDate),
     SEQUENCE(EOMONTH(_EndDate,0)-_FirstDay,,_FirstDay)),"emmm"),
     _Uniq, UNIQUE(TOCOL(_Dates,2)),
     _Output, MAKEARRAY(ROWS(_Uniq),1, LAMBDA(r,c, LET(b, INDEX(_Uniq,r),
    INDEX(SUM(N(b=TOCOL(TAKE(_Dates,,1),2)))*(300/SUM(N(b=TAKE(_Dates,,-1)))),c)))),
     ROUND(SUM(_Output),2))

Используя GROUPBY(), если применимо, тогда:

=LET(
     _StartDate, TEXTBEFORE(A2," - "),
     _EndDate, TEXTAFTER(A2," - "),
     _FirstDay, EOMONTH(_StartDate,-1)+1,
     _Dates, TEXT(SEQUENCE(_EndDate-_StartDate+1,,_StartDate),"emmm"),
     _ActualDates, TEXT(SEQUENCE(EOMONTH(_EndDate,0)-_FirstDay,,_FirstDay),"emmm"),
     ROUND(SUM(DROP(GROUPBY(_Dates,_Dates,ROWS,,0)*
     (300/GROUPBY(_ActualDates,_ActualDates,ROWS,,0)),,1)),2))

Эта формула принимает три части диапазона дат. Начало, конец и промежуточные месяцы. Работает и на старых версиях.

=SUM((EOMONTH(B44,0)-B44+1)*300/(EOMONTH(B44,0)-EOMONTH(B44,-1)),
 IF((YEAR(C44)-YEAR(B44))*12+MONTH(C44)-MONTH(B44)>1,300*((YEAR(C44)-YEAR(B44))*12+MONTH(C44)-MONTH(B44)-1)),
(C44-EOMONTH(C44,-1))*300/(EOMONTH(C44,0)-EOMONTH(C44,-1)))

IF проверяет, есть ли в заданном диапазоне какой-либо полный месяц, и если да, то рассчитывает его значение со ставкой 300 долларов в месяц.

Если у вас есть 365 и каждая дата находится в отдельной ячейке с именем first и last, а сумма за месяц находится в ячейке с именем amt, то:

=LET(
    fullMonths, DATEDIF(
        DATE(YEAR(first), MONTH(first), 1),
        DATE(YEAR(last), MONTH(last) - 1, 1),
        "m"
    ),
    firstFx, (DAY(EOMONTH(first, 0)) - DAY(first) + 1) /
        DAY(EOMONTH(first, 0)),
    lastFx, DAY(last) / DAY(EOMONTH(last, 0)),
    SUM(fullMonths, firstFx, lastFx) * amt
)

Если ваш диапазон дат находится в одной ячейке, вы можете включить функцию TEXTSPLIT для анализа фрагментов.

Если у вас более ранняя версия Excel, вы можете использовать тот же алгоритм с более сложной для понимания формулой:

=(
    DATEDIF(
        DATE(YEAR(first), MONTH(first), 1),
        DATE(YEAR(last), MONTH(last) - 1, 1),
        "m"
    ) +
        (DAY(EOMONTH(first, 0)) - DAY(first) + 1) /
            DAY(EOMONTH(first, 0)) +
        DAY(last) / DAY(EOMONTH(last, 0))
) * 300

Обратите внимание, что вы можете факторизовать свое выражение: сумма является общим коэффициентом, поэтому вам просто нужно умножить 300 на количество полных месяцев, а затем добавить пропорциональные месяцы (февраль и июнь в вашем примере), умноженные на 300.

Зная это, более короткая формула будет такой:

=((DATEDIF(EOMONTH(B1,0)+1,DATE(YEAR(C1),MONTH(C1),1),"m"))*A1)+((((DAY(EOMONTH(B1,0)))-DAY(B1)+1)/(DAY(EOMONTH(B1,0))))*A1)+((DAY(C1)/DAY(EOMONTH(C1,0)))*A1)