Настройте учетную запись хранения с подмодулями для каждой категории

Настройте учетную запись хранения с подмодулями для каждой категории с помощью terraform.

Чтобы определить подмодуль /дочерние модули с использованием подресурса for-each и ссылки на аргументы внутри учетной записи хранения, нам необходимо соблюдать определенную последовательность действий, поскольку параметры зависят от каждого другой.

Общее понимание субмодуля: нам нужно сначала начать писать конфигурацию субмодуля, а затем переходить к корневой конфигурации. Таким образом, иногда изменение последовательности может также вызвать проблему, с которой вы столкнулись.

Я попробовал конфигурацию терраформирования вашего требования, добавив имя в конфигурацию модуля очереди, и мне удалось решить проблему, и я смог успешно выполнить это требование, используя ресурс azapi для очереди хранения.

Конфигурация терраформа:

main.tf:

provider "azurerm" {
  features {}
}

variable "queues" {
  type = map(object({
    metadata = optional(map(string))
    name     = string
    role_assignments = optional(map(object({
      role_definition_id_or_name             = string
      principal_id                           = string
      description                            = optional(string, null)
      skip_service_principal_aad_check       = optional(bool, false)
      condition                              = optional(string, null)
      condition_version                      = optional(string, null)
      delegated_managed_identity_resource_id = optional(string, null)
    })), {})
    timeouts = optional(object({
      create = optional(string)
      delete = optional(string)
      read   = optional(string)
      update = optional(string)
    }))
  }))
  default = {}
}


resource "azurerm_resource_group" "example" {
  name     = "sampletestvk-rg"
  location = "East US"
}

resource "azurerm_storage_account" "example" {
  name                     = "exvksbstrageacct"
  resource_group_name      = azurerm_resource_group.example.name
  location                 = azurerm_resource_group.example.location
  account_tier             = "Standard"
  account_replication_type = "LRS"
}

module "storage_queue" {
  source             = "./modules/storage_queue"
  for_each           = var.queues
  name               = each.value.name
  metadata           = lookup(each.value, "metadata", {})
  storage_account_id = azurerm_storage_account.example.id
  timeouts           = lookup(each.value, "timeouts", null)
}

модуль/storage_queue/main.tf

terraform {
  required_providers {
    azapi = {
      source = "azure/azapi"
    }
  }
}

variable "name" {
  description = "The name of the queue."
  type        = string
}

variable "metadata" {
  description = "Metadata info for the queue."
  type        = map(string)
  default     = {}
}

variable "storage_account_id" {
  description = "The ID of the storage account."
  type        = string
}

variable "timeouts" {
  description = "Timeouts of the queue."
  type = object({
    create = optional(string)
    delete = optional(string)
    read   = optional(string)
  })
  default = null
}

resource "azapi_resource" "queue" {
  type = "Microsoft.Storage/storageAccounts/queueServices/queues@2023-01-01"
  body = jsonencode({
    properties = {
      metadata = var.metadata
    }
  })
  name                      = var.name
  parent_id                 = "${var.storage_account_id}/queueServices/default"
  schema_validation_enabled = false

  dynamic "timeouts" {
    for_each = var.timeouts == null ? [] : [var.timeouts]
    content {
      create = timeouts.value.create
      delete = timeouts.value.delete
      read   = timeouts.value.read
    }
  }
}

Развертывание выполнено успешно: