Delphi, как сериализовать и десериализовать TObject

Проверка возвращаемого значения только TypeInfo(T) не поможет вам в этой ситуации, так как вам придется проверять определенные типы. Вместо этого вы можете использовать GetTypeKind(T) (XE7+), проверяя типы tkInteger, tkInterface и tkClass и соответствующим образом обрабатывать их данные.

Например:

procedure TListHelper<T>.Serialize(const Buffer: IBuffer; const List: IList<T>);
var
  Count, i: Integer;
  LIntf: ILObject;
  LObject: TObject;
begin
  Count := List.Count;
  Buffer.WriteInteger(Count);

  for i := 0 to Count - 1 do
  begin
    case GetTypeKind(T) of 
      tkInteger: begin
        Buffer.WriteInteger(TValue.From<T>(List[I]).AsType<Integer>);
      end;
      tkInterface: begin
        if Supports(TValue.From<T>(List[I]).AsInterface, ILObject, LIntf) then
          LIntf.Serialize(Buffer)
        else
          raise Exception.Create('Unsupported interface type for List serialization');
      end;
      tkClass: begin
        LObject := TValue.From<T>(List[I]).AsObject;
        if LObject.InheritsFrom(TILObject) then
          TILObject(LObject).Serialize(Buffer)
        else
          raise Exception.Create('Unsupported object type for List serialization');
      end;
    else
      raise Exception.Create('Unsupported type for List serialization');
    end;
  end;
end;

function TListHelper<T>.Deserialize(const Buffer: IBuffer): IList<T>;
var
  Count, i: Integer;
  Item: TValue;
  LIntf: ILObjct;
  LObject: TILObject;
begin
  Result := TList<T>.Create;
  Count := Buffer.ReadInt32;

  for i := 0 to Count - 1 do
  begin
    case GetTypeKind(T) of
      tkInteger: begin
        Item := TValue.From<T>(Buffer.ReadInteger);
      end;
      tkInterface: begin
        LIntf := ???.Create as ILObject;
        LIntf.Deserialize(Buffer);
        Item := TValue.From<T>(LIntf);
      end;
      tkClass: begin
        LObject := ???.Create as TILObject;
        LObject.Deserialize(Buffer);
        Item := TValue.From<T>(LObject);
      end;
    else
      raise Exception.Create('Unsupported type for List deserialization');
    end;

    Result.Add(Item.AsType<T>);
  end;
end;

Однако, как вы можете видеть выше, с TListHelper.Deserialize() есть проблема. Сначала вам необходимо создать экземпляр объекта, чтобы вызвать на нем (T)ILObject.Deserialize(), поэтому вам нужно знать, какой тип класса создавать. Но вы не можете вызвать T.Create, поскольку T не имеет ограничения class. Таким образом, вам придется записать имя класса в свой Buffer, прочитать его обратно и использовать отдельную фабрику для создания и возврата нового экземпляра (T)ILObject для указанного имени класса, например:

procedure TListHelper<T>.Serialize(const Buffer: IBuffer; const List: IList<T>);
var
  Count, i: Integer;
  LIntf: ILObject;
  LObject: TObject;
begin
  Count := List.Count;
  Buffer.WriteInteger(Count);

  for i := 0 to Count - 1 do
  begin
    case GetTypeKind(T) of 
      tkInteger: begin
        Buffer.WriteInteger(TValue.From<T>(List[I]).AsType<Integer>);
      end;
      tkInterface: begin
        if Supports(TValue.From<T>(List[I]).AsInterface, ILObject, LIntf) then
        begin
          Buffer.WriteString((LIntf as TObject).ClassName);
          LIntf.Serialize(Buffer);
        end else
          raise Exception.Create('Unsupported interface type for List serialization');
      end;
      tkClass: begin
        LObject := TValue.From<T>(List[I]).AsObject;
        if LObject.InheritsFrom(TILObject) then
        begin
          Buffer.WriteString(LObject.ClassName);
          TILObject(LObject).Serialize(Buffer)
        end else
          raise Exception.Create('Unsupported object type for List serialization');
      end;
    else
      raise Exception.Create('Unsupported type for List serialization');
    end;
  end;
end;

function TListHelper<T>.Deserialize(const Buffer: IBuffer): IList<T>;
var
  Count, i: Integer;
  Item: TValue;
  LClassName: string;
  LIntf: ILObjct;
  LObject: TILObject;
begin
  Result := TList<T>.Create;
  Count := Buffer.ReadInt32;

  for i := 0 to Count - 1 do
  begin
    case GetTypeKind(T) of
      tkInteger: begin
        Item := TValue.From<T>(Buffer.ReadInteger);
      end;
      tkInterface: begin
        LClassName := Buffer.ReadString;
        LIntf := CreateILObject(LClassName) as ILObject; // <--
        LIntf.Deserialize(Buffer);
        Item := TValue.From<T>(LIntf);
      end;
      tkClass: begin
        LClassName := Buffer.ReadString;
        LObject := CreateILObject(LClassName); // <--
        LObject.Deserialize(Buffer);
        Item := TValue.From<T>(LObject);
      end;
    else
      raise Exception.Create('Unsupported type for List deserialization');
    end;

    Result.Add(Item.AsType<T>);
  end;
end;

Вам придется реализовать CreateILObject() самостоятельно, например:

function CreateILObject(AClassName: string): TILObject;
begin
  if AClassName = 'TChild' then
    Result := TChild.Create
  ...
  else
    Result := nil; // or raise
end;

Есть способы обобщить такую ​​фабрику, но это выходит за рамки данного вопроса. На StackOverflow (и других форумах) есть много других вопросов, связанных с (де)сериализацией объектов.