Фиджи Макрос для пакетной обработки изображений .nd2

Синтаксис этой строки:

run("Z Project...", start=1 stop=totalSlices, " projection=[Max Intensity]");

неверно.

Если вы это сделаете:

run("Z Project...", "projection=[Max Intensity]");

он должен работать нормально. По умолчанию начинается с 1 и заканчивается на последнем срезе, поэтому это будет работать.

Чтобы исправить исходную строку (и понять, почему она не работает), вам нужно будет сделать:

run("Z Project...", "start=1 stop = " + totalSlices + " projection=[Max Intensity]");

Вам нужно создать строку в качестве аргумента, чего не было в исходном коде. Однако существует дополнительная проблема: переменная totalSlices определяется как getSliceNumber(), которая представляет собой номер текущего среза (1), а не общее количество срезов. Вот почему код не работает.

Правильный код должен быть:

// Function to process each .nd2 file
function processFile(filePath) {
    // Open the .nd2 file
    setBatchMode(true);
    open(filePath);
    // Get the title of the opened image
    title = getTitle();
    
    // Stack different focal planes into one high projection image per channel
    run("Split Channels");
    channelTitles = getList("image.titles");

    // Process each channel
    for (c = 0; c < channelTitles.length; c++) {
        selectWindow(channelTitles[c]);
        // Use all slices for Z Projection
        run("Z Project...", "projection=[Max Intensity]");
        projTitle = getTitle();
        close(channelTitles[c]);
        selectWindow(projTitle);
        // Adjust brightness and contrast automatically
        run("Enhance Contrast", "saturated=0.35");
        run("Apply LUT", "stack");
        
        // Convert to RGB
        run("RGB Color");
        
        // Save the processed channel
        saveAs("Tiff", filePath + "_channel" + (c + 1) + ".tif");
        close();
    }
    
    // Close the original image
    close(title);
}

Кроме того, импортер биоформатов должен быть настроен так, чтобы открытие каждого файла .nd2 не запускало диалоговое окно импорта.

Ниже вы найдете демонстрационный макрос ImageJ, в котором используется файл «.nd2», который я нашел здесь. Пожалуйста, загрузите этот raw-файл и попробуйте макрос с этим файлом! В файле показаны два цветовых канала с четырьмя изображениями (здесь: моменты времени).

//imagej-macro "nd2-processing" (Herbie G., 09. Aug. 2024)
requires("1.54j");
path=File.openDialog("Open the sample nd2-file");
run("Bio-Formats","open=[path] color_mode=Default rois_import=[ROI manager] split_channels view=Hyperstack stack_order=XYCZT use_virtual_stack series_1");
path=File.getDirectory(path)+File.nameWithoutExtension;
clr=newArray("Blue","Green","Red");
n=nImages;
for (i=0;i<n;i++) {
   run("Z Project...","projection=[Max Intensity]");
   run("Enhance Contrast...","saturated=0.35");
   run(clr[i]);
   saveAs("PNG",path+"_ch-"+(n-i)+".png");
   close(); close();
}
exit();
//imagej-macro "nd2-processing" (Herbie G., 09. Aug. 2024)

Обратите внимание, что при назначении LUT проекционным изображениям они сохраняются с глубиной 8 бит. Сохраните в формате TIF, чтобы сохранить глубину 16 бит. ===========================================

Наконец, ниже вы найдете код для пакетной обработки всех файлов «.nd2» в папке:

//imagej-macro "batch_nd2-processing" (Herbie G., 09. Aug. 2024)
requires("1.54j");
close("*");
inSfx=0;   // preferred source file suffix
outSfx=2; // preferred result file suffix
Dialog.create("Batch Process Folder");
   suffix=newArray(".nd2",".bmp",".png",".tif");
   Dialog.setInsets(0,200,0);
   Dialog.addMessage("Macro does not process nested folders!",12,"blue");
   Dialog.setInsets(6,0,0);
   Dialog.addChoice("Suffix",suffix,suffix[inSfx]);   
   Dialog.setInsets(-28,182,0);
   Dialog.addMessage("of the source files");   
   Dialog.addDirectory("Source-Folder",getDir("file"));
   Dialog.addChoice("Suffix",suffix,suffix[outSfx]);   
   Dialog.setInsets(-37,182,0);
   Dialog.addMessage("for the result files");  
   Dialog.addDirectory("Result-Folder",getDir("file"));
Dialog.show();
sfx1=Dialog.getChoice();
srce=Dialog.getString();
sfx2=Dialog.getChoice();
dest=Dialog.getString();
setBatchMode(true);
count=processFolder(sfx1,srce,sfx2,dest);
setBatchMode(false);
exit(""+count+" files processed");
//
function processFolder(xtn1,dir1,xtn2,dir2) {
   color=newArray("Blue","Green","Red");
   cnt=0;
   list=getFileList(dir1);
   n=list.length;
   for (i=0;i<n;i++)
      if (endsWith(list[i],xtn1)) {
         cnt++;
         path=dir1+list[i];
         run("Bio-Formats","open=[path] color_mode=Default split_channels view=Hyperstack stack_order=XYCZT use_virtual_stack series_1");
         path=dir2+File.nameWithoutExtension;
         processInput(path,xtn2,color);
      }
   return cnt;
}
function processInput(pth,xtn,clr) {
   n=nImages;
   for (i=0;i<n;i++) {
      run("Z Project...","projection=[Max Intensity]");
      run("Enhance Contrast...","saturated=0.35");
      run(clr[i]);
      saveAs(pth+"_ch-"+(n-i)+xtn);
      close(); close();
   }
}
//imagej-macro "batch_nd2-processing" (Herbie G., 09. Aug. 2024)

Предполагается, что исходные стеки имеют максимум три цветовых канала!