Захват события клавиатуры Cmd-C (или Ctrl-C) из модульного приложения Flex в браузере или AIR

Я провел тест, в котором я прослушивал события нажатия клавиш на сцене и заметил, что (на моем Mac) я мог легко захватить control-c, control-v и т. д., Но ничего, связанного с командой (клавиша ), не было захватывались, пока я не отпустил командную клавишу, а затем ctrlKey был ложным (хотя в документации сказано, что ctrlKey должен быть истинным для командной клавиши на Mac), а charCode был равен 0. Короче говоря, довольно бесполезно.

Еще одна невероятно неприятная вещь, которую я только что понял, это то, что ctrl-c не может быть захвачен event.ctrlKey && event.keyCode = Keyboard.C (или ... event.charCode == 67), вместо этого вам нужно проверить, является ли charCode или keyCode3. Это имеет смысл для charCode, поскольку ctrl-c - это 3 в таблице ASCII, но не имеет смысла для keyCode, который должен представлять клавишу на клавиатуре, а не вводимый символ. То же самое и со всеми другими комбинациями клавиш (потому что каждая комбинация ctrl имеет эквивалент ASCII).

Редактировать Нашел ошибку в системе ошибок Flex по этому поводу: https://bugs.adobe.com/jira/browse/FP-375

Для меня работает следующее:

    private var _ctrlHoldFlag:Boolean = false; 

    // Do something if CTRL was held down and C was pressed
    // Otherwise release the ctrl flag if it was pressed
    public function onKey_Up(event:KeyboardEvent):void {  
        var keycode_c:uint = 67;

        if (_ctrlHoldFlag && event.keyCode == keycode_c)
        {
            //do whatever you need on CTRL-C
        }

        if (event.ctrlKey)
        {
            _ctrlHoldFlag = false;
        }
    }

    // Track ctrl key down press 
    public function onKey_Down(event:KeyboardEvent):void
    {
        if (event.ctrlKey)
        {
            _ctrlHoldFlag = true;
        }
    }

Я нашел способ обхода этого, основанный на последовательности захвата. Например, когда вы нажимаете Cmd + A, последовательность действий следующая:

• тип: KEY_DOWN, keyCode 15
• тип: KEY_UP, keyCode 15
• тип: KEY_DOWN, keyCode 65

Таким образом, каждый раз, когда вы получаете keyCode 15 вниз, а затем вверх, а следующий захват не выполняется, вы можете предположить, что пользователь нажал комбинацию клавиш. Моя реализация выглядит так:

    protected var lastKeys:Array;
    this.stage.addEventListener(KeyboardEvent.KEY_DOWN, keyHandler, false, 0, true);
    this.stage.addEventListener(KeyboardEvent.KEY_UP, keyHandler, false, 0, true);

    private function getCmdKey(ev:KeyboardEvent):Boolean {
        this.lastKeys.push(ev);
        this.lastKeys = this.lastKeys.splice(Math.max(0, this.lastKeys.length-3), 3);

        if (this.lastKeys.length < 3) return false;

        if (ev.keyCode != 15 && ev.type == KeyboardEvent.KEY_UP) {
            var firstKey:KeyboardEvent = this.lastKeys[0] as KeyboardEvent;
            var secondKey:KeyboardEvent = this.lastKeys[1] as KeyboardEvent;

            if (firstKey.keyCode == 15 && firstKey.type == KeyboardEvent.KEY_DOWN &&
                secondKey.keyCode == 15 && secondKey.type == KeyboardEvent.KEY_UP) {
                    return true;
            }
        }

        return false;
    }

    private function keyHandler(ev:KeyboardEvent):void {
        var cmdKey:Boolean = this.getCmdKey(ev.clone() as KeyboardEvent);
        var ctrlKey:Boolean = ev.ctrlKey || cmdKey;

        if (ctrlKey) {
            if (ev.keyCode == 65) { 
                // ctrl + "a"-- select all!
            }
        }
    }