Есть ли в доступе MS (2003) что-либо, сопоставимое с хранимой процедурой. Я хочу выполнить сложный запрос в доступе к MS

Я не знаю способа запуска хранимых процедур в базе данных Access. Однако Access может выполнять хранимые процедуры, если он используется с серверной частью SQL. Если вы не можете разделить пользовательский интерфейс на Access и данные на SQL, то, вероятно, лучше всего будет закодировать модуль VBA, чтобы получить нужный результат.

Что ж, вы можете использовать объект Recordset для циклического выполнения вашего запроса в VBA, объединяя значения полей на основе любых критериев, которые вам нужны.

Если вы хотите вернуть результаты в виде строк, все будет в порядке. Если вы хотите вернуть их в виде запроса, это будет сложнее. Возможно, вам придется создать временную таблицу и сохранить в ней результаты, чтобы вы могли вернуть их в виде таблицы или запроса.

Ни хранимых процедур, ни временных таблиц.

Если вам нужно вернуть запрос в виде набора записей, вы можете использовать отключенный набор записей.

Я считаю, что вы можете создавать функции VBA и использовать их в своих запросах доступа. Это может вам помочь.

Для выполнения вашей задачи вам нужно будет использовать код. Одно из решений, использующее более значимые имена, заключается в следующем:

Основная таблица с двумя применимыми столбцами:

Table Name: Widgets

Field 1: ID (Long)

Field 2: Color (Text 32)

Добавьте таблицу с двумя столбцами:

Table Name: ColorListByWidget

Field 1: ID (Long)

Field 2: ColorList (Text 255)

Добавьте следующий код в модуль и вызовите по мере необходимости для обновления таблицы ColorListByWidget:

Public Sub GenerateColorList()

Dim cn As New ADODB.Connection
Dim Widgets As New ADODB.Recordset
Dim ColorListByWidget As New ADODB.Recordset
Dim ColorList As String

Set cn = CurrentProject.Connection

cn.Execute "DELETE * FROM ColorListByWidget"
cn.Execute "INSERT INTO ColorListByWidget (ID) SELECT ID FROM Widgets GROUP BY ID"

With ColorListByWidget
   .Open "ColorListByWidget", cn, adOpenForwardOnly, adLockOptimistic, adCmdTable
   If Not (.BOF And .EOF) Then
      .MoveFirst
      Do Until .EOF
         Widgets.Open "SELECT Color FROM Widgets WHERE ID = " & .Fields("ID"), cn
         If Not (.BOF And .EOF) Then
            Widgets.MoveFirst
            ColorList = ""
            Do Until Widgets.EOF
               ColorList = ColorList & Widgets.Fields("Color").Value & ", "
               Widgets.MoveNext
            Loop
         End If
         .Fields("ColorList") = Left$(ColorList, Len(ColorList) - 2)
         .MoveNext
         Widgets.Close
      Loop
   End If
End With


End Sub

Таблица ColorListByWidget теперь содержит желаемую информацию. Будьте осторожны, чтобы список (цвета в этом примере) не превышал 255 символов.

Вы можете объединить записи с помощью пользовательской функции (UDF).

Приведенный ниже код можно вставить "как есть" в стандартный модуль. Пример SQL для вас:

