Создание и управление коллекциями элементов управления времени выполнения по запросу

Итак, я думаю, это то, что вам нужно. Обратите внимание, что это не самый чистый код, но он выполняет отдельные части рисования в пользовательской форме.

Во-первых, я сохранил OriginX и OriginY в самой пользовательской форме - в конце концов, он должен контролировать, где должно начинаться рисование. Код пользовательской формы:

Public OriginX As Integer
Public OriginY As Integer
Private Sub UserForm_Initialize()
    OriginX = 20
    OriginY = 20
End Sub

Затем я создал класс BigBox для красного прямоугольника, который у вас был. У него есть высота, ширина, и при инициализации он добавит метку в пользовательскую форму. (Обратите внимание, что размещение метки в форме таким образом - плохая практика - класс не должен знать, где его нарисовать. Однако - для ответа на ваш вопрос это не актуально сразу.)

Класс BigBox:

Private p_width As Integer
Private p_height As Integer
Private p_label As MSForms.Label
Public Property Let Width(value As Integer)
    p_width = value
    p_label.Width = p_width
End Property
Public Property Get Width() As Integer
    Width = p_width
End Property
Public Property Let Height(value As Integer)
    p_height = value
    p_label.Height = p_height
End Property
Public Property Get Height() As Integer
    Height = p_height
End Property
Public Property Get Label() As MSForms.Label
    Set Label = p_label
End Property
Private Sub Class_Initialize() 'This bit is bad practice, but it works:
    Set p_label = frmPlanning.Controls.Add("Forms.Label.1", "BigBox", True)
    p_label.Left = frmPlanning.OriginX
    p_label.Top = frmPlanning.OriginY
    p_label.BorderColor = Red
    p_label.BorderStyle = 1
End Sub

Затем я создал класс «Cut», который можно использовать в коллекции с разрезами, поэтому, когда вам нужно перерисовать, вы сохраните их / они не будут забыты:

Класс резки:

Private p_width As Integer
Private p_height As Integer
Public Property Let Width(value As Integer)
    p_width = value
End Property
Public Property Get Width() As Integer
    Width = p_width
End Property
Public Property Let Height(value As Integer)
    p_height = value
End Property
Public Property Get Height() As Integer
    Height = p_height
End Property

Затем я изолировал коллекции «Cuts» и «Labels», так как метки нужно удалить и перерисовать, когда вы добавите второй пакет. Следующая процедура

• Убедитесь, что коллекция Cuts и коллекции этикеток существуют.
• Показывает форму (без режима, поэтому выполнение кода продолжается)
• Создает BigBox и устанавливает высоту и ширину. Отсюда все разрезы будут иметь высоту.
• Добавляет пару раз сокращений.
• Имеет ли подпрограмма "добавить вырез" также для выполнения подпрограммы рисования.

Код модуля1:

Option Explicit
Public bb As BigBox
Public cuts As Collection
Public cutLabels As Collection
Public totalCutsWidth As Integer
Public piece As Cut
Sub test2()
    If cuts Is Nothing Then
        Set cuts = New Collection
    End If
    If cutLabels Is Nothing Then
        Set cutLabels = New Collection
    End If

    frmPlanning.Show vbModeless

    Set bb = New BigBox
    bb.Height = 100
    bb.Width = 500
    AddCuts 5, 20
    AddCuts 10, 10
    AddCuts 7, 50
End Sub

Sub AddCuts(numberOfCuts As Integer, widthOfCuts As Integer)
Dim i As Integer
If numberOfCuts <= 0 Then Exit Sub
For i = 1 To numberOfCuts
    Set piece = New Cut
    piece.Width = widthOfCuts
    piece.Height = bb.Height
    totalCutsWidth = totalCutsWidth + widthOfCuts
    If totalCutsWidth <= bb.Width Then
        cuts.Add piece
    End If
Next i
DrawCuts
End Sub
Sub DrawCuts()
Dim i As Integer
Dim OffsetX As Integer
Dim newLabel As MSForms.Label

OffsetX = 0

For i = cutLabels.Count To 1 Step -1
    frmPlanning.Controls.Remove "Corte" & i
    cutLabels.Remove i
Next i

i = 0
OffsetX = frmPlanning.OriginX
For Each piece In cuts
    i = i + 1
    Set newLabel = frmPlanning.Controls.Add("Forms.Label.1", "Corte" & i, True)
    With newLabel
        .ControlTipText = .Name
        .Left = OffsetX
        .Width = piece.Width
        .Height = piece.Height
        .Top = frmPlanning.OriginY
        .BackColor = &HFFFFFF
        .BorderStyle = 1
        .TextAlign = 2
        .Font.Size = 6
        .Caption = i
        OffsetX = OffsetX + piece.Width
    End With
    cutLabels.Add newLabel
Next piece
End Sub

Обратите внимание, что добавление разрезов гарантирует, что разрезы по-прежнему помещаются в большую рамку, и что рисунок разрезов отделен от него. Кроме того, если следующий кусок больше не помещается в коробке, он не будет добавлен. Т.е. если большая коробка имеет ширину 500, и вы добавляете 10 разрезов шириной 25, а затем 11 разрезов шириной 30, он добавит только первые 8 из второй партии (10 * 25 = 250, 8 * 30 = 240, 240 + 250 = 490, поэтому 9-й, 10-й и 11-й не помещаются в общую ширину 500, поэтому не будут добавлены.

Надеюсь, это поможет и достаточной информации для включения в существующее решение.