Разбор XML с помощью XSLT

С XSLT 3 xsl:iterate вы можете передать ранее обработанный элемент, а затем вывести его с правильными начальным и конечным значениями, также позаботившись о последнем элементе с помощью xsl:on-completion:

<?xml version = "1.0" encoding = "UTF-8"?>
<xsl:stylesheet xmlns:xsl = "http://www.w3.org/1999/XSL/Transform"
    xmlns:xs = "http://www.w3.org/2001/XMLSchema"
    xmlns:map = "http://www.w3.org/2005/xpath-functions/map"
    exclude-result-prefixes = "#all"
    expand-text = "yes"
    version = "3.0">

  <xsl:param name = "default-end" as = "xs:integer" select = "99999"/>

  <xsl:param name = "type-map" as = "map(xs:string, xs:string)"
    select = "map { 'Stage1' : 'NREM1', 'Stage2' : 'NREM2', 'Stage3' : 'NREM3' }"/>

  <xsl:output indent = "yes"/>

  <xsl:template match = "NeuroRKStaging">
      <stages>
          <xsl:iterate select = "Stage[not(@Type = 'Movement')]">
              <xsl:param name = "previous" as = "element()?" select = "()"/>
              <xsl:on-completion>
                  <xsl:if test = "$previous">
                      <epoch>
                      <epoch_start>{$previous/@Start}</epoch_start>
                      <epoch_end>{$default-end}</epoch_end>
                      <xsl:apply-templates select = "$previous/@Type"/>
                  </epoch>
                  </xsl:if>
              </xsl:on-completion>
              <xsl:if test = "$previous">
                  <epoch>
                      <epoch_start>{$previous/@Start}</epoch_start>
                      <epoch_end>{@Start}</epoch_end>
                      <xsl:apply-templates select = "$previous/@Type"/>
                  </epoch>
              </xsl:if>
              <xsl:next-iteration>
                  <xsl:with-param name = "previous" select = "."/>
              </xsl:next-iteration>
          </xsl:iterate>
      </stages>
  </xsl:template>

  <xsl:template match = "Stage/@Type">
      <stage>{.}</stage>
  </xsl:template>

  <xsl:template match = "Stage/@Type[map:contains($type-map, .)]">
      <stage>{$type-map(.)}</stage>
  </xsl:template>

</xsl:stylesheet>

https://xsltfiddle.liberty-development.net/bFN1y8Z/1