SELECT tbl.A, Concatenate("SELECT B  FROM tbl
        WHERE A = " & [A]) AS ConcA
FROM tbl
GROUP BY tbl.A

Этот код принадлежит DHookom, Access MVP и взят из http://www.tek-tips.com/faqs.cfm?fid=4233

Function Concatenate(pstrSQL As String, _
        Optional pstrDelim As String = ", ") _
            As String
    'example
    'tblFamily with FamID as numeric primary key
    'tblFamMem with FamID, FirstName, DOB,...
    'return a comma separated list of FirstNames
    'for a FamID
    '    John, Mary, Susan
    'in a Query
    '(This SQL statement assumes FamID is numeric)
    '===================================
    'SELECT FamID,
    'Concatenate("SELECT FirstName FROM tblFamMem
    '     WHERE FamID  = " & [FamID]) as FirstNames
    'FROM tblFamily
    '===================================
    '
    'If the FamID is a string then the SQL would be
    '===================================
    'SELECT FamID,
    'Concatenate("SELECT FirstName FROM tblFamMem
    '     WHERE FamID  = """ & [FamID] & """") as FirstNames
    'FROM tblFamily
    '===================================

    '======For DAO uncomment next 4 lines=======
    '======     comment out ADO below    =======
    'Dim db As DAO.Database
    'Dim rs As DAO.Recordset
    'Set db = CurrentDb
    'Set rs = db.OpenRecordset(pstrSQL)

    '======For ADO uncomment next two lines=====
    '======     comment out DAO above     ======
    Dim rs As New ADODB.Recordset
    rs.Open pstrSQL, CurrentProject.Connection, _
            adOpenKeyset, adLockOptimistic
    Dim strConcat As String 'build return string
    With rs
        If Not .EOF Then
            .MoveFirst
            Do While Not .EOF
                strConcat = strConcat & _
                    .Fields(0) & pstrDelim
                .MoveNext
            Loop
        End If
        .Close
    End With
    Set rs = Nothing
    '====== uncomment next line for DAO ========
    'Set db = Nothing
    If Len(strConcat) > 0 Then
        strConcat = Left(strConcat, _
            Len(strConcat) - Len(pstrDelim))
    End If
    Concatenate = strConcat
End Function 

Вы можете использовать GetString в VBA, который вернет набор записей, разделенный любым значением, которое вам нравится (например, запятой, тире, ячейками таблицы и т. д.), Хотя я должен признать, что использовал его только в VBScript, а не в Visual Basic. У W3Schools есть хороший учебник, который, надеюсь, удовлетворит ваши потребности..

Вы можете написать свою хранимую процедуру в виде текста и отправить ее в базу данных с помощью:

Dim sp as string
sp = "your stored procedure here" (you can load it from a text file or a memo field?)

Access.CurrentProject.AccessConnection.Execute sp

Предполагается, что вы используете объекты ADODB (библиотека объектов данных ActiveX правильно упоминается в вашем приложении).

Я уверен, что с DAO есть что-то подобное ...

Возможно, вместо того, чтобы спрашивать, есть ли у Jet хранимые процедуры, вы должны объяснить, чего вы хотите достичь, а затем мы сможем объяснить, как это сделать с помощью Jet (неясно, используете ли вы Access для своего приложения или просто используете Jet MDB как ваше хранилище данных).

@Remou о функции Concatenate DHookom: ни в стандарте SQL, ни в Jet нет функции установки CONCATENATE(). Проще говоря, это потому, что это нарушение 1НФ. Я бы предпочел сделать это на стороне приложения, а не пытаться заставить SQL делать то, для чего он не предназначен. Возможно, многозначные типы ACE (Access2007) подходят лучше: все еще NFNF, но, по крайней мере, есть поддержка на уровне движка. Помните, вопрос относится к объекту хранится: как пользователь может запросить нескалярный столбец с помощью SQL ...?

@ Дэвид В. Фентон о том, есть ли в Jet хранимые процедуры: разве мы с вами не обсуждали это в группах новостей пару лет назад. Начиная с версии 4.0 Jet / ACE поддерживает следующий синтаксис в режиме запроса ANSI-92:

CREATE PROCEDURE procedure (param1 datatype[, param2 datatype][, ...]) AS sqlstatement;

EXECUTE procedure [param1[, param2[, ...]];

Итак, Jet создает и выполняет то, что он знает (по крайней мере, в одном режиме) как «процедуру», которая «хранится» в файле MDB. Однако Jet / ACE SQL прост и понятен: он не имеет синтаксиса управления потоком, а PROCEDURE может содержать только один оператор SQL, поэтому о любом коде процессуальный не может быть и речи. Таким образом, ответ на вопрос, есть ли в Jet хранимые процедуры, является субъективным.