Создайте форму без полей без потери команд Windows

Некоторые из команд, на которые вы ссылаетесь, являются системными командами, связанными с изменением размера окна. Для этого нужна толстая рамка, без нее "WIN+право" и "WIN+лево" работать не будут. Кроме того, для работы команд WIN + вверх/вниз вам понадобится окно свертывания и окно максимизации.

Лучше всего начать с нуля и включить нужные стили, иначе VCL может помешать. Если есть возможность воссоздать вашу форму, поместите стиль в переопределение CreateWnd.

procedure TForm1.FormCreate(Sender: TObject);
begin
  BorderStyle := bsNone;
  SetWindowLong(Handle, GWL_STYLE, WS_CLIPCHILDREN or WS_OVERLAPPEDWINDOW);
end;

Тогда есть кадр, который вам не нужен. В редактировании вопроса вы раздуваете прямоугольник клиента, чтобы избавиться от него. Не угадывайте ширину/высоту кадра, сделайте это, как показано ниже.

procedure TForm1.WMNCCalcSize(var Message: TWMNCCalcSize);
var
  R: TRect;
begin
  if not Message.CalcValidRects then
    R := PRect(Message.CalcSize_Params)^;
  inherited;
  if Message.CalcValidRects then
    Message.CalcSize_Params.rgrc0 := Message.CalcSize_Params.rgrc1
  else
    PRect(Message.CalcSize_Params)^ := R;
  Message.Result := 0;
end;

На этом этапе чтение документация для сообщения является обязательным, параметры имеют разные значения на разных этапах и т. д.

Вышеприведенное оставляет окно без какой-либо неклиентской области. Прямоугольник клиента равен прямоугольнику окна. Хотя заголовок не виден, вы можете активировать системное меню, нажав Alt+Пробел. Проблема в том, что система настаивает на отображении состояния активации. Теперь он рисует рамку в клиентской области!!

Избавьтесь от него, перехватив WM_NCACTIVATE, он же нужен для отрисовки вашего заголовка по статусу активации:

procedure TForm1.WMNCActivate(var Message: TWMNCActivate);
begin
  if Message.Active then
    // draw active caption
  else
    // draw incactive caption

  // don't call inherited
end;

Возможно, вам придется иметь дело с некоторыми глюками, испорченное окно имеет последствия. Например, в моем тесте свернутая форма не имеет связанного значка в диалоговом окне alt + tab.

Ниже мой тестовый образец полностью.

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants,
  System.Classes, Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  protected
    procedure WMNCActivate(var Message: TWMNCActivate); message WM_NCACTIVATE;
    procedure WMNCCalcSize(var Message: TWMNCCalcSize); message WM_NCCALCSIZE;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
  BorderStyle := bsNone;
  SetWindowLong(Handle, GWL_STYLE, WS_CLIPCHILDREN or WS_OVERLAPPEDWINDOW);
end;

procedure TForm1.WMNCActivate(var Message: TWMNCActivate);
begin
  if Message.Active then
    // draw active caption
  else
    // draw incactive caption

  // don't call inherited
end;

procedure TForm1.WMNCCalcSize(var Message: TWMNCCalcSize);
var
  R: TRect;
begin
  if not Message.CalcValidRects then
    R := PRect(Message.CalcSize_Params)^;
  inherited;
  if Message.CalcValidRects then
    Message.CalcSize_Params.rgrc0 := Message.CalcSize_Params.rgrc1
  else
    PRect(Message.CalcSize_Params)^ := R;
  Message.Result := 0;
end;

end.