В моем интерфейсе Az Cli для развертывания бицепса в области управления не отображаются изменения во вложенной группе управления

Обновлять

По вашему последующему запросу

Попробовал ответить, жестко закодировав subID в бицепсе, и это сработало; теперь вопрос в том, как передать значение вывода модуля подписки в B.bicep в качестве значения параметра?

Если вы предпочитаете инструмент Azure CLI, то после того, как вам удастся создать новую подписку с помощью модуля подписки, вы можете использовать команду az deployment mg show, чтобы получить действительные выходные данные subscriptionId из 1stARMDeployment-CreateNewSub, а затем передать их в B.bicep в качестве значения параметра для 2ndARMDeployment-CreateResourcesFromB.

Добавьте output subscriptionId string = subAlias.outputs.subscriptionId в A.bicep;

targetScope = 'managementGroup'

module subAlias './modules/subscription.bicep' = {
  name: 'create-${subscriptionAlias}'
  params: {
    billingAccount: billingAccount
    subscriptionAlias: subscriptionAlias
    subscriptionDisplayName: subscriptionDisplayName
    subscriptionWorkload: environmentconfigurationMap[environment].subscriptionWorkload
  }
}

output subscriptionId string = subAlias.outputs.subscriptionId

PowerShell

$newSubID = $(az deployment mg show --name '1stARMDeployment-CreateNewSub' --management-group-id 'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx' --query properties.outputs.subscriptionId.value)

az deployment mg what-if --name '2ndARMDeployment-CreateResourcesFromB' --management-group-id 'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx' --location "southeast asia" --template-file 'B.bicep' --parameters subID=$newSubID

Судя по вашему описанию, мне удалось воспроизвести проблему через локальную PowerShell с помощью приведенных ниже примеров шаблонов бицепсов.

А.бицепс

param subscriptionDisplayName string = 'Azure Subscription ARM1'
param subscriptionAlias string = 'subARM1'
param billingAccount string = '/providers/Microsoft.Billing/billingAccounts/123456/enrollmentAccounts/654321'
param environment string = 'Prod'
param environmentconfigurationMap object= {
  Prod: {
    subscriptionWorkload: 'Production'
  }
}

targetScope = 'managementGroup'

module subAlias './modules/subscription.bicep' = {
  name: 'create-${subscriptionAlias}'
  params: {
    billingAccount: billingAccount
    subscriptionAlias: subscriptionAlias
    subscriptionDisplayName: subscriptionDisplayName
    subscriptionWorkload: environmentconfigurationMap[environment].subscriptionWorkload
  }
}

module createResourceGroupStorage 'B.bicep' = {
  name: 'nested-createResources-${subscriptionDisplayName}'
  params:{
      subID : subAlias.outputs.subscriptionId // Require a valid subID
    }
}

/modules/subscription.bicep

targetScope = 'managementGroup'

@description('BillingAccount used for subscription billing')
param billingAccount string

@description('Alias to assign to the subscription')
param subscriptionAlias string

@description('Display name for the subscription')
param subscriptionDisplayName string

@description('Workload type for the subscription')
param subscriptionWorkload string

resource alias 'Microsoft.Subscription/aliases@2020-09-01' = {
  scope: tenant()
  name: subscriptionAlias
  properties: {
    workload: subscriptionWorkload
    displayName: subscriptionDisplayName
    billingScope: billingAccount
  }
}

output subscriptionId string = alias.properties.subscriptionId

Б.бицепс

targetScope = 'managementGroup'

@description('subscriptionId for the deployment')
param subID string

@description('Name of the resourceGroup, will be created in the same location as the deployment.')
param resourceGroupName string = 'rg-armdemo'

@description('Location for the deployments and the resources')
param location string = deployment().location

// deploy to the subscription and create the resourceGroup
module rg './modules/resourcegroup.bicep' = {
  scope: subscription(subID)
  name: 'create-${resourceGroupName}'
  params: {
    resourceGroupName: resourceGroupName
    location: location
  }
}

/modules/resourcegroup.bicep

targetScope = 'subscription'

@description('Name of the resourceGroup.')
param resourceGroupName string

param location string = deployment().location

resource rg 'Microsoft.Resources/resourceGroups@2021-04-01' = {
  name: resourceGroupName
  location: location
}

Если напрямую использовать строку subID вместо выходных данных восходящего модуля, команда what-if сможет просмотреть ресурсы, которые будут развернуты в B.bicep. Такое поведение является задуманным, поскольку команда what-if может только просматривать изменения в развертывании, а не вносить какие-либо изменения в существующие ресурсы. Кроме того, ресурс для развертывания в B.bicep требует использования действующего subID, а команда what-if не выводит такое значение.

Что касается проблемы Scope, она должна соответствовать области развертывания каждого развертываемого ресурса. Например, если использовать приведенный ниже шаблон C.bicep для создания новой группы управления, его область действия была такой же, как у новой подписки в A.bicep, но отличалась от области действия новой группы ресурсов в B.bicep.