VBA Удаление строк с помощью оператора Like

Во-первых, домашнее хозяйство ...

1. Добавить Option Explicit
2. Добавить Option Explicit
3. Оцените все объекты (Range) с помощью рабочего листа

Вам следует избегать удаления строк во время цикла по нескольким причинам. Основная причина в том, что это может быть очень неэффективно. Скажем, например, что у вас есть 500 клеток с Like "2L*". Это означает, что у вас будет 500 итераций удаляемых строк.

Вместо, добавьте каждый экземпляр Like "2L*" в Union (коллекцию) ячеек и после завершения цикла удалите все Union сразу. Теперь у вас есть только 1 экземпляр удаляемых строк.

Еще одна причина избегать удаления строк внутри цикла заключается в том, что он заставляет вас выполнять цикл в обратном направлении. В этом нет ничего плохого, это просто доставляет людям неудобства, поскольку поначалу это не интуитивно понятно. Когда вы удаляете строку, вы перемещаете диапазон, который вы просматриваете в цикле, и это приводит к пропуску строк. Приведенный ниже метод не требует повторения цикла в обратном направлении.

Option Explicit

Sub Cleanup()

Dim ws As Worksheet: Set ws = ThisWorkbook.Sheets("???")
Dim i As Long, DeleteMe As Range

'Gather up union of CELLS like 2L*
For i = 1 To ws.Range("F" & ws.Rows.Count).End(xlUp).Row
    If ws.Range("F" & i) Like "2L*" Then
        If DeleteMe Is Nothing Then
            Set DeleteMe = ws.Range("F" & i)
        Else
            Set DeleteMe = Union(DeleteMe, ws.Range("F" & i))
        End If
    End If
Next i

'Delete collection of cells here (if any exist)
If Not DeleteMe Is Nothing Then DeleteMe.EntireRow.Delete

End Sub

В целях обучения вы можете выполнить цикл в обратном направлении. У него меньше строк, чем у вышеупомянутого метода, но он менее эффективен. Если вы все же решите пойти по этому пути, не забудьте выключить ScreenUpdating, чтобы ускорить процесс.

Sub CleanUp2()

Dim ws As Worksheet: Set ws = ThisWorkbook.Sheets("???")
Dim i As Long

For i = ws.Range("F" & ws.Rows.Count).End(xlUp).Row to 1 Step -1 '<===== Backwards!
    If ws.Range("F" & i) Like "2L*" Then ws.Rows(i).Delete
Next i

End Sub

Я здесь одолжить у Jeeped и предлагаю ответ, который не требует цикла:

Sub DeleteBlankRows()

    With Worksheets(1)
        On Error Resume Next
        Intersect(.Range("F:F"), .UsedRange).SpecialCells(xlCellTypeBlanks).EntireRow.Delete
        On Error GoTo 0
    End With

End Sub

Или воспользуйтесь автофильтром

Option Explicit
Public Sub CleanUp()
    Dim lastRow As Long, testRange As Range
    With ThisWorkbook.Worksheets("Sheet2")
        lastRow = .Cells(.Rows.Count, "F").End(xlUp).Row
        Set testRange = .Range("F1:F" & lastRow)
        If Application.WorksheetFunction.CountIf(testRange, "2L*") > 0 Then
            With testRange
                .AutoFilter
                .AutoFilter Field:=1, Criteria1: = "2L*", Operator:=xlFilterValues
                .SpecialCells(xlCellTypeVisible).EntireRow.Delete
            End With
        End If
    End With
End Sub